configure.ac 49 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677787980818283848586878889909192939495969798991001011021031041051061071081091101111121131141151161171181191201211221231241251261271281291301311321331341351361371381391401411421431441451461471481491501511521531541551561571581591601611621631641651661671681691701711721731741751761771781791801811821831841851861871881891901911921931941951961971981992002012022032042052062072082092102112122132142152162172182192202212222232242252262272282292302312322332342352362372382392402412422432442452462472482492502512522532542552562572582592602612622632642652662672682692702712722732742752762772782792802812822832842852862872882892902912922932942952962972982993003013023033043053063073083093103113123133143153163173183193203213223233243253263273283293303313323333343353363373383393403413423433443453463473483493503513523533543553563573583593603613623633643653663673683693703713723733743753763773783793803813823833843853863873883893903913923933943953963973983994004014024034044054064074084094104114124134144154164174184194204214224234244254264274284294304314324334344354364374384394404414424434444454464474484494504514524534544554564574584594604614624634644654664674684694704714724734744754764774784794804814824834844854864874884894904914924934944954964974984995005015025035045055065075085095105115125135145155165175185195205215225235245255265275285295305315325335345355365375385395405415425435445455465475485495505515525535545555565575585595605615625635645655665675685695705715725735745755765775785795805815825835845855865875885895905915925935945955965975985996006016026036046056066076086096106116126136146156166176186196206216226236246256266276286296306316326336346356366376386396406416426436446456466476486496506516526536546556566576586596606616626636646656666676686696706716726736746756766776786796806816826836846856866876886896906916926936946956966976986997007017027037047057067077087097107117127137147157167177187197207217227237247257267277287297307317327337347357367377387397407417427437447457467477487497507517527537547557567577587597607617627637647657667677687697707717727737747757767777787797807817827837847857867877887897907917927937947957967977987998008018028038048058068078088098108118128138148158168178188198208218228238248258268278288298308318328338348358368378388398408418428438448458468478488498508518528538548558568578588598608618628638648658668678688698708718728738748758768778788798808818828838848858868878888898908918928938948958968978988999009019029039049059069079089099109119129139149159169179189199209219229239249259269279289299309319329339349359369379389399409419429439449459469479489499509519529539549559569579589599609619629639649659669679689699709719729739749759769779789799809819829839849859869879889899909919929939949959969979989991000100110021003100410051006100710081009101010111012101310141015101610171018101910201021102210231024102510261027102810291030103110321033103410351036103710381039104010411042104310441045104610471048104910501051105210531054105510561057105810591060106110621063106410651066106710681069107010711072107310741075107610771078107910801081108210831084108510861087108810891090109110921093109410951096109710981099110011011102110311041105110611071108110911101111111211131114111511161117111811191120112111221123112411251126112711281129113011311132113311341135113611371138113911401141114211431144114511461147114811491150115111521153115411551156115711581159116011611162116311641165116611671168116911701171117211731174117511761177117811791180118111821183118411851186118711881189119011911192119311941195119611971198119912001201120212031204120512061207120812091210121112121213121412151216121712181219122012211222122312241225122612271228122912301231123212331234123512361237123812391240124112421243124412451246124712481249125012511252125312541255125612571258125912601261126212631264126512661267126812691270127112721273127412751276127712781279128012811282128312841285128612871288128912901291129212931294129512961297129812991300130113021303130413051306130713081309131013111312131313141315131613171318131913201321132213231324132513261327132813291330133113321333133413351336133713381339134013411342134313441345134613471348134913501351135213531354135513561357135813591360136113621363136413651366136713681369137013711372137313741375137613771378137913801381138213831384138513861387138813891390139113921393139413951396139713981399140014011402140314041405140614071408140914101411141214131414141514161417141814191420142114221423142414251426142714281429143014311432143314341435143614371438143914401441144214431444144514461447144814491450145114521453145414551456145714581459146014611462146314641465146614671468146914701471147214731474147514761477147814791480148114821483148414851486148714881489149014911492149314941495149614971498149915001501150215031504150515061507150815091510151115121513151415151516151715181519152015211522152315241525152615271528152915301531153215331534153515361537153815391540154115421543154415451546154715481549155015511552155315541555155615571558155915601561156215631564156515661567156815691570157115721573157415751576157715781579158015811582158315841585158615871588158915901591159215931594159515961597159815991600160116021603160416051606160716081609161016111612161316141615161616171618161916201621
  1. ##
  2. ## Configure template file for Quagga.
  3. ## autoconf will generate configure script.
  4. ##
  5. ## Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
  6. ## Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
  7. ##
  8. AC_PREREQ(2.53)
  9. AC_INIT(Quagga, 0.99.25-dev, [https://bugzilla.quagga.net])
  10. CONFIG_ARGS="$*"
  11. AC_SUBST(CONFIG_ARGS)
  12. AC_CONFIG_SRCDIR(lib/zebra.h)
  13. AC_CONFIG_MACRO_DIR([m4])
  14. dnl -----------------------------------
  15. dnl Get hostname and other information.
  16. dnl -----------------------------------
  17. AC_CANONICAL_BUILD()
  18. AC_CANONICAL_HOST()
  19. AC_CANONICAL_TARGET()
  20. AM_INIT_AUTOMAKE(1.6)
  21. AM_SILENT_RULES([yes])
  22. AC_CONFIG_HEADERS(config.h)
  23. AC_PATH_PROG(PERL, perl)
  24. AC_CHECK_PROG([GAWK],[gawk],[gawk],[not-in-PATH])
  25. if test "x$GAWK" = "xnot-in-PATH" ; then
  26. AC_MSG_ERROR([GNU awk is required for lib/memtype.h made by memtypes.awk.
  27. BSD awk complains: awk: gensub doesn't support backreferences (subst "\1") ])
  28. fi
  29. AC_ARG_VAR([GAWK],[GNU AWK])
  30. dnl default is to match previous behavior
  31. exampledir=${sysconfdir}
  32. AC_ARG_ENABLE([exampledir],
  33. AS_HELP_STRING([--enable-exampledir],
  34. [specify alternate directory for examples]),
  35. exampledir="$enableval",)
  36. dnl XXX add --exampledir to autoconf standard directory list somehow
  37. AC_SUBST(exampledir)
  38. dnl default is to match previous behavior
  39. pkgsrcrcdir=""
  40. pkgsrcdir=""
  41. AC_ARG_ENABLE([pkgsrcrcdir],
  42. AS_HELP_STRING([--enable-pkgsrcrcdir],
  43. [specify directory for rc.d scripts]),
  44. pkgsrcrcdir="$enableval"; pkgsrcdir="pkgsrc",)
  45. dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  46. AC_SUBST(pkgsrcdir)
  47. AC_SUBST(pkgsrcrcdir)
  48. dnl ------------
  49. dnl Check CFLAGS
  50. dnl ------------
  51. AC_ARG_WITH(cflags,
  52. [ --with-cflags Set CFLAGS for use in compilation.])
  53. if test "x$with_cflags" != "x" ; then
  54. CFLAGS="$with_cflags" ; cflags_specified=yes ;
  55. elif test -n "$CFLAGS" ; then
  56. cflags_specified=yes ;
  57. fi
  58. dnl --------------------
  59. dnl Check CC and friends
  60. dnl --------------------
  61. AC_LANG([C])
  62. AC_PROG_CC
  63. AC_PROG_CPP
  64. AM_PROG_CC_C_O
  65. AC_PROG_EGREP
  66. dnl autoconf 2.59 appears not to support AC_PROG_SED
  67. dnl AC_PROG_SED
  68. AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
  69. dnl pdflatex and latexmk are needed to build HACKING.pdf
  70. AC_CHECK_PROG([PDFLATEX],[pdflatex],[pdflatex],[/bin/false])
  71. AC_CHECK_PROG([LATEXMK],[latexmk],[latexmk],[/bin/false])
  72. if test "x$PDFLATEX" = "x/bin/false" -o "x$LATEXMK" = "x/bin/false"; then
  73. AC_MSG_WARN([Will not be able to make PDF versions of TeX documents])
  74. else
  75. HAVE_LATEX=true
  76. fi
  77. AM_CONDITIONAL([HAVE_LATEX], [test "x$HAVE_LATEX" = "xtrue"])
  78. if test "x${GCC}" != "xyes" ; then
  79. AC_MSG_CHECKING([whether we are using SunPro compiler])
  80. AC_EGREP_CPP([^__SUNPRO_C.*0x5(7|8|9)], ["__SUNPRO_C" __SUNPRO_C],
  81. [AC_MSG_RESULT([no])],
  82. [COMPILER="SUNPRO"
  83. AC_MSG_RESULT([yes])]
  84. )
  85. fi
  86. dnl ---------------------------------------------
  87. dnl If CLFAGS doesn\'t exist set default value
  88. dnl AC_PROG_CC will have set minimal default
  89. dnl already, eg "-O2 -g" for gcc, "-g" for others
  90. dnl (Wall is gcc specific... have to make sure
  91. dnl gcc is being used before setting it)
  92. dnl
  93. dnl Sun Studio 10 / SunPro 5.7 is also supported,
  94. dnl so lets set some sane CFLAGS for it.
  95. dnl ---------------------------------------------
  96. AC_USE_SYSTEM_EXTENSIONS()
  97. AC_DEFUN([AC_C_FLAG], [{
  98. AC_LANG_PUSH(C)
  99. ac_c_flag_save="$CFLAGS"
  100. CFLAGS="$CFLAGS $1"
  101. AC_MSG_CHECKING([[whether $CC supports $1]])
  102. AC_COMPILE_IFELSE(
  103. [AC_LANG_PROGRAM([[]])],
  104. [
  105. AC_MSG_RESULT([yes])
  106. m4_if([$3], [], [], [
  107. CFLAGS="$ac_c_flag_save"
  108. $3
  109. ])
  110. ], [
  111. CFLAGS="$ac_c_flag_save"
  112. AC_MSG_RESULT([no])
  113. $2
  114. ])
  115. AC_LANG_POP(C)
  116. }])
  117. AC_MSG_CHECKING([whether to set a default CFLAGS])
  118. if test "x${cflags_specified}" = "x" ; then
  119. case ${COMPILER} in
  120. "SUNPRO")
  121. CFLAGS="-xO4 -v -g -xspace -xcode=pic32 -xstrconst -xc99"
  122. AC_MSG_RESULT([SunPro default])
  123. ;;
  124. *)
  125. AC_MSG_RESULT([autodetecting])
  126. AC_C_FLAG([-diag-error 10006])
  127. AC_C_FLAG([-std=gnu99])
  128. AC_C_FLAG([-g])
  129. AC_C_FLAG([-Os], [
  130. AC_C_FLAG([-O2])
  131. ])
  132. AC_C_FLAG([-fno-omit-frame-pointer])
  133. AC_C_FLAG([-Wall])
  134. AC_C_FLAG([-Wextra])
  135. AC_C_FLAG([-Wmissing-prototypes])
  136. AC_C_FLAG([-Wmissing-declarations])
  137. AC_C_FLAG([-Wpointer-arith])
  138. AC_C_FLAG([-Wbad-function-cast])
  139. AC_C_FLAG([-Wwrite-strings])
  140. if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
  141. AC_C_FLAG([-Wcast-qual])
  142. AC_C_FLAG([-Wstrict-prototypes])
  143. AC_C_FLAG([-Wmissing-noreturn])
  144. AC_C_FLAG([-Wmissing-format-attribute])
  145. AC_C_FLAG([-Wunreachable-code])
  146. AC_C_FLAG([-Wpacked])
  147. AC_C_FLAG([-Wpadded])
  148. else
  149. AC_C_FLAG([-Wno-unused-result])
  150. fi
  151. AC_C_FLAG([-Wno-unused-parameter])
  152. AC_C_FLAG([-Wno-missing-field-initializers])
  153. # ICC emits a broken warning for const char *x = a ? "b" : "c";
  154. # for some reason the string consts get 'promoted' to char *,
  155. # triggering a const to non-const conversion warning.
  156. AC_C_FLAG([-diag-disable 3179])
  157. ;;
  158. esac
  159. else
  160. AC_MSG_RESULT([CFLAGS supplied by user])
  161. fi
  162. if test x"${enable_werror}" = x"yes" ; then
  163. WERROR="-Werror"
  164. fi
  165. AC_SUBST(WERROR)
  166. dnl --------------
  167. dnl Check programs
  168. dnl --------------
  169. AC_PROG_INSTALL
  170. AC_PROG_LN_S
  171. AC_PROG_MAKE_SET
  172. AC_CHECK_TOOL(AR, ar)
  173. dnl ---------------------------
  174. dnl We, perhaps unfortunately,
  175. dnl depend on GNU Make specific
  176. dnl constructs.
  177. dnl Give the user a warning if
  178. dnl not GNU Make.
  179. dnl ---------------------------
  180. AC_CACHE_CHECK([if ${MAKE-make} is GNU make], [quagga_cv_gnu_make],
  181. [quagga_cv_gnu_make=no
  182. if ${MAKE-make} --version 2>/dev/null | \
  183. grep '^GNU Make ' >/dev/null ; then
  184. quagga_cv_gnu_make=yes;
  185. fi
  186. ]
  187. )
  188. dnl -----------------
  189. dnl System extensions
  190. dnl -----------------
  191. AC_GNU_SOURCE
  192. dnl -------
  193. dnl libtool
  194. dnl -------
  195. AC_PROG_LIBTOOL
  196. dnl ----------------------
  197. dnl Packages configuration
  198. dnl ----------------------
  199. AC_ARG_WITH(pkg-extra-version,
  200. AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
  201. [EXTRAVERSION=$withval],)
  202. AC_ARG_WITH(pkg-git-version,
  203. AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
  204. [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
  205. AC_ARG_ENABLE(vtysh,
  206. AS_HELP_STRING([--enable-vtysh], [include integrated vty shell for Quagga]))
  207. AC_ARG_ENABLE(doc,
  208. AS_HELP_STRING([--disable-doc], [do not build docs]))
  209. AC_ARG_ENABLE(zebra,
  210. AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
  211. AC_ARG_ENABLE(bgpd,
  212. AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
  213. AC_ARG_ENABLE(ripd,
  214. AS_HELP_STRING([--disable-ripd], [do not build ripd]))
  215. AC_ARG_ENABLE(ripngd,
  216. AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
  217. AC_ARG_ENABLE(ospfd,
  218. AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
  219. AC_ARG_ENABLE(ospf6d,
  220. AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
  221. AC_ARG_ENABLE(watchquagga,
  222. AS_HELP_STRING([--disable-watchquagga], [do not build watchquagga]))
  223. AC_ARG_ENABLE(isisd,
  224. AS_HELP_STRING([--disable-isisd], [do not build isisd]))
  225. AC_ARG_ENABLE(pimd,
  226. AS_HELP_STRING([--enable-pimd], [build pimd]))
  227. AC_ARG_ENABLE(bgp-announce,
  228. AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
  229. AC_ARG_ENABLE(snmp,
  230. AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
  231. AC_ARG_WITH(libpam,
  232. AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
  233. AC_ARG_ENABLE(tcp-zebra,
  234. AS_HELP_STRING([--enable-tcp-zebra], [enable TCP/IP socket connection between zebra and protocol daemon]))
  235. AC_ARG_ENABLE(opaque-lsa,
  236. AS_HELP_STRING([--disable-opaque-lsa],[do not build OSPF Opaque-LSA with OSPFAPI support (RFC2370)]))
  237. AC_ARG_ENABLE(ospfapi,
  238. AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
  239. AC_ARG_ENABLE(ospfclient,
  240. AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
  241. (this is the default if --disable-ospfapi is set)]))
  242. AC_ARG_ENABLE(ospf-te,
  243. AS_HELP_STRING([--disable-ospf-te],[disable Traffic Engineering Extension to OSPF]))
  244. AC_ARG_ENABLE(multipath,
  245. AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
  246. AC_ARG_ENABLE(user,
  247. AS_HELP_STRING([--enable-user=USER], [user to run Quagga suite as (default quagga)]))
  248. AC_ARG_ENABLE(group,
  249. AS_HELP_STRING([--enable-group=GROUP], [group to run Quagga suite as (default quagga)]))
  250. AC_ARG_ENABLE(vty_group,
  251. AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
  252. AC_ARG_ENABLE(configfile_mask,
  253. AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
  254. AC_ARG_ENABLE(logfile_mask,
  255. AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
  256. AC_ARG_ENABLE(rtadv,
  257. AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
  258. AC_ARG_ENABLE(irdp,
  259. AS_HELP_STRING([--enable-irdp], [enable IRDP server support in zebra]))
  260. AC_ARG_ENABLE(isis_topology,
  261. AS_HELP_STRING([--enable-isis-topology], [enable IS-IS topology generator]))
  262. AC_ARG_ENABLE(capabilities,
  263. AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
  264. AC_ARG_ENABLE(rusage,
  265. AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
  266. AC_ARG_ENABLE(gcc_ultra_verbose,
  267. AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
  268. AC_ARG_ENABLE(linux24_tcp_md5,
  269. AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
  270. AC_ARG_ENABLE(gcc-rdynamic,
  271. AS_HELP_STRING([--enable-gcc-rdynamic], [enable linking with -rdynamic for better backtraces (default if gcc)]))
  272. AC_ARG_ENABLE(backtrace,
  273. AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
  274. AC_ARG_ENABLE(time-check,
  275. AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
  276. AC_ARG_ENABLE(pcreposix,
  277. AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
  278. AC_ARG_ENABLE(fpm,
  279. AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
  280. AC_ARG_ENABLE(werror,
  281. AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
  282. if test x"${enable_gcc_rdynamic}" != x"no" ; then
  283. if test x"${enable_gcc_rdynamic}" = x"yes" -o x"$COMPILER" = x"GCC"; then
  284. LDFLAGS="${LDFLAGS} -rdynamic"
  285. fi
  286. fi
  287. if test x"${enable_time_check}" != x"no" ; then
  288. if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
  289. AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
  290. else
  291. AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
  292. fi
  293. fi
  294. if test "${enable_fpm}" = "yes"; then
  295. AC_DEFINE(HAVE_FPM,,Forwarding Plane Manager support)
  296. fi
  297. if test "${enable_tcp_zebra}" = "yes"; then
  298. AC_DEFINE(HAVE_TCP_ZEBRA,,Use TCP for zebra communication)
  299. fi
  300. if test "${enable_opaque_lsa}" != "no"; then
  301. AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
  302. fi
  303. if test "${enable_ospf_te}" != "no"; then
  304. AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
  305. AC_DEFINE(HAVE_OSPF_TE,,OSPF TE)
  306. fi
  307. if test "${enable_linux24_tcp_md5}" = "yes"; then
  308. AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
  309. fi
  310. AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
  311. if test "${enable_rtadv}" != "no"; then
  312. AC_MSG_RESULT(yes)
  313. AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
  314. else
  315. AC_MSG_RESULT(no)
  316. fi
  317. if test "${enable_irdp}" = "yes"; then
  318. AC_DEFINE(HAVE_IRDP,, IRDP )
  319. fi
  320. if test "${enable_isisd}" != "no" && test "${enable_isis_topology}" = yes; then
  321. AC_DEFINE(TOPOLOGY_GENERATE,,Enable IS-IS topology generator code)
  322. ISIS_TOPOLOGY_INCLUDES="-I\$(srcdir)/topology"
  323. ISIS_TOPOLOGY_DIR="topology"
  324. ISIS_TOPOLOGY_LIB="./topology/libtopology.a"
  325. fi
  326. AC_SUBST(ISIS_TOPOLOGY_INCLUDES)
  327. AC_SUBST(ISIS_TOPOLOGY_DIR)
  328. AC_SUBST(ISIS_TOPOLOGY_LIB)
  329. if test "${enable_user}" = "yes" || test x"${enable_user}" = x""; then
  330. enable_user="quagga"
  331. elif test "${enable_user}" = "no"; then
  332. enable_user="root"
  333. fi
  334. if test "${enable_group}" = "yes" || test x"${enable_group}" = x""; then
  335. enable_group="quagga"
  336. elif test "${enable_group}" = "no"; then
  337. enable_group="root"
  338. fi
  339. if test x"${enable_vty_group}" = x"yes" ; then
  340. AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
  341. elif test x"${enable_vty_group}" != x""; then
  342. if test x"${enable_vty_group}" != x"no"; then
  343. AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
  344. fi
  345. fi
  346. AC_SUBST([enable_user])
  347. AC_SUBST([enable_group])
  348. AC_SUBST([enable_vty_group])
  349. AC_DEFINE_UNQUOTED(QUAGGA_USER, "${enable_user}", Quagga User)
  350. AC_DEFINE_UNQUOTED(QUAGGA_GROUP, "${enable_group}", Quagga Group)
  351. enable_configfile_mask=${enable_configfile_mask:-0600}
  352. AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
  353. enable_logfile_mask=${enable_logfile_mask:-0600}
  354. AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
  355. MULTIPATH_NUM=1
  356. case "${enable_multipath}" in
  357. [[0-9]|[1-9][0-9]])
  358. MULTIPATH_NUM="${enable_multipath}"
  359. ;;
  360. "")
  361. ;;
  362. *)
  363. AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
  364. ;;
  365. esac
  366. AC_SUBST(MULTIPATH_NUM)
  367. dnl -----------------------------------
  368. dnl Add extra version string to package
  369. dnl name, string and version fields.
  370. dnl -----------------------------------
  371. if test "x${EXTRAVERSION}" != "x" ; then
  372. VERSION="${VERSION}${EXTRAVERSION}"
  373. PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
  374. PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
  375. fi
  376. if test "x$with_pkg_git_version" = "xyes"; then
  377. if test -d "${srcdir}/.git"; then
  378. AC_DEFINE(GIT_VERSION, [1], [include git version info])
  379. else with_pkg_git_version="no"
  380. AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
  381. fi
  382. fi
  383. AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
  384. dnl ------------------------------------
  385. dnl Check C keywords and standard types
  386. dnl ------------------------------------
  387. AC_C_CONST
  388. AC_C_INLINE
  389. AC_C_RESTRICT
  390. AC_C_VOLATILE
  391. AC_HEADER_STDC
  392. AC_HEADER_TIME
  393. AC_HEADER_SYS_WAIT
  394. dnl AC_TYPE_PID_T
  395. AC_TYPE_UID_T
  396. AC_TYPE_MODE_T
  397. AC_TYPE_SIZE_T
  398. AC_STRUCT_TM
  399. dnl -------------------------
  400. dnl Check other header files.
  401. dnl -------------------------
  402. AC_CHECK_HEADERS([stropts.h sys/ksym.h sys/times.h sys/select.h \
  403. sys/types.h linux/version.h netdb.h asm/types.h \
  404. sys/cdefs.h sys/param.h limits.h signal.h \
  405. sys/socket.h netinet/in.h time.h sys/time.h])
  406. dnl Utility macro to avoid retyping includes all the time
  407. m4_define([QUAGGA_INCLUDES],
  408. [#ifdef SUNOS_5
  409. #define _XPG4_2
  410. #define __EXTENSIONS__
  411. #endif
  412. #include <stdio.h>
  413. #if STDC_HEADERS
  414. # include <stdlib.h>
  415. # include <stddef.h>
  416. #else
  417. # if HAVE_STDLIB_H
  418. # include <stdlib.h>
  419. # endif
  420. #endif
  421. #if HAVE_SYS_TYPES_H
  422. # include <sys/types.h>
  423. #endif
  424. /* sys/conf.h depends on param.h on FBSD at least */
  425. #if HAVE_SYS_PARAM_H
  426. # include <sys/param.h>
  427. #endif
  428. /* Required for MAXSIG */
  429. #if HAVE_SIGNAL_H
  430. # include <signal.h>
  431. #endif
  432. #if HAVE_SYS_SOCKET_H
  433. # include <sys/socket.h>
  434. #endif
  435. #ifdef __APPLE__
  436. # define __APPLE_USE_RFC_3542
  437. #endif
  438. #if HAVE_NETINET_IN_H
  439. # include <netinet/in.h>
  440. #endif
  441. #ifdef TIME_WITH_SYS_TIME
  442. # include <sys/time.h>
  443. # include <time.h>
  444. #else
  445. # ifdef HAVE_SYS_TIME_H
  446. # include <sys/time.h>
  447. # else
  448. # include <time.h>
  449. # endif
  450. #endif /* TIME_WITH_SYS_TIME */
  451. ])dnl
  452. dnl HAVE_NET_IF_H must be discovered by the time the longer AC_CHECK_HEADERS
  453. dnl round below execution begins, otherwise it doesn't properly detect
  454. dnl HAVE_NETINET6_IN6_VAR_H, HAVE_NET_IF_VAR_H and HAVE_STRUCT_IN6_ALIASREQ
  455. dnl on FreeBSD (BZ#408).
  456. AC_CHECK_HEADERS([net/if.h], [], [], QUAGGA_INCLUDES)
  457. m4_define([QUAGGA_INCLUDES],
  458. QUAGGA_INCLUDES
  459. [#if HAVE_NET_IF_H
  460. # include <net/if.h>
  461. #endif
  462. ])dnl
  463. dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
  464. dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
  465. dnl an additional round for it.
  466. AC_CHECK_HEADERS([net/if_var.h], [], [], QUAGGA_INCLUDES)
  467. m4_define([QUAGGA_INCLUDES],
  468. QUAGGA_INCLUDES
  469. [#if HAVE_NET_IF_VAR_H
  470. # include <net/if_var.h>
  471. #endif
  472. ])dnl
  473. AC_CHECK_HEADERS([sys/un.h netinet/in_systm.h netinet/in_var.h \
  474. net/if_dl.h net/netopt.h net/route.h \
  475. inet/nd.h arpa/inet.h netinet/ip_icmp.h \
  476. fcntl.h stddef.h sys/ioctl.h syslog.h wchar.h wctype.h \
  477. sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
  478. [], [], QUAGGA_INCLUDES)
  479. AC_CHECK_HEADERS([ucontext.h], [], [],
  480. [#ifndef __USE_GNU
  481. #define __USE_GNU
  482. #endif /* __USE_GNU */
  483. QUAGGA_INCLUDES
  484. ])
  485. m4_define([UCONTEXT_INCLUDES],
  486. [#include <ucontext.h>])dnl
  487. AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
  488. [], [], [UCONTEXT_INCLUDES])
  489. AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
  490. [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
  491. [], [], [UCONTEXT_INCLUDES])],
  492. [], [UCONTEXT_INCLUDES])
  493. AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
  494. [], [], [UCONTEXT_INCLUDES])
  495. m4_define([QUAGGA_INCLUDES],
  496. QUAGGA_INCLUDES
  497. [#if HAVE_SYS_UN_H
  498. # include <sys/un.h>
  499. #endif
  500. #if HAVE_NETINET_IN_SYSTM_H
  501. # include <netinet/in_systm.h>
  502. #endif
  503. #if HAVE_NETINET_IN_VAR_H
  504. # include <netinet/in_var.h>
  505. #endif
  506. #if HAVE_NET_IF_DL_H
  507. # include <net/if_dl.h>
  508. #endif
  509. #if HAVE_NET_NETOPT_H
  510. # include <net/netopt.h>
  511. #endif
  512. #if HAVE_NET_ROUTE_H
  513. # include <net/route.h>
  514. #endif
  515. #if HAVE_INET_ND_H
  516. # include <inet/nd.h>
  517. #endif
  518. #if HAVE_ARPA_INET_H
  519. # include <arpa/inet.h>
  520. #endif
  521. /* Required for IDRP */
  522. #if HAVE_NETINET_IP_ICMP_H
  523. # include <netinet/ip_icmp.h>
  524. #endif
  525. ])dnl
  526. dnl V6 headers are checked below, after we check for v6
  527. dnl Some systems (Solaris 2.x) require libnsl (Network Services Library)
  528. case "$host" in
  529. [*-sunos5.[6-7]*] | [*-solaris2.[6-7]*])
  530. opsys=sol2-6
  531. AC_DEFINE(SUNOS_56, 1, SunOS 5.6 to 5.7)
  532. AC_DEFINE(SUNOS_5, 1, SunOS 5)
  533. AC_CHECK_LIB(xnet, main)
  534. CURSES=-lcurses
  535. SOLARIS="solaris"
  536. ;;
  537. [*-sunos5.[8-9]] \
  538. | [*-sunos5.1[0-9]] \
  539. | [*-sunos5.1[0-9].[0-9]] \
  540. | [*-solaris2.[8-9]] \
  541. | [*-solaris2.1[0-9]] \
  542. | [*-solaris2.1[0-9].[0-9]])
  543. opsys=sol8
  544. AC_DEFINE(SUNOS_59, 1, [SunOS 5.8 up])
  545. AC_DEFINE(SUNOS_5, 1, [SunOS 5])
  546. AC_CHECK_LIB(socket, main)
  547. AC_CHECK_LIB(nsl, main)
  548. AC_CHECK_LIB(umem, main)
  549. AC_CHECK_FUNCS([printstack],
  550. [AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
  551. AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
  552. ])
  553. CURSES=-lcurses
  554. SOLARIS="solaris"
  555. ;;
  556. *-sunos5* | *-solaris2*)
  557. AC_DEFINE(SUNOS_5,,SunOS 5, Unknown SunOS)
  558. AC_CHECK_LIB(socket, main)
  559. AC_CHECK_LIB(nsl, main)
  560. CURSES=-lcurses
  561. SOLARIS="solaris"
  562. ;;
  563. *-linux*)
  564. opsys=gnu-linux
  565. AC_DEFINE(GNU_LINUX,,GNU Linux)
  566. ;;
  567. *-openbsd*)
  568. opsys=openbsd
  569. AC_DEFINE(OPEN_BSD,,OpenBSD)
  570. ;;
  571. esac
  572. AC_SYS_LARGEFILE
  573. dnl ---------------------
  574. dnl Integrated VTY option
  575. dnl ---------------------
  576. case "${enable_vtysh}" in
  577. "yes") VTYSH="vtysh";
  578. AC_DEFINE(VTYSH,,VTY shell)
  579. dnl Vtysh uses libreadline, which looks for termcap functions at
  580. dnl configure time. We follow readlines search order.
  581. dnl The required procedures are in libtermcap on NetBSD, in
  582. dnl [TODO] on Linux, and in [TODO] on Solaris.
  583. AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
  584. [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
  585. [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
  586. [AC_CHECK_LIB(ncurses, tputs,
  587. LIBREADLINE="$LIBREADLINE -lncurses")]
  588. )]
  589. )]
  590. )
  591. AC_CHECK_LIB(readline, main, LIBREADLINE="$LIBREADLINE -lreadline",,
  592. "$LIBREADLINE")
  593. if test $ac_cv_lib_readline_main = no; then
  594. AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
  595. fi
  596. AC_CHECK_HEADER(readline/history.h)
  597. if test $ac_cv_header_readline_history_h = no;then
  598. AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
  599. fi
  600. AC_CHECK_LIB(readline, rl_completion_matches,
  601. LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
  602. if test $ac_cv_lib_readline_rl_completion_matches = no; then
  603. AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
  604. fi
  605. ;;
  606. "no" ) VTYSH="";;
  607. * ) ;;
  608. esac
  609. AC_SUBST(LIBREADLINE)
  610. AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
  611. dnl ----------
  612. dnl PAM module
  613. dnl
  614. dnl Quagga detects the PAM library it is built against by checking for a
  615. dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
  616. dnl is known to #include pam_appl.h, the standard header of a PAM library, and
  617. dnl openpam.h doesn't do that, although depends on the header too. Hence a
  618. dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
  619. dnl of OpenPAM.
  620. dnl ----------
  621. if test "$with_libpam" = "yes"; then
  622. AC_CHECK_HEADER([security/pam_misc.h],
  623. [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
  624. AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
  625. pam_conv_func="misc_conv"
  626. ],
  627. [], QUAGGA_INCLUDES)
  628. AC_CHECK_HEADER([security/openpam.h],
  629. [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
  630. AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
  631. pam_conv_func="openpam_ttyconv"
  632. ],
  633. [], QUAGGA_INCLUDES[#include <security/pam_appl.h>])
  634. if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
  635. AC_MSG_WARN([*** pam support will not be built ***])
  636. with_libpam="no"
  637. fi
  638. fi
  639. if test "$with_libpam" = "yes"; then
  640. dnl took this test from proftpds configure.in and suited to our needs
  641. dnl -------------------------------------------------------------------------
  642. dnl
  643. dnl This next check looks funky due to a linker problem with some versions
  644. dnl of the PAM library. Prior to 0.72 release, the Linux PAM shared library
  645. dnl omitted requiring libdl linking information. PAM-0.72 or better ships
  646. dnl with RedHat 6.2 and Debian 2.2 or better.
  647. AC_CHECK_LIB(pam, pam_start,
  648. [AC_CHECK_LIB(pam, $pam_conv_func,
  649. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  650. LIBPAM="-lpam"],
  651. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  652. LIBPAM="-lpam -lpam_misc"]
  653. )
  654. ],
  655. [AC_CHECK_LIB(pam, pam_end,
  656. [AC_CHECK_LIB(pam, $pam_conv_func,
  657. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  658. LIBPAM="-lpam -ldl"],
  659. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  660. LIBPAM="-lpam -ldl -lpam_misc"]
  661. )
  662. ],AC_MSG_WARN([*** pam support will not be built ***]),
  663. [-ldl])
  664. ]
  665. )
  666. fi
  667. AC_SUBST(LIBPAM)
  668. dnl -------------------------------
  669. dnl Endian-ness check
  670. dnl -------------------------------
  671. AC_WORDS_BIGENDIAN
  672. dnl -------------------------------
  673. dnl check the size in byte of the C
  674. dnl -------------------------------
  675. dnl AC_CHECK_SIZEOF(char)
  676. dnl AC_CHECK_SIZEOF(int)
  677. dnl AC_CHECK_SIZEOF(short)
  678. dnl AC_CHECK_SIZEOF(long)
  679. dnl ----------------------------
  680. dnl check existance of functions
  681. dnl ----------------------------
  682. AC_FUNC_CHOWN
  683. AC_FUNC_FNMATCH
  684. AC_FUNC_FORK
  685. AC_FUNC_MEMCMP
  686. AC_FUNC_MKTIME
  687. AC_FUNC_STRFTIME
  688. AC_FUNC_STAT
  689. AC_FUNC_SELECT_ARGTYPES
  690. AC_FUNC_STRFTIME
  691. dnl Avoid AC_FUNC_STRNLEN because it pulls in AC_SYSTEM_EXTENSIONS which
  692. dnl can lead to strange side effects. So we just check for strnlen
  693. dnl directly, see below.
  694. dnl AC_FUNC_STRNLENdnl
  695. AC_FUNC_VPRINTF
  696. dnl -------------------------------
  697. dnl bgpd needs pow() and hence libm
  698. dnl -------------------------------
  699. TMPLIBS="$LIBS"
  700. AC_CHECK_HEADER([math.h],
  701. [AC_CHECK_LIB([m], [pow],
  702. [LIBM="-lm"
  703. LIBS="$LIBS $LIBM"
  704. AC_DEFINE(HAVE_LIBM,, Have libm)
  705. AC_CHECK_FUNCS(pow,[],[LIBM=""])
  706. ])
  707. ])
  708. if test x"$LIBM" = x ; then
  709. AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
  710. fi
  711. LIBS="$TMPLIBS"
  712. AC_SUBST(LIBM)
  713. dnl ---------------
  714. dnl other functions
  715. dnl ---------------
  716. AC_CHECK_FUNCS([dup2 ftruncate getcwd gethostbyname getpagesize gettimeofday \
  717. inet_ntoa inet_aton strnlen \
  718. memchr memmove memset select socket \
  719. strcasecmp strchr strcspn strdup strerror \
  720. strncasecmp strndup strrchr strspn strstr \
  721. strtol strtoul strlcat strlcpy \
  722. daemon snprintf vsnprintf \
  723. if_nametoindex if_indextoname getifaddrs \
  724. uname fcntl])
  725. AC_CHECK_FUNCS(setproctitle, ,
  726. [AC_CHECK_LIB(util, setproctitle,
  727. [LIBS="$LIBS -lutil"
  728. AC_DEFINE(HAVE_SETPROCTITLE,, Have setproctitle)
  729. ]
  730. )
  731. ]
  732. )
  733. AC_CHECK_HEADER([asm-generic/unistd.h],
  734. [AC_CHECK_DECL(__NR_setns,
  735. AC_DEFINE(HAVE_NETNS,, Have netns),,
  736. QUAGGA_INCLUDES [#include <asm-generic/unistd.h>
  737. ])
  738. AC_CHECK_FUNCS(setns, AC_DEFINE(HAVE_SETNS,, Have setns))]
  739. )
  740. dnl ------------------------------------
  741. dnl Determine routing get and set method
  742. dnl ------------------------------------
  743. AC_MSG_CHECKING(zebra between kernel interface method)
  744. if test x"$opsys" = x"gnu-linux"; then
  745. AC_MSG_RESULT(netlink)
  746. RT_METHOD=rt_netlink.o
  747. AC_DEFINE(HAVE_NETLINK,,netlink)
  748. netlink=yes
  749. else
  750. AC_MSG_RESULT(Route socket)
  751. KERNEL_METHOD="kernel_socket.o"
  752. RT_METHOD="rt_socket.o"
  753. fi
  754. AC_SUBST(RT_METHOD)
  755. AC_SUBST(KERNEL_METHOD)
  756. AM_CONDITIONAL([HAVE_NETLINK], [test "x$netlink" = "xyes"])
  757. dnl --------------------------
  758. dnl Determine IS-IS I/O method
  759. dnl --------------------------
  760. AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
  761. AC_DEFINE(ISIS_METHOD_DLPI, 2, [ constant value for isis method dlpi ])
  762. AC_DEFINE(ISIS_METHOD_BPF, 3, [ constant value for isis method bpf ])
  763. AC_CHECK_HEADER(net/bpf.h)
  764. AC_CHECK_HEADER(sys/dlpi.h)
  765. AC_MSG_CHECKING(zebra IS-IS I/O method)
  766. if test x"$opsys" = x"gnu-linux"; then
  767. AC_MSG_RESULT(pfpacket)
  768. ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
  769. elif test x"$opsys" = x"sol2-6" -o x"$opsys" = x"sol8"; then
  770. AC_MSG_RESULT(DLPI)
  771. ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
  772. else
  773. if test $ac_cv_header_net_bpf_h = no; then
  774. if test $ac_cv_header_sys_dlpi_h = no; then
  775. AC_MSG_RESULT(none)
  776. AC_MSG_WARN([*** IS-IS support will not be built ***])
  777. ISISD=""
  778. else
  779. AC_MSG_RESULT(DLPI)
  780. fi
  781. ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
  782. else
  783. AC_MSG_RESULT(BPF)
  784. ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
  785. fi
  786. fi
  787. AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
  788. dnl ------------------------------------
  789. dnl check for broken CMSG_FIRSTHDR macro
  790. dnl ------------------------------------
  791. AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
  792. AC_RUN_IFELSE([AC_LANG_SOURCE([[
  793. #ifdef SUNOS_5
  794. #define _XPG4_2
  795. #define __EXTENSIONS__
  796. #endif
  797. #ifdef HAVE_STDLIB_H
  798. # include <stdlib.h>
  799. #endif
  800. #ifdef HAVE_SYS_TYPES_H
  801. #include <sys/types.h>
  802. #endif
  803. #ifdef HAVE_SYS_SOCKET_H
  804. #include <sys/socket.h>
  805. #endif
  806. main()
  807. {
  808. struct msghdr msg;
  809. char buf[4];
  810. msg.msg_control = buf;
  811. msg.msg_controllen = 0;
  812. if (CMSG_FIRSTHDR(&msg) != NULL)
  813. exit(0);
  814. exit (1);
  815. }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
  816. [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
  817. dnl ------------------------------
  818. dnl check kernel route read method
  819. dnl ------------------------------
  820. AC_CACHE_CHECK([route read method], [quagga_cv_rtread_method],
  821. [if test "x$netlink" = xyes; then
  822. quagga_cv_rtread_method="netlink"
  823. else
  824. for quagga_cv_rtread_method in /dev/ip /dev/null;
  825. do
  826. test x`ls $quagga_cv_rtread_method 2>/dev/null` = x"$quagga_cv_rtread_method" && break
  827. done
  828. case $quagga_cv_rtread_method in
  829. "/dev/ip")
  830. case "$host" in
  831. *-freebsd*) quagga_cv_rtread_method="sysctl";;
  832. *) quagga_cv_rtread_method="getmsg";;
  833. esac;;
  834. *)
  835. quagga_cv_rtread_method="sysctl";;
  836. esac
  837. fi])
  838. RTREAD_METHOD=rtread_${quagga_cv_rtread_method}.o
  839. AC_SUBST(RTREAD_METHOD)
  840. dnl -----------------------------
  841. dnl check interface lookup method
  842. dnl -----------------------------
  843. IOCTL_METHOD=ioctl.o
  844. AC_MSG_CHECKING(interface looking up method)
  845. if test "$netlink" = yes; then
  846. AC_MSG_RESULT(netlink)
  847. IF_METHOD=if_netlink.o
  848. elif test "$opsys" = "sol2-6";then
  849. AC_MSG_RESULT(Solaris GIF)
  850. IF_METHOD=if_ioctl.o
  851. elif test "$opsys" = "sol8";then
  852. AC_MSG_RESULT(Solaris GLIF)
  853. IF_METHOD=if_ioctl_solaris.o
  854. IOCTL_METHOD=ioctl_solaris.o
  855. elif test "$opsys" = "openbsd";then
  856. AC_MSG_RESULT(openbsd)
  857. IF_METHOD=if_ioctl.o
  858. elif grep NET_RT_IFLIST /usr/include/sys/socket.h >/dev/null 2>&1; then
  859. AC_MSG_RESULT(sysctl)
  860. IF_METHOD=if_sysctl.o
  861. AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
  862. else
  863. AC_MSG_RESULT(ioctl)
  864. IF_METHOD=if_ioctl.o
  865. fi
  866. AC_SUBST(IF_METHOD)
  867. AC_SUBST(IOCTL_METHOD)
  868. dnl ---------------------------------------------------------------
  869. dnl figure out how to specify an interface in multicast sockets API
  870. dnl ---------------------------------------------------------------
  871. AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], QUAGGA_INCLUDES)
  872. AC_CHECK_HEADERS([linux/mroute.h], [], [],
  873. [
  874. #if HAVE_NETINET_IN_H
  875. #include<netinet/in.h>
  876. #endif])
  877. AC_MSG_CHECKING([for BSD struct ip_mreq hack])
  878. AC_TRY_COMPILE([#ifdef HAVE_SYS_PARAM_H
  879. #include <sys/param.h>
  880. #endif],[#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
  881. return (0);
  882. #else
  883. #error No support for BSD struct ip_mreq hack detected
  884. #endif],[AC_MSG_RESULT(yes)
  885. AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
  886. AC_MSG_RESULT(no))
  887. AC_MSG_CHECKING([for RFC3678 protocol-independed API])
  888. AC_TRY_COMPILE([
  889. #include <sys/types.h>
  890. #include <netinet/in.h>
  891. ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
  892. ], [AC_MSG_RESULT(yes)
  893. AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
  894. AC_MSG_RESULT(no))
  895. dnl ---------------------------------------------------------------
  896. dnl figure out how to check link-state
  897. dnl ---------------------------------------------------------------
  898. AC_CHECK_HEADER([net/if.h],
  899. [AC_CHECK_HEADER( [net/if_media.h],
  900. [m4_define([LINK_DETECT_INCLUDES],
  901. QUAGGA_INCLUDES
  902. [#include <net/if_media.h>
  903. ])
  904. AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
  905. AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
  906. [], LINK_DETECT_INCLUDES)],
  907. [],
  908. QUAGGA_INCLUDES)],
  909. [], QUAGGA_INCLUDES )
  910. dnl ---------------------------------------------------------------
  911. dnl Additional, newer way to check link-state using ifi_link_state.
  912. dnl Not available in all BSD's when ifmediareq available
  913. dnl ---------------------------------------------------------------
  914. AC_CHECK_HEADER([net/if.h],
  915. AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
  916. AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
  917. [], QUAGGA_INCLUDES),
  918. ,)
  919. dnl ------------------------
  920. dnl TCP_MD5SIG socket option
  921. dnl ------------------------
  922. AC_CHECK_HEADER([netinet/tcp.h],
  923. [m4_define([MD5_INCLUDES],
  924. QUAGGA_INCLUDES
  925. [#include <netinet/tcp.h>
  926. ])
  927. AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
  928. [],
  929. QUAGGA_INCLUDES)
  930. if test $ac_cv_have_decl_TCP_MD5SIG = no; then
  931. AC_CHECK_HEADER([linux/tcp.h],
  932. [m4_define([MD5_INCLUDES],
  933. QUAGGA_INCLUDES
  934. [#include <linux/tcp.h>
  935. ])
  936. AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
  937. fi
  938. dnl -----------------------------
  939. dnl check ipforward detect method
  940. dnl -----------------------------
  941. AC_CACHE_CHECK([ipforward method], [quagga_cv_ipforward_method],
  942. [if test x$cross_compiling = xyes; then
  943. if test x"$opsys" = x"gnu-linux"; then
  944. quagga_cv_ipforward_method=/proc/net/snmp
  945. else
  946. quagga_cv_ipforward_method=/dev/ip
  947. fi
  948. else
  949. for quagga_cv_ipforward_method in /proc/net/snmp /dev/ip /dev/null;
  950. do
  951. test x`ls $quagga_cv_ipforward_method 2>/dev/null` = x"$quagga_cv_ipforward_method" && break
  952. done
  953. fi
  954. case $quagga_cv_ipforward_method in
  955. "/proc/net/snmp") quagga_cv_ipforward_method="proc";;
  956. "/dev/ip")
  957. case "$host" in
  958. *-freebsd*) quagga_cv_ipforward_method="sysctl";;
  959. *) quagga_cv_ipforward_method="solaris";;
  960. esac;;
  961. *) quagga_cv_ipforward_method="sysctl";;
  962. esac])
  963. IPFORWARD=ipforward_${quagga_cv_ipforward_method}.o
  964. AC_SUBST(IPFORWARD)
  965. AC_CHECK_FUNCS(getaddrinfo, [have_getaddrinfo=yes], [have_getaddrinfo=no])
  966. dnl ----------
  967. dnl IPv6 check
  968. dnl ----------
  969. AC_MSG_CHECKING(whether does this OS have IPv6 stack)
  970. dnl ---------
  971. dnl KAME IPv6
  972. dnl ---------
  973. if grep WIDE /usr/include/netinet6/in6.h >/dev/null 2>&1; then
  974. AC_DEFINE(KAME,1,KAME IPv6)
  975. AC_MSG_RESULT(KAME)
  976. dnl ------------------------------------
  977. dnl Solaris 9, 10 and potentially higher
  978. dnl ------------------------------------
  979. elif test x"$opsys" = x"sol8"; then
  980. AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
  981. AC_MSG_RESULT(Solaris IPv6)
  982. dnl ----------
  983. dnl Linux IPv6
  984. dnl ----------
  985. elif test x"$opsys" = x"gnu-linux"; then
  986. AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
  987. AC_MSG_RESULT(Linux IPv6)
  988. else
  989. AC_MSG_ERROR([Failed to detect IPv6 stack])
  990. fi
  991. dnl this is unconditial, for compatibility
  992. AC_DEFINE(HAVE_IPV6,1,IPv6)
  993. dnl ------------------
  994. dnl IPv6 header checks
  995. dnl ------------------
  996. AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h netinet/icmp6.h \
  997. netinet6/in6_var.h netinet6/nd6.h], [], [],
  998. QUAGGA_INCLUDES)
  999. m4_define([QUAGGA_INCLUDES],dnl
  1000. QUAGGA_INCLUDES
  1001. [#if HAVE_NETINET6_IN6_H
  1002. #include <netinet6/in6.h>
  1003. #endif
  1004. #if HAVE_NETINET_IN6_VAR_H
  1005. #include <netinet/in6_var.h>
  1006. #endif
  1007. #if HAVE_NETINET_ICMP6_H
  1008. # include <netinet/icmp6.h>
  1009. #endif
  1010. #if HAVE_NETINET6_IN6_VAR_H
  1011. # include <netinet6/in6_var.h>
  1012. #endif
  1013. #if HAVE_NETINET6_ND6_H
  1014. # include <netinet6/nd6.h>
  1015. #endif
  1016. ])dnl
  1017. dnl disable doc check
  1018. if test "${enable_doc}" = "no";then
  1019. DOC=""
  1020. else
  1021. DOC="doc"
  1022. fi
  1023. dnl --------------------
  1024. dnl Daemon disable check
  1025. dnl --------------------
  1026. if test "${enable_zebra}" = "no";then
  1027. ZEBRA=""
  1028. else
  1029. ZEBRA="zebra"
  1030. fi
  1031. AM_CONDITIONAL(ZEBRA, test "x$ZEBRA" = "xzebra")
  1032. if test "${enable_bgpd}" = "no";then
  1033. BGPD=""
  1034. else
  1035. BGPD="bgpd"
  1036. fi
  1037. AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
  1038. if test "${enable_ripd}" = "no";then
  1039. RIPD=""
  1040. else
  1041. RIPD="ripd"
  1042. fi
  1043. AM_CONDITIONAL(RIPD, test "x$RIPD" = "xripd")
  1044. if test "${enable_ospfd}" = "no";then
  1045. OSPFD=""
  1046. else
  1047. OSPFD="ospfd"
  1048. fi
  1049. AM_CONDITIONAL(OSPFD, test "x$OSPFD" = "xospfd")
  1050. if test "${enable_watchquagga}" = "no";then
  1051. WATCHQUAGGA=""
  1052. else
  1053. WATCHQUAGGA="watchquagga"
  1054. fi
  1055. AM_CONDITIONAL(WATCHQUAGGA, test "x$WATCHQUAGGA" = "xwatchquagga")
  1056. OSPFCLIENT=""
  1057. if test "${enable_opaque_lsa}" != "no"; then
  1058. if test "${enable_ospfapi}" != "no";then
  1059. AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
  1060. if test "${enable_ospfclient}" != "no";then
  1061. OSPFCLIENT="ospfclient"
  1062. fi
  1063. fi
  1064. fi
  1065. AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
  1066. case "${enable_ripngd}" in
  1067. "no" ) RIPNGD="";;
  1068. * ) RIPNGD="ripngd";;
  1069. esac
  1070. AM_CONDITIONAL(RIPNGD, test "x$RIPNGD" = "xripngd")
  1071. case "${enable_ospf6d}" in
  1072. "no" ) OSPF6D="";;
  1073. * ) OSPF6D="ospf6d";;
  1074. esac
  1075. AM_CONDITIONAL(OSPF6D, test "x$OSPF6D" = "xospf6d")
  1076. case "${enable_isisd}" in
  1077. "no" ) ISISD="";;
  1078. * ) ISISD="isisd";;
  1079. esac
  1080. AM_CONDITIONAL(ISISD, test "x$ISISD" = "xisisd")
  1081. case "${enable_pimd}" in
  1082. "yes") PIMD="pimd";;
  1083. "no" ) PIMD="";;
  1084. * ) ;;
  1085. esac
  1086. AM_CONDITIONAL(PIMD, test "x$PIMD" = "xpimd")
  1087. if test "${enable_bgp_announce}" = "no";then
  1088. AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
  1089. else
  1090. AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
  1091. fi
  1092. AC_SUBST(DOC)
  1093. AC_SUBST(ZEBRA)
  1094. AC_SUBST(BGPD)
  1095. AC_SUBST(RIPD)
  1096. AC_SUBST(RIPNGD)
  1097. AC_SUBST(OSPFD)
  1098. AC_SUBST(OSPF6D)
  1099. AC_SUBST(WATCHQUAGGA)
  1100. AC_SUBST(ISISD)
  1101. AC_SUBST(PIMD)
  1102. AC_SUBST(SOLARIS)
  1103. AC_SUBST(VTYSH)
  1104. AC_SUBST(CURSES)
  1105. AC_SUBST(OSPFCLIENT)
  1106. AC_SUBST(OSPFAPI)
  1107. AC_CHECK_LIB(c, inet_ntop, [AC_DEFINE(HAVE_INET_NTOP,,inet_ntop)])
  1108. AC_CHECK_LIB(c, inet_pton, [AC_DEFINE(HAVE_INET_PTON,,inet_pton)])
  1109. AC_CHECK_LIB(crypt, crypt)
  1110. AC_CHECK_LIB(resolv, res_init)
  1111. dnl ---------------------------
  1112. dnl check system has PCRE regexp
  1113. dnl ---------------------------
  1114. if test "x$enable_pcreposix" = "xyes"; then
  1115. AC_CHECK_LIB(pcreposix, pcreposix_regexec, ,[enable_pcreposix=no
  1116. AC_MSG_WARN([*** falling back to other regex library ***]) ])
  1117. fi
  1118. if test "x$enable_pcreposix" != "xyes"; then
  1119. dnl ---------------------------
  1120. dnl check system has GNU regexp
  1121. dnl ---------------------------
  1122. AC_MSG_CHECKING(whether system has GNU regex)
  1123. AC_CHECK_LIB(c, regexec,
  1124. [AC_DEFINE(HAVE_GNU_REGEX,,GNU regexp library)
  1125. LIB_REGEX=""],
  1126. [LIB_REGEX="regex.o"])
  1127. fi
  1128. AC_SUBST(HAVE_LIBPCREPOSIX)
  1129. AC_SUBST(LIB_REGEX)
  1130. dnl ------------------
  1131. dnl check Net-SNMP library
  1132. dnl ------------------
  1133. if test "${enable_snmp}" != ""; then
  1134. AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
  1135. if test x"$NETSNMP_CONFIG" = x"no"; then
  1136. AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
  1137. fi
  1138. LIBS="$LIBS `${NETSNMP_CONFIG} --agent-libs`"
  1139. CFLAGS="`${NETSNMP_CONFIG} --base-cflags` $CFLAGS"
  1140. AC_MSG_CHECKING([whether we can link to Net-SNMP])
  1141. AC_LINK_IFELSE([AC_LANG_PROGRAM([
  1142. int main(void);
  1143. ],
  1144. [
  1145. {
  1146. return 0;
  1147. }
  1148. ])],[AC_MSG_RESULT(yes)],[
  1149. AC_MSG_RESULT(no)
  1150. AC_MSG_ERROR([--enable-snmp given but not usable])])
  1151. AC_DEFINE(HAVE_SNMP,,SNMP)
  1152. case "${enable_snmp}" in
  1153. yes)
  1154. SNMP_METHOD=agentx
  1155. ;;
  1156. smux|agentx)
  1157. SNMP_METHOD="${enable_snmp}"
  1158. ;;
  1159. *)
  1160. AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
  1161. ;;
  1162. esac
  1163. AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
  1164. AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
  1165. AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
  1166. fi
  1167. dnl ---------------------------
  1168. dnl sockaddr and netinet checks
  1169. dnl ---------------------------
  1170. AC_CHECK_TYPES([struct sockaddr, struct sockaddr_in,
  1171. struct sockaddr_in6, struct sockaddr_un, struct sockaddr_dl,
  1172. socklen_t, struct vifctl, struct mfcctl, struct sioc_sg_req,
  1173. vifi_t, struct sioc_vif_req, struct igmpmsg,
  1174. struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
  1175. struct nd_opt_adv_interval, struct rt_addrinfo,
  1176. struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
  1177. [], [], QUAGGA_INCLUDES)
  1178. AC_CHECK_MEMBERS([struct sockaddr.sa_len,
  1179. struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
  1180. struct sockaddr_in6.sin6_scope_id,
  1181. struct sockaddr_dl.sdl_len,
  1182. struct if6_aliasreq.ifra_lifetime,
  1183. struct nd_opt_adv_interval.nd_opt_ai_type],
  1184. [], [], QUAGGA_INCLUDES)
  1185. dnl ---------------------------
  1186. dnl IRDP/pktinfo/icmphdr checks
  1187. dnl ---------------------------
  1188. AC_CHECK_TYPES([struct in_pktinfo],
  1189. [AC_CHECK_TYPES([struct icmphdr],
  1190. [if test "${enable_irdp}" != "no"; then
  1191. AC_DEFINE(HAVE_IRDP,, IRDP)
  1192. fi],
  1193. [if test "${enable_irdp}" = "yes"; then
  1194. AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
  1195. fi], [QUAGGA_INCLUDES])],
  1196. [if test "${enable_irdp}" = "yes"; then
  1197. AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
  1198. fi], [QUAGGA_INCLUDES])
  1199. dnl -----------------------
  1200. dnl checking for IP_PKTINFO
  1201. dnl -----------------------
  1202. AC_MSG_CHECKING(for IP_PKTINFO)
  1203. AC_TRY_COMPILE([#include <netdb.h>], [
  1204. int opt = IP_PKTINFO;
  1205. ], [
  1206. AC_MSG_RESULT(yes)
  1207. AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
  1208. ], [
  1209. AC_MSG_RESULT(no)
  1210. ])
  1211. dnl ---------------------------
  1212. dnl checking for IP_RECVDSTADDR
  1213. dnl ---------------------------
  1214. AC_MSG_CHECKING(for IP_RECVDSTADDR)
  1215. AC_TRY_COMPILE([#include <netinet/in.h>], [
  1216. int opt = IP_RECVDSTADDR;
  1217. ], [
  1218. AC_MSG_RESULT(yes)
  1219. AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
  1220. ], [
  1221. AC_MSG_RESULT(no)
  1222. ])
  1223. dnl ----------------------
  1224. dnl checking for IP_RECVIF
  1225. dnl ----------------------
  1226. AC_MSG_CHECKING(for IP_RECVIF)
  1227. AC_TRY_COMPILE([#include <netinet/in.h>], [
  1228. int opt = IP_RECVIF;
  1229. ], [
  1230. AC_MSG_RESULT(yes)
  1231. AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
  1232. ], [
  1233. AC_MSG_RESULT(no)
  1234. ])
  1235. dnl --------------------------------------
  1236. dnl checking for getrusage struct and call
  1237. dnl --------------------------------------
  1238. if test "${enable_rusage}" != "no"; then
  1239. AC_MSG_CHECKING(whether getrusage is available)
  1240. AC_TRY_COMPILE([#include <sys/resource.h>],[struct rusage ac_x; getrusage (RUSAGE_SELF, &ac_x);],
  1241. [AC_MSG_RESULT(yes)
  1242. AC_DEFINE(HAVE_RUSAGE,,rusage)],
  1243. AC_MSG_RESULT(no))
  1244. fi
  1245. dnl --------------------------------------
  1246. dnl checking for clock_time monotonic struct and call
  1247. dnl --------------------------------------
  1248. AC_CHECK_DECL(CLOCK_MONOTONIC,
  1249. [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
  1250. AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
  1251. ], [AC_MSG_RESULT(no)], [QUAGGA_INCLUDES])
  1252. dnl -------------------
  1253. dnl capabilities checks
  1254. dnl -------------------
  1255. if test "${enable_capabilities}" != "no"; then
  1256. AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
  1257. AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
  1258. [AC_MSG_RESULT(yes)
  1259. AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
  1260. quagga_ac_keepcaps="yes"],
  1261. AC_MSG_RESULT(no)
  1262. )
  1263. if test x"${quagga_ac_keepcaps}" = x"yes"; then
  1264. AC_CHECK_HEADERS(sys/capability.h)
  1265. fi
  1266. if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
  1267. AC_CHECK_LIB(cap, cap_init,
  1268. [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
  1269. LIBCAP="-lcap"
  1270. quagga_ac_lcaps="yes"]
  1271. )
  1272. else
  1273. AC_CHECK_HEADERS(priv.h,
  1274. [AC_MSG_CHECKING(Solaris style privileges are available)
  1275. AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
  1276. [AC_MSG_RESULT(yes)
  1277. AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
  1278. quagga_ac_scaps="yes"],
  1279. AC_MSG_RESULT(no)
  1280. )
  1281. ]
  1282. )
  1283. fi
  1284. if test x"${quagga_ac_scaps}" = x"yes" \
  1285. -o x"${quagga_ac_lcaps}" = x"yes"; then
  1286. AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
  1287. fi
  1288. fi
  1289. AC_SUBST(LIBCAP)
  1290. dnl ---------------------------------------------------------------------------
  1291. dnl http://www.gnu.org/software/autoconf-archive/ax_sys_weak_alias.html
  1292. dnl Check for and set one of the following = 1
  1293. dnl HAVE_SYS_WEAK_ALIAS_ATTRIBUTE
  1294. dnl HAVE_SYS_WEAK_ALIAS_PRAGMA
  1295. dnl HAVE_SYS_WEAK_ALIAS_HPSECONDARY
  1296. dnl HAVE_SYS_WEAK_ALIAS_CRIDUPLICATE
  1297. dnl If any scheme is found, set
  1298. dnl HAVE_SYS_WEAK_ALIAS=1
  1299. dnl The following variable is set to text value
  1300. dnl WEAK_ALIAS = "attribute" || "pragma" || "hpsecondary" || "criduplicate" || "no"
  1301. dnl If weak alias can cross object file boundaries
  1302. dnl WEAK_ALIAS_CROSSFILE = "yes" || "no"
  1303. dnl ---------------------------------------------------------------------------
  1304. AX_SYS_WEAK_ALIAS
  1305. dnl ---------------------------
  1306. dnl check for glibc 'backtrace'
  1307. dnl ---------------------------
  1308. if test x"${enable_backtrace}" != x"no" ; then
  1309. backtrace_ok=no
  1310. AC_CHECK_HEADER([execinfo.h], [
  1311. AC_SEARCH_LIBS([backtrace], [execinfo], [
  1312. AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
  1313. AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
  1314. backtrace_ok=yes
  1315. ],, [-lm])
  1316. ])
  1317. if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
  1318. dnl user explicitly requested backtrace but we failed to find support
  1319. AC_MSG_FAILURE([failed to find backtrace support])
  1320. fi
  1321. fi
  1322. dnl -----------------------------------------
  1323. dnl check for malloc mallinfo struct and call
  1324. dnl this must try and link using LIBS, in
  1325. dnl order to check no alternative allocator
  1326. dnl has been specified, which might not provide
  1327. dnl mallinfo, e.g. such as Umem on Solaris.
  1328. dnl -----------------------------------------
  1329. AC_CHECK_HEADER([malloc.h],
  1330. [AC_MSG_CHECKING(whether mallinfo is available)
  1331. AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
  1332. [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
  1333. [AC_MSG_RESULT(yes)
  1334. AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
  1335. AC_MSG_RESULT(no)
  1336. )
  1337. ], [], QUAGGA_INCLUDES)
  1338. dnl ----------
  1339. dnl configure date
  1340. dnl ----------
  1341. CONFDATE=`date '+%Y%m%d'`
  1342. AC_SUBST(CONFDATE)
  1343. dnl Conditionally enable PIE support for GNU toolchains.
  1344. AC_ARG_ENABLE(pie, AS_HELP_STRING([--disable-pie], [Do not build tools as a Position Independent Executables]))
  1345. if test "$enable_pie" != "no"; then
  1346. AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
  1347. save_CFLAGS=$CFLAGS
  1348. save_LDFLAGS=$LDFLAGS
  1349. CFLAGS="$CFLAGS -fPIE"
  1350. LDFLAGS="$LDFLAGS -pie"
  1351. AC_LINK_IFELSE([AC_LANG_SOURCE([[static int foo[30000]; int main () { return 0; }]])],
  1352. [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no]
  1353. )
  1354. CFLAGS=$save_CFLAGS
  1355. LDFLAGS=$save_LDFLAGS
  1356. ])
  1357. if test "$ap_cv_cc_pie" = "yes"; then
  1358. PICFLAGS="-fPIE"
  1359. PILDFLAGS="-pie"
  1360. fi
  1361. fi
  1362. AC_SUBST(PICFLAGS)
  1363. AC_SUBST(PILDFLAGS)
  1364. dnl -------
  1365. dnl DejaGNU
  1366. dnl -------
  1367. if test x"$DEJAGNU" = x
  1368. then
  1369. DEJAGNU="\$(top_srcdir)/tests/global-conf.exp"
  1370. fi
  1371. RUNTESTDEFAULTFLAGS="-x --tool \$\$tool"
  1372. AC_SUBST(DEJAGNU)
  1373. AC_SUBST(RUNTESTDEFAULTFLAGS)
  1374. dnl ------------------------------
  1375. dnl set paths for state directory
  1376. dnl ------------------------------
  1377. AC_MSG_CHECKING(directory to use for state file)
  1378. if test "${prefix}" = "NONE"; then
  1379. quagga_statedir_prefix="";
  1380. else
  1381. quagga_statedir_prefix=${prefix}
  1382. fi
  1383. if test "${localstatedir}" = '${prefix}/var'; then
  1384. for QUAGGA_STATE_DIR in ${quagga_statedir_prefix}/var/run dnl
  1385. ${quagga_statedir_prefix}/var/adm dnl
  1386. ${quagga_statedir_prefix}/etc dnl
  1387. /var/run dnl
  1388. /var/adm dnl
  1389. /etc dnl
  1390. /dev/null;
  1391. do
  1392. test -d $QUAGGA_STATE_DIR && break
  1393. done
  1394. quagga_statedir=$QUAGGA_STATE_DIR
  1395. else
  1396. quagga_statedir=${localstatedir}
  1397. fi
  1398. if test $quagga_statedir = "/dev/null"; then
  1399. AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
  1400. fi
  1401. AC_MSG_RESULT(${quagga_statedir})
  1402. AC_SUBST(quagga_statedir)
  1403. AC_DEFINE_UNQUOTED(PATH_ZEBRA_PID, "$quagga_statedir/zebra.pid",zebra PID)
  1404. AC_DEFINE_UNQUOTED(PATH_RIPD_PID, "$quagga_statedir/ripd.pid",ripd PID)
  1405. AC_DEFINE_UNQUOTED(PATH_RIPNGD_PID, "$quagga_statedir/ripngd.pid",ripngd PID)
  1406. AC_DEFINE_UNQUOTED(PATH_BGPD_PID, "$quagga_statedir/bgpd.pid",bgpd PID)
  1407. AC_DEFINE_UNQUOTED(PATH_OSPFD_PID, "$quagga_statedir/ospfd.pid",ospfd PID)
  1408. AC_DEFINE_UNQUOTED(PATH_OSPF6D_PID, "$quagga_statedir/ospf6d.pid",ospf6d PID)
  1409. AC_DEFINE_UNQUOTED(PATH_ISISD_PID, "$quagga_statedir/isisd.pid",isisd PID)
  1410. AC_DEFINE_UNQUOTED(PATH_PIMD_PID, "$quagga_statedir/pimd.pid",pimd PID)
  1411. AC_DEFINE_UNQUOTED(PATH_WATCHQUAGGA_PID, "$quagga_statedir/watchquagga.pid",watchquagga PID)
  1412. AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$quagga_statedir/zserv.api",zebra api socket)
  1413. AC_DEFINE_UNQUOTED(ZEBRA_VTYSH_PATH, "$quagga_statedir/zebra.vty",zebra vty socket)
  1414. AC_DEFINE_UNQUOTED(RIP_VTYSH_PATH, "$quagga_statedir/ripd.vty",rip vty socket)
  1415. AC_DEFINE_UNQUOTED(RIPNG_VTYSH_PATH, "$quagga_statedir/ripngd.vty",ripng vty socket)
  1416. AC_DEFINE_UNQUOTED(BGP_VTYSH_PATH, "$quagga_statedir/bgpd.vty",bgpd vty socket)
  1417. AC_DEFINE_UNQUOTED(OSPF_VTYSH_PATH, "$quagga_statedir/ospfd.vty",ospfd vty socket)
  1418. AC_DEFINE_UNQUOTED(OSPF6_VTYSH_PATH, "$quagga_statedir/ospf6d.vty",ospf6d vty socket)
  1419. AC_DEFINE_UNQUOTED(ISIS_VTYSH_PATH, "$quagga_statedir/isisd.vty",isisd vty socket)
  1420. AC_DEFINE_UNQUOTED(PIM_VTYSH_PATH, "$quagga_statedir/pimd.vty",pimd vty socket)
  1421. AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$quagga_statedir",daemon vty directory)
  1422. dnl -------------------------------
  1423. dnl Quagga sources should always be
  1424. dnl current wrt interfaces. Dont
  1425. dnl allow deprecated interfaces to
  1426. dnl be exposed.
  1427. dnl -------------------------------
  1428. AC_DEFINE(QUAGGA_NO_DEPRECATED_INTERFACES, 1, Hide deprecated interfaces)
  1429. dnl ---------------------------
  1430. dnl Check htonl works correctly
  1431. dnl ---------------------------
  1432. AC_MSG_CHECKING(for working htonl)
  1433. AC_CACHE_VAL(ac_cv_htonl_works,
  1434. [AC_LINK_IFELSE([AC_LANG_PROGRAM([QUAGGA_INCLUDES],[htonl (0);])],
  1435. [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
  1436. ]
  1437. )
  1438. AC_MSG_RESULT($ac_cv_htonl_works)
  1439. AC_CONFIG_FILES([Makefile lib/Makefile zebra/Makefile ripd/Makefile
  1440. ripngd/Makefile bgpd/Makefile ospfd/Makefile watchquagga/Makefile
  1441. ospf6d/Makefile isisd/Makefile vtysh/Makefile
  1442. doc/Makefile ospfclient/Makefile tests/Makefile m4/Makefile
  1443. pimd/Makefile
  1444. tests/bgpd.tests/Makefile
  1445. tests/libzebra.tests/Makefile
  1446. redhat/Makefile
  1447. pkgsrc/Makefile
  1448. redhat/quagga.spec
  1449. lib/version.h
  1450. doc/defines.texi
  1451. isisd/topology/Makefile
  1452. pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
  1453. pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh])
  1454. AC_CONFIG_FILES([solaris/Makefile])
  1455. AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
  1456. ## Hack, but working solution to avoid rebuilding of quagga.info.
  1457. ## It's already in CVS until texinfo 4.7 is more common.
  1458. AC_OUTPUT
  1459. echo "
  1460. Quagga configuration
  1461. --------------------
  1462. quagga version : ${PACKAGE_VERSION}
  1463. host operating system : ${host_os}
  1464. source code location : ${srcdir}
  1465. compiler : ${CC}
  1466. compiler flags : ${CFLAGS}
  1467. make : ${MAKE-make}
  1468. linker flags : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
  1469. state file directory : ${quagga_statedir}
  1470. config file directory : `eval echo \`echo ${sysconfdir}\``
  1471. example directory : `eval echo \`echo ${exampledir}\``
  1472. user to run as : ${enable_user}
  1473. group to run as : ${enable_group}
  1474. group for vty sockets : ${enable_vty_group}
  1475. config file mask : ${enable_configfile_mask}
  1476. log file mask : ${enable_logfile_mask}
  1477. The above user and group must have read/write access to the state file
  1478. directory and to the config files in the config file directory."
  1479. if test x"$quagga_cv_gnu_make" = x"no"; then echo "
  1480. Warning: The ${MAKE-make} programme detected, either in your path or
  1481. via the MAKE variable, is not GNU Make. GNU make may be installed as
  1482. gmake on some systems. and is required to complete a build of Quagga
  1483. " > /dev/stderr
  1484. fi