configure.ac 49 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677787980818283848586878889909192939495969798991001011021031041051061071081091101111121131141151161171181191201211221231241251261271281291301311321331341351361371381391401411421431441451461471481491501511521531541551561571581591601611621631641651661671681691701711721731741751761771781791801811821831841851861871881891901911921931941951961971981992002012022032042052062072082092102112122132142152162172182192202212222232242252262272282292302312322332342352362372382392402412422432442452462472482492502512522532542552562572582592602612622632642652662672682692702712722732742752762772782792802812822832842852862872882892902912922932942952962972982993003013023033043053063073083093103113123133143153163173183193203213223233243253263273283293303313323333343353363373383393403413423433443453463473483493503513523533543553563573583593603613623633643653663673683693703713723733743753763773783793803813823833843853863873883893903913923933943953963973983994004014024034044054064074084094104114124134144154164174184194204214224234244254264274284294304314324334344354364374384394404414424434444454464474484494504514524534544554564574584594604614624634644654664674684694704714724734744754764774784794804814824834844854864874884894904914924934944954964974984995005015025035045055065075085095105115125135145155165175185195205215225235245255265275285295305315325335345355365375385395405415425435445455465475485495505515525535545555565575585595605615625635645655665675685695705715725735745755765775785795805815825835845855865875885895905915925935945955965975985996006016026036046056066076086096106116126136146156166176186196206216226236246256266276286296306316326336346356366376386396406416426436446456466476486496506516526536546556566576586596606616626636646656666676686696706716726736746756766776786796806816826836846856866876886896906916926936946956966976986997007017027037047057067077087097107117127137147157167177187197207217227237247257267277287297307317327337347357367377387397407417427437447457467477487497507517527537547557567577587597607617627637647657667677687697707717727737747757767777787797807817827837847857867877887897907917927937947957967977987998008018028038048058068078088098108118128138148158168178188198208218228238248258268278288298308318328338348358368378388398408418428438448458468478488498508518528538548558568578588598608618628638648658668678688698708718728738748758768778788798808818828838848858868878888898908918928938948958968978988999009019029039049059069079089099109119129139149159169179189199209219229239249259269279289299309319329339349359369379389399409419429439449459469479489499509519529539549559569579589599609619629639649659669679689699709719729739749759769779789799809819829839849859869879889899909919929939949959969979989991000100110021003100410051006100710081009101010111012101310141015101610171018101910201021102210231024102510261027102810291030103110321033103410351036103710381039104010411042104310441045104610471048104910501051105210531054105510561057105810591060106110621063106410651066106710681069107010711072107310741075107610771078107910801081108210831084108510861087108810891090109110921093109410951096109710981099110011011102110311041105110611071108110911101111111211131114111511161117111811191120112111221123112411251126112711281129113011311132113311341135113611371138113911401141114211431144114511461147114811491150115111521153115411551156115711581159116011611162116311641165116611671168116911701171117211731174117511761177117811791180118111821183118411851186118711881189119011911192119311941195119611971198119912001201120212031204120512061207120812091210121112121213121412151216121712181219122012211222122312241225122612271228122912301231123212331234123512361237123812391240124112421243124412451246124712481249125012511252125312541255125612571258125912601261126212631264126512661267126812691270127112721273127412751276127712781279128012811282128312841285128612871288128912901291129212931294129512961297129812991300130113021303130413051306130713081309131013111312131313141315131613171318131913201321132213231324132513261327132813291330133113321333133413351336133713381339134013411342134313441345134613471348134913501351135213531354135513561357135813591360136113621363136413651366136713681369137013711372137313741375137613771378137913801381138213831384138513861387138813891390139113921393139413951396139713981399140014011402140314041405140614071408140914101411141214131414141514161417141814191420142114221423142414251426142714281429143014311432143314341435143614371438143914401441144214431444144514461447144814491450145114521453145414551456145714581459146014611462146314641465146614671468146914701471147214731474147514761477147814791480148114821483148414851486148714881489149014911492149314941495149614971498149915001501150215031504150515061507150815091510151115121513151415151516151715181519152015211522152315241525152615271528152915301531153215331534153515361537153815391540154115421543154415451546154715481549155015511552155315541555155615571558155915601561156215631564156515661567156815691570157115721573157415751576157715781579158015811582158315841585158615871588158915901591159215931594159515961597159815991600160116021603160416051606160716081609161016111612161316141615161616171618161916201621
  1. ##
  2. ## Configure template file for Quagga.
  3. ## autoconf will generate configure script.
  4. ##
  5. ## Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
  6. ## Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
  7. ##
  8. AC_PREREQ(2.53)
  9. AC_INIT(Quagga, 0.99.24-rc1, [https://bugzilla.quagga.net])
  10. AC_CONFIG_SRCDIR(lib/zebra.h)
  11. AC_CONFIG_MACRO_DIR([m4])
  12. dnl -----------------------------------
  13. dnl Get hostname and other information.
  14. dnl -----------------------------------
  15. AC_CANONICAL_BUILD()
  16. AC_CANONICAL_HOST()
  17. AC_CANONICAL_TARGET()
  18. AM_INIT_AUTOMAKE(1.6)
  19. AC_CONFIG_HEADERS(config.h)
  20. AC_PATH_PROG(PERL, perl)
  21. AC_CHECK_PROG([GAWK],[gawk],[gawk],[not-in-PATH])
  22. if test "x$GAWK" = "xnot-in-PATH" ; then
  23. AC_MSG_ERROR([GNU awk is required for lib/memtype.h made by memtypes.awk.
  24. BSD awk complains: awk: gensub doesn't support backreferences (subst "\1") ])
  25. fi
  26. AC_ARG_VAR([GAWK],[GNU AWK])
  27. dnl default is to match previous behavior
  28. exampledir=${sysconfdir}
  29. AC_ARG_ENABLE([exampledir],
  30. AS_HELP_STRING([--enable-exampledir],
  31. [specify alternate directory for examples]),
  32. exampledir="$enableval",)
  33. dnl XXX add --exampledir to autoconf standard directory list somehow
  34. AC_SUBST(exampledir)
  35. dnl default is to match previous behavior
  36. pkgsrcrcdir=""
  37. pkgsrcdir=""
  38. AC_ARG_ENABLE([pkgsrcrcdir],
  39. AS_HELP_STRING([--enable-pkgsrcrcdir],
  40. [specify directory for rc.d scripts]),
  41. pkgsrcrcdir="$enableval"; pkgsrcdir="pkgsrc",)
  42. dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  43. AC_SUBST(pkgsrcdir)
  44. AC_SUBST(pkgsrcrcdir)
  45. dnl ------------
  46. dnl Check CFLAGS
  47. dnl ------------
  48. AC_ARG_WITH(cflags,
  49. [ --with-cflags Set CFLAGS for use in compilation.])
  50. if test "x$with_cflags" != "x" ; then
  51. CFLAGS="$with_cflags" ; cflags_specified=yes ;
  52. elif test -n "$CFLAGS" ; then
  53. cflags_specified=yes ;
  54. fi
  55. dnl --------------------
  56. dnl Check CC and friends
  57. dnl --------------------
  58. AC_LANG([C])
  59. AC_PROG_CC
  60. AC_PROG_CPP
  61. AM_PROG_CC_C_O
  62. AC_PROG_EGREP
  63. dnl autoconf 2.59 appears not to support AC_PROG_SED
  64. dnl AC_PROG_SED
  65. AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
  66. dnl pdflatex and latexmk are needed to build HACKING.pdf
  67. AC_CHECK_PROG([PDFLATEX],[pdflatex],[pdflatex],[/bin/false])
  68. AC_CHECK_PROG([LATEXMK],[latexmk],[latexmk],[/bin/false])
  69. if test "x$PDFLATEX" = "x/bin/false" -o "x$LATEXMK" = "x/bin/false"; then
  70. AC_MSG_WARN([Will not be able to make PDF versions of TeX documents])
  71. else
  72. HAVE_LATEX=true
  73. fi
  74. AM_CONDITIONAL([HAVE_LATEX], [test "x$HAVE_LATEX" = "xtrue"])
  75. dnl ------------------------------------------------------------------
  76. dnl Intel compiler check. Although Intel tries really hard to make icc
  77. dnl look like gcc, there are some differences. It's very verbose with
  78. dnl -Wall and it doesn't support the individual -W options.
  79. dnl ------------------------------------------------------------------
  80. if test "x${GCC}" = "xyes" ; then
  81. COMPILER="GCC"
  82. AC_MSG_CHECKING([whether we are using the Intel compiler])
  83. AC_EGREP_CPP([^__INTEL_COMPILER], [__INTEL_COMPILER],
  84. [AC_MSG_RESULT([no])],
  85. [COMPILER="ICC"
  86. AC_MSG_RESULT([yes])]
  87. )
  88. else
  89. AC_MSG_CHECKING([whether we are using SunPro compiler])
  90. AC_EGREP_CPP([^__SUNPRO_C.*0x5(7|8|9)], ["__SUNPRO_C" __SUNPRO_C],
  91. [AC_MSG_RESULT([no])],
  92. [COMPILER="SUNPRO"
  93. AC_MSG_RESULT([yes])]
  94. )
  95. fi
  96. dnl ---------------------------------------------
  97. dnl If CLFAGS doesn\'t exist set default value
  98. dnl AC_PROG_CC will have set minimal default
  99. dnl already, eg "-O2 -g" for gcc, "-g" for others
  100. dnl (Wall is gcc specific... have to make sure
  101. dnl gcc is being used before setting it)
  102. dnl
  103. dnl Intel icc 8.0 also sets __GNUC__,
  104. dnl but doesn't support all these fancy -W options.
  105. dnl Intel compiler warnings we ignore:
  106. dnl 279: controlling expression is constant.
  107. dnl 869: parameter "xxx" was never referenced - to avoid massive warnings
  108. dnl about "self", "vty", "argc" and "argv" never referenced in DEFUN
  109. dnl macro.
  110. dnl 981: operands are evaluated in unspecified order.
  111. dnl
  112. dnl Sun Studio 10 / SunPro 5.7 is also supported,
  113. dnl so lets set some sane CFLAGS for it.
  114. dnl ---------------------------------------------
  115. AC_MSG_CHECKING([whether to set a default CFLAGS])
  116. if test "x${cflags_specified}" = "x" ; then
  117. case ${COMPILER} in
  118. "ICC")
  119. CFLAGS="-Os -g -Wall"
  120. AC_MSG_RESULT([Intel default])
  121. ;;
  122. "GCC")
  123. CFLAGS="-Os -fno-omit-frame-pointer -g -std=gnu99 -Wall"
  124. CFLAGS="${CFLAGS} -Wsign-compare -Wpointer-arith"
  125. CFLAGS="${CFLAGS} -Wbad-function-cast -Wwrite-strings"
  126. CFLAGS="${CFLAGS} -Wmissing-prototypes -Wmissing-declarations"
  127. CFLAGS="${CFLAGS} -Wchar-subscripts -Wcast-qual"
  128. # TODO: conditionally addd -Wpacked if handled
  129. AC_MSG_RESULT([gcc default])
  130. ;;
  131. "SUNPRO")
  132. CFLAGS="-xO4 -v -g -xspace -xcode=pic32 -xstrconst -xc99"
  133. AC_MSG_RESULT([SunPro default])
  134. ;;
  135. *)
  136. AC_MSG_RESULT([unknown compiler])
  137. ;;
  138. esac
  139. else
  140. AC_MSG_RESULT([CFLAGS supplied by user])
  141. fi
  142. dnl --------------
  143. dnl Check programs
  144. dnl --------------
  145. AC_PROG_INSTALL
  146. AC_PROG_LN_S
  147. AC_PROG_MAKE_SET
  148. AC_CHECK_TOOL(AR, ar)
  149. dnl ---------------------------
  150. dnl We, perhaps unfortunately,
  151. dnl depend on GNU Make specific
  152. dnl constructs.
  153. dnl Give the user a warning if
  154. dnl not GNU Make.
  155. dnl ---------------------------
  156. AC_CACHE_CHECK([if ${MAKE-make} is GNU make], [quagga_cv_gnu_make],
  157. [quagga_cv_gnu_make=no
  158. if ${MAKE-make} --version 2>/dev/null | \
  159. grep '^GNU Make ' >/dev/null ; then
  160. quagga_cv_gnu_make=yes;
  161. fi
  162. ]
  163. )
  164. dnl -----------------
  165. dnl System extensions
  166. dnl -----------------
  167. AC_GNU_SOURCE
  168. dnl -------
  169. dnl libtool
  170. dnl -------
  171. AC_PROG_LIBTOOL
  172. dnl ----------------------
  173. dnl Packages configuration
  174. dnl ----------------------
  175. AC_ARG_WITH(pkg-extra-version,
  176. AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
  177. [EXTRAVERSION=$withval],)
  178. AC_ARG_WITH(pkg-git-version,
  179. AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
  180. [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
  181. AC_ARG_ENABLE(vtysh,
  182. AS_HELP_STRING([--enable-vtysh], [include integrated vty shell for Quagga]))
  183. AC_ARG_ENABLE(ipv6,
  184. AS_HELP_STRING([--disable-ipv6], [turn off IPv6 related features and daemons]))
  185. AC_ARG_ENABLE(doc,
  186. AS_HELP_STRING([--disable-doc], [do not build docs]))
  187. AC_ARG_ENABLE(zebra,
  188. AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
  189. AC_ARG_ENABLE(bgpd,
  190. AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
  191. AC_ARG_ENABLE(ripd,
  192. AS_HELP_STRING([--disable-ripd], [do not build ripd]))
  193. AC_ARG_ENABLE(ripngd,
  194. AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
  195. AC_ARG_ENABLE(ospfd,
  196. AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
  197. AC_ARG_ENABLE(ospf6d,
  198. AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
  199. AC_ARG_ENABLE(babeld,
  200. AS_HELP_STRING([--disable-babeld], [do not build babeld]))
  201. AC_ARG_ENABLE(watchquagga,
  202. AS_HELP_STRING([--disable-watchquagga], [do not build watchquagga]))
  203. AC_ARG_ENABLE(isisd,
  204. AS_HELP_STRING([--enable-isisd], [build isisd]))
  205. AC_ARG_ENABLE(pimd,
  206. AS_HELP_STRING([--enable-pimd], [build pimd]))
  207. AC_ARG_ENABLE(bgp-announce,
  208. AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
  209. AC_ARG_ENABLE(snmp,
  210. AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
  211. AC_ARG_WITH(libpam,
  212. AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
  213. AC_ARG_ENABLE(tcp-zebra,
  214. AS_HELP_STRING([--enable-tcp-zebra], [enable TCP/IP socket connection between zebra and protocol daemon]))
  215. AC_ARG_ENABLE(opaque-lsa,
  216. AS_HELP_STRING([--disable-opaque-lsa],[do not build OSPF Opaque-LSA with OSPFAPI support (RFC2370)]))
  217. AC_ARG_ENABLE(ospfapi,
  218. AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
  219. AC_ARG_ENABLE(ospfclient,
  220. AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
  221. (this is the default if --disable-ospfapi is set)]))
  222. AC_ARG_ENABLE(ospf-te,
  223. AS_HELP_STRING([--disable-ospf-te],[disable Traffic Engineering Extension to OSPF]))
  224. AC_ARG_ENABLE(multipath,
  225. AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
  226. AC_ARG_ENABLE(user,
  227. AS_HELP_STRING([--enable-user=USER], [user to run Quagga suite as (default quagga)]))
  228. AC_ARG_ENABLE(group,
  229. AS_HELP_STRING([--enable-group=GROUP], [group to run Quagga suite as (default quagga)]))
  230. AC_ARG_ENABLE(vty_group,
  231. AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
  232. AC_ARG_ENABLE(configfile_mask,
  233. AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
  234. AC_ARG_ENABLE(logfile_mask,
  235. AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
  236. AC_ARG_ENABLE(rtadv,
  237. AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
  238. AC_ARG_ENABLE(irdp,
  239. AS_HELP_STRING([--enable-irdp], [enable IRDP server support in zebra]))
  240. AC_ARG_ENABLE(isis_topology,
  241. AS_HELP_STRING([--enable-isis-topology], [enable IS-IS topology generator]))
  242. AC_ARG_ENABLE(capabilities,
  243. AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
  244. AC_ARG_ENABLE(rusage,
  245. AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
  246. AC_ARG_ENABLE(gcc_ultra_verbose,
  247. AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
  248. AC_ARG_ENABLE(linux24_tcp_md5,
  249. AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
  250. AC_ARG_ENABLE(gcc-rdynamic,
  251. AS_HELP_STRING([--enable-gcc-rdynamic], [enable linking with -rdynamic for better backtraces (default if gcc)]))
  252. AC_ARG_ENABLE(backtrace,
  253. AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
  254. AC_ARG_ENABLE(time-check,
  255. AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
  256. AC_ARG_ENABLE(pcreposix,
  257. AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
  258. AC_ARG_ENABLE(fpm,
  259. AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
  260. if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
  261. CFLAGS="${CFLAGS} -W -Wcast-qual -Wstrict-prototypes"
  262. CFLAGS="${CFLAGS} -Wmissing-declarations -Wmissing-noreturn"
  263. CFLAGS="${CFLAGS} -Wmissing-format-attribute -Wunreachable-code"
  264. CFLAGS="${CFLAGS} -Wpacked -Wpadded"
  265. fi
  266. if test x"${enable_gcc_rdynamic}" != x"no" ; then
  267. if test x"${enable_gcc_rdynamic}" = x"yes" -o x"$COMPILER" = x"GCC"; then
  268. LDFLAGS="${LDFLAGS} -rdynamic"
  269. fi
  270. fi
  271. if test x"${enable_time_check}" != x"no" ; then
  272. if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
  273. AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
  274. else
  275. AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
  276. fi
  277. fi
  278. if test "${enable_fpm}" = "yes"; then
  279. AC_DEFINE(HAVE_FPM,,Forwarding Plane Manager support)
  280. fi
  281. if test "${enable_tcp_zebra}" = "yes"; then
  282. AC_DEFINE(HAVE_TCP_ZEBRA,,Use TCP for zebra communication)
  283. fi
  284. if test "${enable_opaque_lsa}" != "no"; then
  285. AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
  286. fi
  287. if test "${enable_ospf_te}" != "no"; then
  288. AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
  289. AC_DEFINE(HAVE_OSPF_TE,,OSPF TE)
  290. fi
  291. if test "${enable_linux24_tcp_md5}" = "yes"; then
  292. AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
  293. fi
  294. AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
  295. if test "${enable_rtadv}" != "no"; then
  296. AC_MSG_RESULT(yes)
  297. AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
  298. else
  299. AC_MSG_RESULT(no)
  300. fi
  301. if test "${enable_irdp}" = "yes"; then
  302. AC_DEFINE(HAVE_IRDP,, IRDP )
  303. fi
  304. if test "${enable_isisd}" = "yes" && test "${enable_isis_topology}" = yes; then
  305. AC_DEFINE(TOPOLOGY_GENERATE,,Enable IS-IS topology generator code)
  306. ISIS_TOPOLOGY_INCLUDES="-I\$(srcdir)/topology"
  307. ISIS_TOPOLOGY_DIR="topology"
  308. ISIS_TOPOLOGY_LIB="./topology/libtopology.a"
  309. fi
  310. AC_SUBST(ISIS_TOPOLOGY_INCLUDES)
  311. AC_SUBST(ISIS_TOPOLOGY_DIR)
  312. AC_SUBST(ISIS_TOPOLOGY_LIB)
  313. if test "${enable_user}" = "yes" || test x"${enable_user}" = x""; then
  314. enable_user="quagga"
  315. elif test "${enable_user}" = "no"; then
  316. enable_user="root"
  317. fi
  318. if test "${enable_group}" = "yes" || test x"${enable_group}" = x""; then
  319. enable_group="quagga"
  320. elif test "${enable_group}" = "no"; then
  321. enable_group="root"
  322. fi
  323. if test x"${enable_vty_group}" = x"yes" ; then
  324. AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
  325. elif test x"${enable_vty_group}" != x""; then
  326. if test x"${enable_vty_group}" != x"no"; then
  327. AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
  328. fi
  329. fi
  330. AC_SUBST([enable_user])
  331. AC_SUBST([enable_group])
  332. AC_SUBST([enable_vty_group])
  333. AC_DEFINE_UNQUOTED(QUAGGA_USER, "${enable_user}", Quagga User)
  334. AC_DEFINE_UNQUOTED(QUAGGA_GROUP, "${enable_group}", Quagga Group)
  335. enable_configfile_mask=${enable_configfile_mask:-0600}
  336. AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
  337. enable_logfile_mask=${enable_logfile_mask:-0600}
  338. AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
  339. MULTIPATH_NUM=1
  340. case "${enable_multipath}" in
  341. [[0-9]|[1-9][0-9]])
  342. MULTIPATH_NUM="${enable_multipath}"
  343. ;;
  344. "")
  345. ;;
  346. *)
  347. AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
  348. ;;
  349. esac
  350. AC_SUBST(MULTIPATH_NUM)
  351. dnl -----------------------------------
  352. dnl Add extra version string to package
  353. dnl name, string and version fields.
  354. dnl -----------------------------------
  355. if test "x${EXTRAVERSION}" != "x" ; then
  356. VERSION="${VERSION}${EXTRAVERSION}"
  357. PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
  358. PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
  359. fi
  360. if test "x$with_pkg_git_version" = "xyes"; then
  361. if test -d "${srcdir}/.git"; then
  362. AC_DEFINE(GIT_VERSION, [1], [include git version info])
  363. else with_pkg_git_version="no"
  364. AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
  365. fi
  366. fi
  367. AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
  368. dnl ------------------------------------
  369. dnl Check C keywords and standard types
  370. dnl ------------------------------------
  371. AC_C_CONST
  372. AC_C_INLINE
  373. AC_C_RESTRICT
  374. AC_C_VOLATILE
  375. AC_HEADER_STDC
  376. AC_HEADER_TIME
  377. AC_HEADER_SYS_WAIT
  378. dnl AC_TYPE_PID_T
  379. AC_TYPE_UID_T
  380. AC_TYPE_MODE_T
  381. AC_TYPE_SIZE_T
  382. AC_TYPE_SIGNAL
  383. AC_STRUCT_TM
  384. dnl -------------------------
  385. dnl Check other header files.
  386. dnl -------------------------
  387. AC_CHECK_HEADERS([stropts.h sys/ksym.h sys/times.h sys/select.h \
  388. sys/types.h linux/version.h netdb.h asm/types.h \
  389. sys/cdefs.h sys/param.h limits.h signal.h \
  390. sys/socket.h netinet/in.h time.h sys/time.h])
  391. dnl Utility macro to avoid retyping includes all the time
  392. m4_define([QUAGGA_INCLUDES],
  393. [#ifdef SUNOS_5
  394. #define _XPG4_2
  395. #define __EXTENSIONS__
  396. #endif
  397. #include <stdio.h>
  398. #if STDC_HEADERS
  399. # include <stdlib.h>
  400. # include <stddef.h>
  401. #else
  402. # if HAVE_STDLIB_H
  403. # include <stdlib.h>
  404. # endif
  405. #endif
  406. #if HAVE_SYS_TYPES_H
  407. # include <sys/types.h>
  408. #endif
  409. /* sys/conf.h depends on param.h on FBSD at least */
  410. #if HAVE_SYS_PARAM_H
  411. # include <sys/param.h>
  412. #endif
  413. /* Required for MAXSIG */
  414. #if HAVE_SIGNAL_H
  415. # include <signal.h>
  416. #endif
  417. #if HAVE_SYS_SOCKET_H
  418. # include <sys/socket.h>
  419. #endif
  420. #ifdef __APPLE__
  421. # define __APPLE_USE_RFC_3542
  422. #endif
  423. #if HAVE_NETINET_IN_H
  424. # include <netinet/in.h>
  425. #endif
  426. #ifdef TIME_WITH_SYS_TIME
  427. # include <sys/time.h>
  428. # include <time.h>
  429. #else
  430. # ifdef HAVE_SYS_TIME_H
  431. # include <sys/time.h>
  432. # else
  433. # include <time.h>
  434. # endif
  435. #endif /* TIME_WITH_SYS_TIME */
  436. ])dnl
  437. dnl HAVE_NET_IF_H must be discovered by the time the longer AC_CHECK_HEADERS
  438. dnl round below execution begins, otherwise it doesn't properly detect
  439. dnl HAVE_NETINET6_IN6_VAR_H, HAVE_NET_IF_VAR_H and HAVE_STRUCT_IN6_ALIASREQ
  440. dnl on FreeBSD (BZ#408).
  441. AC_CHECK_HEADERS([net/if.h], [], [], QUAGGA_INCLUDES)
  442. m4_define([QUAGGA_INCLUDES],
  443. QUAGGA_INCLUDES
  444. [#if HAVE_NET_IF_H
  445. # include <net/if.h>
  446. #endif
  447. ])dnl
  448. dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
  449. dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
  450. dnl an additional round for it.
  451. AC_CHECK_HEADERS([net/if_var.h], [], [], QUAGGA_INCLUDES)
  452. m4_define([QUAGGA_INCLUDES],
  453. QUAGGA_INCLUDES
  454. [#if HAVE_NET_IF_VAR_H
  455. # include <net/if_var.h>
  456. #endif
  457. ])dnl
  458. AC_CHECK_HEADERS([sys/un.h netinet/in_systm.h netinet/in_var.h \
  459. net/if_dl.h net/netopt.h net/route.h \
  460. inet/nd.h arpa/inet.h netinet/ip_icmp.h \
  461. fcntl.h stddef.h sys/ioctl.h syslog.h wchar.h wctype.h \
  462. sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
  463. [], [], QUAGGA_INCLUDES)
  464. AC_CHECK_HEADERS([ucontext.h], [], [],
  465. [#ifndef __USE_GNU
  466. #define __USE_GNU
  467. #endif /* __USE_GNU */
  468. QUAGGA_INCLUDES
  469. ])
  470. m4_define([UCONTEXT_INCLUDES],
  471. [#include <ucontext.h>])dnl
  472. AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
  473. [], [], [UCONTEXT_INCLUDES])
  474. AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
  475. [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
  476. [], [], [UCONTEXT_INCLUDES])],
  477. [], [UCONTEXT_INCLUDES])
  478. AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
  479. [], [], [UCONTEXT_INCLUDES])
  480. m4_define([QUAGGA_INCLUDES],
  481. QUAGGA_INCLUDES
  482. [#if HAVE_SYS_UN_H
  483. # include <sys/un.h>
  484. #endif
  485. #if HAVE_NETINET_IN_SYSTM_H
  486. # include <netinet/in_systm.h>
  487. #endif
  488. #if HAVE_NETINET_IN_VAR_H
  489. # include <netinet/in_var.h>
  490. #endif
  491. #if HAVE_NET_IF_DL_H
  492. # include <net/if_dl.h>
  493. #endif
  494. #if HAVE_NET_NETOPT_H
  495. # include <net/netopt.h>
  496. #endif
  497. #if HAVE_NET_ROUTE_H
  498. # include <net/route.h>
  499. #endif
  500. #if HAVE_INET_ND_H
  501. # include <inet/nd.h>
  502. #endif
  503. #if HAVE_ARPA_INET_H
  504. # include <arpa/inet.h>
  505. #endif
  506. /* Required for IDRP */
  507. #if HAVE_NETINET_IP_ICMP_H
  508. # include <netinet/ip_icmp.h>
  509. #endif
  510. ])dnl
  511. dnl V6 headers are checked below, after we check for v6
  512. dnl Some systems (Solaris 2.x) require libnsl (Network Services Library)
  513. case "$host" in
  514. [*-sunos5.[6-7]*] | [*-solaris2.[6-7]*])
  515. opsys=sol2-6
  516. AC_DEFINE(SUNOS_56, 1, SunOS 5.6 to 5.7)
  517. AC_DEFINE(SUNOS_5, 1, SunOS 5)
  518. AC_CHECK_LIB(xnet, main)
  519. CURSES=-lcurses
  520. SOLARIS="solaris"
  521. ;;
  522. [*-sunos5.[8-9]] \
  523. | [*-sunos5.1[0-9]] \
  524. | [*-sunos5.1[0-9].[0-9]] \
  525. | [*-solaris2.[8-9]] \
  526. | [*-solaris2.1[0-9]] \
  527. | [*-solaris2.1[0-9].[0-9]])
  528. opsys=sol8
  529. AC_DEFINE(SUNOS_59, 1, [SunOS 5.8 up])
  530. AC_DEFINE(SUNOS_5, 1, [SunOS 5])
  531. AC_CHECK_LIB(socket, main)
  532. AC_CHECK_LIB(nsl, main)
  533. AC_CHECK_LIB(umem, main)
  534. AC_CHECK_FUNCS([printstack],
  535. [AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
  536. AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
  537. ])
  538. CURSES=-lcurses
  539. SOLARIS="solaris"
  540. ;;
  541. *-sunos5* | *-solaris2*)
  542. AC_DEFINE(SUNOS_5,,SunOS 5, Unknown SunOS)
  543. AC_CHECK_LIB(socket, main)
  544. AC_CHECK_LIB(nsl, main)
  545. CURSES=-lcurses
  546. SOLARIS="solaris"
  547. ;;
  548. *-linux*)
  549. opsys=gnu-linux
  550. AC_DEFINE(GNU_LINUX,,GNU Linux)
  551. ;;
  552. *-openbsd*)
  553. opsys=openbsd
  554. AC_DEFINE(OPEN_BSD,,OpenBSD)
  555. ;;
  556. esac
  557. AC_SYS_LARGEFILE
  558. dnl ---------------------
  559. dnl Integrated VTY option
  560. dnl ---------------------
  561. case "${enable_vtysh}" in
  562. "yes") VTYSH="vtysh";
  563. AC_DEFINE(VTYSH,,VTY shell)
  564. dnl Vtysh uses libreadline, which looks for termcap functions at
  565. dnl configure time. We follow readlines search order.
  566. dnl The required procedures are in libtermcap on NetBSD, in
  567. dnl [TODO] on Linux, and in [TODO] on Solaris.
  568. AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
  569. [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
  570. [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
  571. [AC_CHECK_LIB(ncurses, tputs,
  572. LIBREADLINE="$LIBREADLINE -lncurses")]
  573. )]
  574. )]
  575. )
  576. AC_CHECK_LIB(readline, main, LIBREADLINE="$LIBREADLINE -lreadline",,
  577. "$LIBREADLINE")
  578. if test $ac_cv_lib_readline_main = no; then
  579. AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
  580. fi
  581. AC_CHECK_HEADER(readline/history.h)
  582. if test $ac_cv_header_readline_history_h = no;then
  583. AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
  584. fi
  585. AC_CHECK_LIB(readline, rl_completion_matches,
  586. LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
  587. if test $ac_cv_lib_readline_rl_completion_matches = no; then
  588. AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
  589. fi
  590. ;;
  591. "no" ) VTYSH="";;
  592. * ) ;;
  593. esac
  594. AC_SUBST(LIBREADLINE)
  595. AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
  596. dnl ----------
  597. dnl PAM module
  598. dnl
  599. dnl Quagga detects the PAM library it is built against by checking for a
  600. dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
  601. dnl is known to #include pam_appl.h, the standard header of a PAM library, and
  602. dnl openpam.h doesn't do that, although depends on the header too. Hence a
  603. dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
  604. dnl of OpenPAM.
  605. dnl ----------
  606. if test "$with_libpam" = "yes"; then
  607. AC_CHECK_HEADER([security/pam_misc.h],
  608. [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
  609. AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
  610. pam_conv_func="misc_conv"
  611. ],
  612. [], QUAGGA_INCLUDES)
  613. AC_CHECK_HEADER([security/openpam.h],
  614. [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
  615. AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
  616. pam_conv_func="openpam_ttyconv"
  617. ],
  618. [], QUAGGA_INCLUDES[#include <security/pam_appl.h>])
  619. if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
  620. AC_MSG_WARN([*** pam support will not be built ***])
  621. with_libpam="no"
  622. fi
  623. fi
  624. if test "$with_libpam" = "yes"; then
  625. dnl took this test from proftpds configure.in and suited to our needs
  626. dnl -------------------------------------------------------------------------
  627. dnl
  628. dnl This next check looks funky due to a linker problem with some versions
  629. dnl of the PAM library. Prior to 0.72 release, the Linux PAM shared library
  630. dnl omitted requiring libdl linking information. PAM-0.72 or better ships
  631. dnl with RedHat 6.2 and Debian 2.2 or better.
  632. AC_CHECK_LIB(pam, pam_start,
  633. [AC_CHECK_LIB(pam, $pam_conv_func,
  634. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  635. LIBPAM="-lpam"],
  636. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  637. LIBPAM="-lpam -lpam_misc"]
  638. )
  639. ],
  640. [AC_CHECK_LIB(pam, pam_end,
  641. [AC_CHECK_LIB(pam, $pam_conv_func,
  642. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  643. LIBPAM="-lpam -ldl"],
  644. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  645. LIBPAM="-lpam -ldl -lpam_misc"]
  646. )
  647. ],AC_MSG_WARN([*** pam support will not be built ***]),
  648. [-ldl])
  649. ]
  650. )
  651. fi
  652. AC_SUBST(LIBPAM)
  653. dnl -------------------------------
  654. dnl Endian-ness check
  655. dnl -------------------------------
  656. AC_WORDS_BIGENDIAN
  657. dnl -------------------------------
  658. dnl check the size in byte of the C
  659. dnl -------------------------------
  660. dnl AC_CHECK_SIZEOF(char)
  661. dnl AC_CHECK_SIZEOF(int)
  662. dnl AC_CHECK_SIZEOF(short)
  663. dnl AC_CHECK_SIZEOF(long)
  664. dnl ----------------------------
  665. dnl check existance of functions
  666. dnl ----------------------------
  667. AC_FUNC_CHOWN
  668. AC_FUNC_FNMATCH
  669. AC_FUNC_FORK
  670. AC_FUNC_MEMCMP
  671. AC_FUNC_MKTIME
  672. AC_FUNC_STRFTIME
  673. AC_FUNC_STAT
  674. AC_FUNC_SELECT_ARGTYPES
  675. AC_FUNC_STRFTIME
  676. dnl Avoid AC_FUNC_STRNLEN because it pulls in AC_SYSTEM_EXTENSIONS which
  677. dnl can lead to strange side effects. So we just check for strnlen
  678. dnl directly, see below.
  679. dnl AC_FUNC_STRNLENdnl
  680. AC_FUNC_VPRINTF
  681. dnl -------------------------------
  682. dnl bgpd needs pow() and hence libm
  683. dnl -------------------------------
  684. TMPLIBS="$LIBS"
  685. AC_CHECK_HEADER([math.h],
  686. [AC_CHECK_LIB([m], [pow],
  687. [LIBM="-lm"
  688. LIBS="$LIBS $LIBM"
  689. AC_DEFINE(HAVE_LIBM,, Have libm)
  690. AC_CHECK_FUNCS(pow,[],[LIBM=""])
  691. ])
  692. ])
  693. if test x"$LIBM" = x ; then
  694. AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
  695. fi
  696. LIBS="$TMPLIBS"
  697. AC_SUBST(LIBM)
  698. dnl ---------------
  699. dnl other functions
  700. dnl ---------------
  701. AC_CHECK_FUNCS([dup2 ftruncate getcwd gethostbyname getpagesize gettimeofday \
  702. inet_ntoa inet_aton strnlen \
  703. memchr memmove memset select socket \
  704. strcasecmp strchr strcspn strdup strerror \
  705. strncasecmp strndup strrchr strspn strstr \
  706. strtol strtoul strlcat strlcpy \
  707. daemon snprintf vsnprintf \
  708. if_nametoindex if_indextoname getifaddrs \
  709. uname fcntl])
  710. AC_CHECK_FUNCS(setproctitle, ,
  711. [AC_CHECK_LIB(util, setproctitle,
  712. [LIBS="$LIBS -lutil"
  713. AC_DEFINE(HAVE_SETPROCTITLE,, Have setproctitle)
  714. ]
  715. )
  716. ]
  717. )
  718. dnl ------------------------------------
  719. dnl Determine routing get and set method
  720. dnl ------------------------------------
  721. AC_MSG_CHECKING(zebra between kernel interface method)
  722. if test x"$opsys" = x"gnu-linux"; then
  723. AC_MSG_RESULT(netlink)
  724. RT_METHOD=rt_netlink.o
  725. AC_DEFINE(HAVE_NETLINK,,netlink)
  726. netlink=yes
  727. else
  728. AC_MSG_RESULT(Route socket)
  729. KERNEL_METHOD="kernel_socket.o"
  730. RT_METHOD="rt_socket.o"
  731. fi
  732. AC_SUBST(RT_METHOD)
  733. AC_SUBST(KERNEL_METHOD)
  734. AM_CONDITIONAL([HAVE_NETLINK], [test "x$netlink" = "xyes"])
  735. dnl --------------------------
  736. dnl Determine IS-IS I/O method
  737. dnl --------------------------
  738. AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
  739. AC_DEFINE(ISIS_METHOD_DLPI, 2, [ constant value for isis method dlpi ])
  740. AC_DEFINE(ISIS_METHOD_BPF, 3, [ constant value for isis method bpf ])
  741. AC_CHECK_HEADER(net/bpf.h)
  742. AC_CHECK_HEADER(sys/dlpi.h)
  743. AC_MSG_CHECKING(zebra IS-IS I/O method)
  744. if test x"$opsys" = x"gnu-linux"; then
  745. AC_MSG_RESULT(pfpacket)
  746. ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
  747. elif test x"$opsys" = x"sol2-6" -o x"$opsys" = x"sol8"; then
  748. AC_MSG_RESULT(DLPI)
  749. ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
  750. else
  751. if test $ac_cv_header_net_bpf_h = no; then
  752. if test $ac_cv_header_sys_dlpi_h = no; then
  753. AC_MSG_RESULT(none)
  754. AC_MSG_WARN([*** IS-IS support will not be built ***])
  755. ISISD=""
  756. else
  757. AC_MSG_RESULT(DLPI)
  758. fi
  759. ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
  760. else
  761. AC_MSG_RESULT(BPF)
  762. ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
  763. fi
  764. fi
  765. AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
  766. dnl ------------------------------------
  767. dnl check for broken CMSG_FIRSTHDR macro
  768. dnl ------------------------------------
  769. AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
  770. AC_RUN_IFELSE([AC_LANG_SOURCE([[
  771. #ifdef SUNOS_5
  772. #define _XPG4_2
  773. #define __EXTENSIONS__
  774. #endif
  775. #ifdef HAVE_STDLIB_H
  776. # include <stdlib.h>
  777. #endif
  778. #ifdef HAVE_SYS_TYPES_H
  779. #include <sys/types.h>
  780. #endif
  781. #ifdef HAVE_SYS_SOCKET_H
  782. #include <sys/socket.h>
  783. #endif
  784. main()
  785. {
  786. struct msghdr msg;
  787. char buf[4];
  788. msg.msg_control = buf;
  789. msg.msg_controllen = 0;
  790. if (CMSG_FIRSTHDR(&msg) != NULL)
  791. exit(0);
  792. exit (1);
  793. }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
  794. [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
  795. dnl ------------------------------
  796. dnl check kernel route read method
  797. dnl ------------------------------
  798. AC_CACHE_CHECK([route read method], [quagga_cv_rtread_method],
  799. [if test "x$netlink" = xyes; then
  800. quagga_cv_rtread_method="netlink"
  801. else
  802. for quagga_cv_rtread_method in /dev/ip /dev/null;
  803. do
  804. test x`ls $quagga_cv_rtread_method 2>/dev/null` = x"$quagga_cv_rtread_method" && break
  805. done
  806. case $quagga_cv_rtread_method in
  807. "/dev/ip")
  808. case "$host" in
  809. *-freebsd*) quagga_cv_rtread_method="sysctl";;
  810. *) quagga_cv_rtread_method="getmsg";;
  811. esac;;
  812. *)
  813. quagga_cv_rtread_method="sysctl";;
  814. esac
  815. fi])
  816. RTREAD_METHOD=rtread_${quagga_cv_rtread_method}.o
  817. AC_SUBST(RTREAD_METHOD)
  818. dnl -----------------------------
  819. dnl check interface lookup method
  820. dnl -----------------------------
  821. IOCTL_METHOD=ioctl.o
  822. AC_MSG_CHECKING(interface looking up method)
  823. if test "$netlink" = yes; then
  824. AC_MSG_RESULT(netlink)
  825. IF_METHOD=if_netlink.o
  826. elif test "$opsys" = "sol2-6";then
  827. AC_MSG_RESULT(Solaris GIF)
  828. IF_METHOD=if_ioctl.o
  829. elif test "$opsys" = "sol8";then
  830. AC_MSG_RESULT(Solaris GLIF)
  831. IF_METHOD=if_ioctl_solaris.o
  832. IOCTL_METHOD=ioctl_solaris.o
  833. elif test "$opsys" = "openbsd";then
  834. AC_MSG_RESULT(openbsd)
  835. IF_METHOD=if_ioctl.o
  836. elif grep NET_RT_IFLIST /usr/include/sys/socket.h >/dev/null 2>&1; then
  837. AC_MSG_RESULT(sysctl)
  838. IF_METHOD=if_sysctl.o
  839. AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
  840. else
  841. AC_MSG_RESULT(ioctl)
  842. IF_METHOD=if_ioctl.o
  843. fi
  844. AC_SUBST(IF_METHOD)
  845. AC_SUBST(IOCTL_METHOD)
  846. dnl ---------------------------------------------------------------
  847. dnl figure out how to specify an interface in multicast sockets API
  848. dnl ---------------------------------------------------------------
  849. AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], QUAGGA_INCLUDES)
  850. AC_MSG_CHECKING([for BSD struct ip_mreq hack])
  851. AC_TRY_COMPILE([#ifdef HAVE_SYS_PARAM_H
  852. #include <sys/param.h>
  853. #endif],[#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__)
  854. return (0);
  855. #else
  856. #error No support for BSD struct ip_mreq hack detected
  857. #endif],[AC_MSG_RESULT(yes)
  858. AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
  859. AC_MSG_RESULT(no))
  860. AC_MSG_CHECKING([for RFC3678 protocol-independed API])
  861. AC_TRY_COMPILE([
  862. #include <sys/types.h>
  863. #include <netinet/in.h>
  864. ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
  865. ], [AC_MSG_RESULT(yes)
  866. AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
  867. AC_MSG_RESULT(no))
  868. dnl ---------------------------------------------------------------
  869. dnl figure out how to check link-state
  870. dnl ---------------------------------------------------------------
  871. AC_CHECK_HEADER([net/if.h],
  872. [AC_CHECK_HEADER( [net/if_media.h],
  873. [m4_define([LINK_DETECT_INCLUDES],
  874. QUAGGA_INCLUDES
  875. [#include <net/if_media.h>
  876. ])
  877. AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
  878. AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
  879. [], LINK_DETECT_INCLUDES)],
  880. [],
  881. QUAGGA_INCLUDES)],
  882. [], QUAGGA_INCLUDES )
  883. dnl ---------------------------------------------------------------
  884. dnl Additional, newer way to check link-state using ifi_link_state.
  885. dnl Not available in all BSD's when ifmediareq available
  886. dnl ---------------------------------------------------------------
  887. AC_CHECK_HEADER([net/if.h],
  888. AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
  889. AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
  890. [], QUAGGA_INCLUDES),
  891. ,)
  892. dnl ------------------------
  893. dnl TCP_MD5SIG socket option
  894. dnl ------------------------
  895. AC_CHECK_HEADER([netinet/tcp.h],
  896. [m4_define([MD5_INCLUDES],
  897. QUAGGA_INCLUDES
  898. [#include <netinet/tcp.h>
  899. ])
  900. AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
  901. [],
  902. QUAGGA_INCLUDES)
  903. if test $ac_cv_have_decl_TCP_MD5SIG = no; then
  904. AC_CHECK_HEADER([linux/tcp.h],
  905. [m4_define([MD5_INCLUDES],
  906. QUAGGA_INCLUDES
  907. [#include <linux/tcp.h>
  908. ])
  909. AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
  910. fi
  911. dnl -----------------------------
  912. dnl check ipforward detect method
  913. dnl -----------------------------
  914. AC_CACHE_CHECK([ipforward method], [quagga_cv_ipforward_method],
  915. [if test x$cross_compiling = xyes; then
  916. if test x"$opsys" = x"gnu-linux"; then
  917. quagga_cv_ipforward_method=/proc/net/snmp
  918. else
  919. quagga_cv_ipforward_method=/dev/ip
  920. fi
  921. else
  922. for quagga_cv_ipforward_method in /proc/net/snmp /dev/ip /dev/null;
  923. do
  924. test x`ls $quagga_cv_ipforward_method 2>/dev/null` = x"$quagga_cv_ipforward_method" && break
  925. done
  926. fi
  927. case $quagga_cv_ipforward_method in
  928. "/proc/net/snmp") quagga_cv_ipforward_method="proc";;
  929. "/dev/ip")
  930. case "$host" in
  931. *-freebsd*) quagga_cv_ipforward_method="sysctl";;
  932. *) quagga_cv_ipforward_method="solaris";;
  933. esac;;
  934. *) quagga_cv_ipforward_method="sysctl";;
  935. esac])
  936. IPFORWARD=ipforward_${quagga_cv_ipforward_method}.o
  937. AC_SUBST(IPFORWARD)
  938. AC_CHECK_FUNCS(getaddrinfo, [have_getaddrinfo=yes], [have_getaddrinfo=no])
  939. dnl ----------
  940. dnl IPv6 check
  941. dnl ----------
  942. AC_MSG_CHECKING(whether does this OS have IPv6 stack)
  943. if test "${enable_ipv6}" = "no"; then
  944. AC_MSG_RESULT(disabled)
  945. else
  946. dnl ---------
  947. dnl KAME IPv6
  948. dnl ---------
  949. if grep WIDE /usr/include/netinet6/in6.h >/dev/null 2>&1; then
  950. zebra_cv_ipv6=yes
  951. AC_DEFINE(KAME,1,KAME IPv6)
  952. AC_MSG_RESULT(KAME)
  953. dnl ------------------------------------
  954. dnl Solaris 9, 10 and potentially higher
  955. dnl ------------------------------------
  956. elif test x"$opsys" = x"sol8"; then
  957. zebra_cv_ipv6=yes;
  958. AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
  959. AC_MSG_RESULT(Solaris IPv6)
  960. dnl ----------
  961. dnl Linux IPv6
  962. dnl ----------
  963. elif test x"$opsys" = x"gnu-linux"; then
  964. zebra_cv_ipv6=yes
  965. AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
  966. AC_MSG_RESULT(Linux IPv6)
  967. else
  968. AC_MSG_RESULT(Unknown OS)
  969. fi
  970. fi
  971. if test x"$zebra_cv_ipv6" = x"yes"; then
  972. AC_DEFINE(HAVE_IPV6,1,IPv6)
  973. RIPNGD="ripngd"
  974. OSPF6D="ospf6d"
  975. elif test x"${enable_ipv6}" = x"yes"; then
  976. AC_MSG_ERROR([--enable-ipv6 given but IPv6 stack unknown])
  977. fi
  978. dnl ------------------
  979. dnl IPv6 header checks
  980. dnl ------------------
  981. if test "x${zebra_cv_ipv6}" = "xyes"; then
  982. AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h netinet/icmp6.h \
  983. netinet6/in6_var.h netinet6/nd6.h], [], [],
  984. QUAGGA_INCLUDES)
  985. fi
  986. m4_define([QUAGGA_INCLUDES],dnl
  987. QUAGGA_INCLUDES
  988. [#if HAVE_NETINET6_IN6_H
  989. #include <netinet6/in6.h>
  990. #endif
  991. #if HAVE_NETINET_IN6_VAR_H
  992. #include <netinet/in6_var.h>
  993. #endif
  994. #if HAVE_NETINET_ICMP6_H
  995. # include <netinet/icmp6.h>
  996. #endif
  997. #if HAVE_NETINET6_IN6_VAR_H
  998. # include <netinet6/in6_var.h>
  999. #endif
  1000. #if HAVE_NETINET6_ND6_H
  1001. # include <netinet6/nd6.h>
  1002. #endif
  1003. ])dnl
  1004. dnl disable doc check
  1005. if test "${enable_doc}" = "no";then
  1006. DOC=""
  1007. else
  1008. DOC="doc"
  1009. fi
  1010. dnl --------------------
  1011. dnl Daemon disable check
  1012. dnl --------------------
  1013. if test "${enable_zebra}" = "no";then
  1014. ZEBRA=""
  1015. else
  1016. ZEBRA="zebra"
  1017. fi
  1018. AM_CONDITIONAL(ZEBRA, test "x$ZEBRA" = "xzebra")
  1019. if test "${enable_bgpd}" = "no";then
  1020. BGPD=""
  1021. else
  1022. BGPD="bgpd"
  1023. fi
  1024. AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
  1025. if test "${enable_ripd}" = "no";then
  1026. RIPD=""
  1027. else
  1028. RIPD="ripd"
  1029. fi
  1030. AM_CONDITIONAL(RIPD, test "x$RIPD" = "xripd")
  1031. if test "${enable_ospfd}" = "no";then
  1032. OSPFD=""
  1033. else
  1034. OSPFD="ospfd"
  1035. fi
  1036. AM_CONDITIONAL(OSPFD, test "x$OSPFD" = "xospfd")
  1037. if test "${enable_babeld}" = "no";then
  1038. BABELD=""
  1039. else
  1040. BABELD="babeld"
  1041. fi
  1042. AM_CONDITIONAL(BABELD, test "x$BABELD" = "xbabeld")
  1043. if test "${enable_watchquagga}" = "no";then
  1044. WATCHQUAGGA=""
  1045. else
  1046. WATCHQUAGGA="watchquagga"
  1047. fi
  1048. AM_CONDITIONAL(WATCHQUAGGA, test "x$WATCHQUAGGA" = "xwatchquagga")
  1049. OSPFCLIENT=""
  1050. if test "${enable_opaque_lsa}" != "no"; then
  1051. if test "${enable_ospfapi}" != "no";then
  1052. AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
  1053. if test "${enable_ospfclient}" != "no";then
  1054. OSPFCLIENT="ospfclient"
  1055. fi
  1056. fi
  1057. fi
  1058. AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
  1059. case "${enable_ripngd}" in
  1060. "yes") RIPNGD="ripngd";;
  1061. "no" ) RIPNGD="";;
  1062. * ) ;;
  1063. esac
  1064. AM_CONDITIONAL(RIPNGD, test "x$RIPNGD" = "xripngd")
  1065. case "${enable_ospf6d}" in
  1066. "yes") OSPF6D="ospf6d";;
  1067. "no" ) OSPF6D="";;
  1068. * ) ;;
  1069. esac
  1070. AM_CONDITIONAL(OSPF6D, test "x$OSPF6D" = "xospf6d")
  1071. case "${enable_isisd}" in
  1072. "yes") ISISD="isisd";;
  1073. "no" ) ISISD="";;
  1074. * ) ;;
  1075. esac
  1076. AM_CONDITIONAL(ISISD, test "x$ISISD" = "xisisd")
  1077. case "${enable_pimd}" in
  1078. "yes") PIMD="pimd";;
  1079. "no" ) PIMD="";;
  1080. * ) ;;
  1081. esac
  1082. AM_CONDITIONAL(PIMD, test "x$PIMD" = "xpimd")
  1083. if test "${enable_bgp_announce}" = "no";then
  1084. AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
  1085. else
  1086. AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
  1087. fi
  1088. AC_SUBST(DOC)
  1089. AC_SUBST(ZEBRA)
  1090. AC_SUBST(BGPD)
  1091. AC_SUBST(RIPD)
  1092. AC_SUBST(RIPNGD)
  1093. AC_SUBST(OSPFD)
  1094. AC_SUBST(OSPF6D)
  1095. AC_SUBST(BABELD)
  1096. AC_SUBST(WATCHQUAGGA)
  1097. AC_SUBST(ISISD)
  1098. AC_SUBST(PIMD)
  1099. AC_SUBST(SOLARIS)
  1100. AC_SUBST(VTYSH)
  1101. AC_SUBST(INCLUDES)
  1102. AC_SUBST(CURSES)
  1103. AC_SUBST(OSPFCLIENT)
  1104. AC_SUBST(OSPFAPI)
  1105. AC_CHECK_LIB(c, inet_ntop, [AC_DEFINE(HAVE_INET_NTOP,,inet_ntop)])
  1106. AC_CHECK_LIB(c, inet_pton, [AC_DEFINE(HAVE_INET_PTON,,inet_pton)])
  1107. AC_CHECK_LIB(crypt, crypt)
  1108. AC_CHECK_LIB(resolv, res_init)
  1109. dnl ---------------------------
  1110. dnl check system has PCRE regexp
  1111. dnl ---------------------------
  1112. if test "x$enable_pcreposix" = "xyes"; then
  1113. AC_CHECK_LIB(pcreposix, pcreposix_regexec, ,[enable_pcreposix=no
  1114. AC_MSG_WARN([*** falling back to other regex library ***]) ])
  1115. fi
  1116. if test "x$enable_pcreposix" != "xyes"; then
  1117. dnl ---------------------------
  1118. dnl check system has GNU regexp
  1119. dnl ---------------------------
  1120. AC_MSG_CHECKING(whether system has GNU regex)
  1121. AC_CHECK_LIB(c, regexec,
  1122. [AC_DEFINE(HAVE_GNU_REGEX,,GNU regexp library)
  1123. LIB_REGEX=""],
  1124. [LIB_REGEX="regex.o"])
  1125. fi
  1126. AC_SUBST(HAVE_LIBPCREPOSIX)
  1127. AC_SUBST(LIB_REGEX)
  1128. dnl ------------------
  1129. dnl check Net-SNMP library
  1130. dnl ------------------
  1131. if test "${enable_snmp}" != ""; then
  1132. AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
  1133. if test x"$NETSNMP_CONFIG" = x"no"; then
  1134. AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
  1135. fi
  1136. LIBS="$LIBS `${NETSNMP_CONFIG} --agent-libs`"
  1137. CFLAGS="`${NETSNMP_CONFIG} --base-cflags` $CFLAGS"
  1138. AC_MSG_CHECKING([whether we can link to Net-SNMP])
  1139. AC_LINK_IFELSE([AC_LANG_PROGRAM([
  1140. int main(void);
  1141. ],
  1142. [
  1143. {
  1144. return 0;
  1145. }
  1146. ])],[AC_MSG_RESULT(yes)],[
  1147. AC_MSG_RESULT(no)
  1148. AC_MSG_ERROR([--enable-snmp given but not usable])])
  1149. AC_DEFINE(HAVE_SNMP,,SNMP)
  1150. case "${enable_snmp}" in
  1151. yes)
  1152. SNMP_METHOD=agentx
  1153. ;;
  1154. smux|agentx)
  1155. SNMP_METHOD="${enable_snmp}"
  1156. ;;
  1157. *)
  1158. AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
  1159. ;;
  1160. esac
  1161. AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
  1162. AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
  1163. AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
  1164. fi
  1165. dnl ---------------------------
  1166. dnl sockaddr and netinet checks
  1167. dnl ---------------------------
  1168. AC_CHECK_TYPES([struct sockaddr, struct sockaddr_in,
  1169. struct sockaddr_in6, struct sockaddr_un, struct sockaddr_dl,
  1170. socklen_t, struct vifctl, struct mfcctl, struct sioc_sg_req,
  1171. vifi_t, struct sioc_vif_req, struct igmpmsg,
  1172. struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
  1173. struct nd_opt_adv_interval, struct rt_addrinfo,
  1174. struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
  1175. [], [], QUAGGA_INCLUDES)
  1176. AC_CHECK_MEMBERS([struct sockaddr.sa_len,
  1177. struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
  1178. struct sockaddr_in6.sin6_scope_id,
  1179. struct sockaddr_dl.sdl_len,
  1180. struct if6_aliasreq.ifra_lifetime,
  1181. struct nd_opt_adv_interval.nd_opt_ai_type],
  1182. [], [], QUAGGA_INCLUDES)
  1183. dnl ---------------------------
  1184. dnl IRDP/pktinfo/icmphdr checks
  1185. dnl ---------------------------
  1186. AC_CHECK_TYPES([struct in_pktinfo],
  1187. [AC_CHECK_TYPES([struct icmphdr],
  1188. [if test "${enable_irdp}" != "no"; then
  1189. AC_DEFINE(HAVE_IRDP,, IRDP)
  1190. fi],
  1191. [if test "${enable_irdp}" = "yes"; then
  1192. AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
  1193. fi], [QUAGGA_INCLUDES])],
  1194. [if test "${enable_irdp}" = "yes"; then
  1195. AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
  1196. fi], [QUAGGA_INCLUDES])
  1197. dnl -----------------------
  1198. dnl checking for IP_PKTINFO
  1199. dnl -----------------------
  1200. AC_MSG_CHECKING(for IP_PKTINFO)
  1201. AC_TRY_COMPILE([#include <netdb.h>], [
  1202. int opt = IP_PKTINFO;
  1203. ], [
  1204. AC_MSG_RESULT(yes)
  1205. AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
  1206. ], [
  1207. AC_MSG_RESULT(no)
  1208. ])
  1209. dnl ---------------------------
  1210. dnl checking for IP_RECVDSTADDR
  1211. dnl ---------------------------
  1212. AC_MSG_CHECKING(for IP_RECVDSTADDR)
  1213. AC_TRY_COMPILE([#include <netinet/in.h>], [
  1214. int opt = IP_RECVDSTADDR;
  1215. ], [
  1216. AC_MSG_RESULT(yes)
  1217. AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
  1218. ], [
  1219. AC_MSG_RESULT(no)
  1220. ])
  1221. dnl ----------------------
  1222. dnl checking for IP_RECVIF
  1223. dnl ----------------------
  1224. AC_MSG_CHECKING(for IP_RECVIF)
  1225. AC_TRY_COMPILE([#include <netinet/in.h>], [
  1226. int opt = IP_RECVIF;
  1227. ], [
  1228. AC_MSG_RESULT(yes)
  1229. AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
  1230. ], [
  1231. AC_MSG_RESULT(no)
  1232. ])
  1233. dnl --------------------------------------
  1234. dnl checking for getrusage struct and call
  1235. dnl --------------------------------------
  1236. if test "${enable_rusage}" != "no"; then
  1237. AC_MSG_CHECKING(whether getrusage is available)
  1238. AC_TRY_COMPILE([#include <sys/resource.h>],[struct rusage ac_x; getrusage (RUSAGE_SELF, &ac_x);],
  1239. [AC_MSG_RESULT(yes)
  1240. AC_DEFINE(HAVE_RUSAGE,,rusage)],
  1241. AC_MSG_RESULT(no))
  1242. fi
  1243. dnl --------------------------------------
  1244. dnl checking for clock_time monotonic struct and call
  1245. dnl --------------------------------------
  1246. AC_CHECK_DECL(CLOCK_MONOTONIC,
  1247. [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
  1248. AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
  1249. ], [AC_MSG_RESULT(no)], [QUAGGA_INCLUDES])
  1250. dnl -------------------
  1251. dnl capabilities checks
  1252. dnl -------------------
  1253. if test "${enable_capabilities}" != "no"; then
  1254. AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
  1255. AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
  1256. [AC_MSG_RESULT(yes)
  1257. AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
  1258. quagga_ac_keepcaps="yes"],
  1259. AC_MSG_RESULT(no)
  1260. )
  1261. if test x"${quagga_ac_keepcaps}" = x"yes"; then
  1262. AC_CHECK_HEADERS(sys/capability.h)
  1263. fi
  1264. if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
  1265. AC_CHECK_LIB(cap, cap_init,
  1266. [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
  1267. LIBCAP="-lcap"
  1268. quagga_ac_lcaps="yes"]
  1269. )
  1270. else
  1271. AC_CHECK_HEADERS(priv.h,
  1272. [AC_MSG_CHECKING(Solaris style privileges are available)
  1273. AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
  1274. [AC_MSG_RESULT(yes)
  1275. AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
  1276. quagga_ac_scaps="yes"],
  1277. AC_MSG_RESULT(no)
  1278. )
  1279. ]
  1280. )
  1281. fi
  1282. if test x"${quagga_ac_scaps}" = x"yes" \
  1283. -o x"${quagga_ac_lcaps}" = x"yes"; then
  1284. AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
  1285. fi
  1286. fi
  1287. AC_SUBST(LIBCAP)
  1288. dnl ---------------------------------------------------------------------------
  1289. dnl http://www.gnu.org/software/autoconf-archive/ax_sys_weak_alias.html
  1290. dnl Check for and set one of the following = 1
  1291. dnl HAVE_SYS_WEAK_ALIAS_ATTRIBUTE
  1292. dnl HAVE_SYS_WEAK_ALIAS_PRAGMA
  1293. dnl HAVE_SYS_WEAK_ALIAS_HPSECONDARY
  1294. dnl HAVE_SYS_WEAK_ALIAS_CRIDUPLICATE
  1295. dnl If any scheme is found, set
  1296. dnl HAVE_SYS_WEAK_ALIAS=1
  1297. dnl The following variable is set to text value
  1298. dnl WEAK_ALIAS = "attribute" || "pragma" || "hpsecondary" || "criduplicate" || "no"
  1299. dnl If weak alias can cross object file boundaries
  1300. dnl WEAK_ALIAS_CROSSFILE = "yes" || "no"
  1301. dnl ---------------------------------------------------------------------------
  1302. AX_SYS_WEAK_ALIAS
  1303. dnl ---------------------------
  1304. dnl check for glibc 'backtrace'
  1305. dnl ---------------------------
  1306. if test x"${enable_backtrace}" != x"no" ; then
  1307. backtrace_ok=no
  1308. AC_CHECK_HEADER([execinfo.h], [
  1309. AC_SEARCH_LIBS([backtrace], [execinfo], [
  1310. AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
  1311. AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
  1312. backtrace_ok=yes
  1313. ],, [-lm])
  1314. ])
  1315. if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
  1316. dnl user explicitly requested backtrace but we failed to find support
  1317. AC_MSG_FAILURE([failed to find backtrace support])
  1318. fi
  1319. fi
  1320. dnl -----------------------------------------
  1321. dnl check for malloc mallinfo struct and call
  1322. dnl this must try and link using LIBS, in
  1323. dnl order to check no alternative allocator
  1324. dnl has been specified, which might not provide
  1325. dnl mallinfo, e.g. such as Umem on Solaris.
  1326. dnl -----------------------------------------
  1327. AC_CHECK_HEADER([malloc.h],
  1328. [AC_MSG_CHECKING(whether mallinfo is available)
  1329. AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
  1330. [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
  1331. [AC_MSG_RESULT(yes)
  1332. AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
  1333. AC_MSG_RESULT(no)
  1334. )
  1335. ], [], QUAGGA_INCLUDES)
  1336. dnl ----------
  1337. dnl configure date
  1338. dnl ----------
  1339. CONFDATE=`date '+%Y%m%d'`
  1340. AC_SUBST(CONFDATE)
  1341. dnl Conditionally enable PIE support for GNU toolchains.
  1342. AC_ARG_ENABLE(pie, AS_HELP_STRING([--disable-pie], [Do not build tools as a Position Independent Executables]))
  1343. if test "$enable_pie" != "no"; then
  1344. AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
  1345. save_CFLAGS=$CFLAGS
  1346. save_LDFLAGS=$LDFLAGS
  1347. CFLAGS="$CFLAGS -fPIE"
  1348. LDFLAGS="$LDFLAGS -pie"
  1349. AC_LINK_IFELSE([AC_LANG_SOURCE([[static int foo[30000]; int main () { return 0; }]])],
  1350. [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no]
  1351. )
  1352. CFLAGS=$save_CFLAGS
  1353. LDFLAGS=$save_LDFLAGS
  1354. ])
  1355. if test "$ap_cv_cc_pie" = "yes"; then
  1356. PICFLAGS="-fPIE"
  1357. PILDFLAGS="-pie"
  1358. fi
  1359. fi
  1360. AC_SUBST(PICFLAGS)
  1361. AC_SUBST(PILDFLAGS)
  1362. dnl -------
  1363. dnl DejaGNU
  1364. dnl -------
  1365. if test x"$DEJAGNU" = x
  1366. then
  1367. DEJAGNU="\$(top_srcdir)/tests/global-conf.exp"
  1368. fi
  1369. RUNTESTDEFAULTFLAGS="-x --tool \$\$tool"
  1370. AC_SUBST(DEJAGNU)
  1371. AC_SUBST(RUNTESTDEFAULTFLAGS)
  1372. dnl ------------------------------
  1373. dnl set paths for state directory
  1374. dnl ------------------------------
  1375. AC_MSG_CHECKING(directory to use for state file)
  1376. if test "${prefix}" = "NONE"; then
  1377. quagga_statedir_prefix="";
  1378. else
  1379. quagga_statedir_prefix=${prefix}
  1380. fi
  1381. if test "${localstatedir}" = '${prefix}/var'; then
  1382. for QUAGGA_STATE_DIR in ${quagga_statedir_prefix}/var/run dnl
  1383. ${quagga_statedir_prefix}/var/adm dnl
  1384. ${quagga_statedir_prefix}/etc dnl
  1385. /var/run dnl
  1386. /var/adm dnl
  1387. /etc dnl
  1388. /dev/null;
  1389. do
  1390. test -d $QUAGGA_STATE_DIR && break
  1391. done
  1392. quagga_statedir=$QUAGGA_STATE_DIR
  1393. else
  1394. quagga_statedir=${localstatedir}
  1395. fi
  1396. if test $quagga_statedir = "/dev/null"; then
  1397. AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
  1398. fi
  1399. AC_MSG_RESULT(${quagga_statedir})
  1400. AC_SUBST(quagga_statedir)
  1401. AC_DEFINE_UNQUOTED(PATH_ZEBRA_PID, "$quagga_statedir/zebra.pid",zebra PID)
  1402. AC_DEFINE_UNQUOTED(PATH_RIPD_PID, "$quagga_statedir/ripd.pid",ripd PID)
  1403. AC_DEFINE_UNQUOTED(PATH_RIPNGD_PID, "$quagga_statedir/ripngd.pid",ripngd PID)
  1404. AC_DEFINE_UNQUOTED(PATH_BGPD_PID, "$quagga_statedir/bgpd.pid",bgpd PID)
  1405. AC_DEFINE_UNQUOTED(PATH_OSPFD_PID, "$quagga_statedir/ospfd.pid",ospfd PID)
  1406. AC_DEFINE_UNQUOTED(PATH_OSPF6D_PID, "$quagga_statedir/ospf6d.pid",ospf6d PID)
  1407. AC_DEFINE_UNQUOTED(PATH_BABELD_PID, "$quagga_statedir/babeld.pid",babeld PID)
  1408. AC_DEFINE_UNQUOTED(PATH_ISISD_PID, "$quagga_statedir/isisd.pid",isisd PID)
  1409. AC_DEFINE_UNQUOTED(PATH_PIMD_PID, "$quagga_statedir/pimd.pid",pimd PID)
  1410. AC_DEFINE_UNQUOTED(PATH_WATCHQUAGGA_PID, "$quagga_statedir/watchquagga.pid",watchquagga PID)
  1411. AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$quagga_statedir/zserv.api",zebra api socket)
  1412. AC_DEFINE_UNQUOTED(ZEBRA_VTYSH_PATH, "$quagga_statedir/zebra.vty",zebra vty socket)
  1413. AC_DEFINE_UNQUOTED(RIP_VTYSH_PATH, "$quagga_statedir/ripd.vty",rip vty socket)
  1414. AC_DEFINE_UNQUOTED(RIPNG_VTYSH_PATH, "$quagga_statedir/ripngd.vty",ripng vty socket)
  1415. AC_DEFINE_UNQUOTED(BGP_VTYSH_PATH, "$quagga_statedir/bgpd.vty",bgpd vty socket)
  1416. AC_DEFINE_UNQUOTED(OSPF_VTYSH_PATH, "$quagga_statedir/ospfd.vty",ospfd vty socket)
  1417. AC_DEFINE_UNQUOTED(OSPF6_VTYSH_PATH, "$quagga_statedir/ospf6d.vty",ospf6d vty socket)
  1418. AC_DEFINE_UNQUOTED(BABEL_VTYSH_PATH, "$quagga_statedir/babeld.vty",babeld vty socket)
  1419. AC_DEFINE_UNQUOTED(ISIS_VTYSH_PATH, "$quagga_statedir/isisd.vty",isisd vty socket)
  1420. AC_DEFINE_UNQUOTED(PIM_VTYSH_PATH, "$quagga_statedir/pimd.vty",pimd vty socket)
  1421. AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$quagga_statedir",daemon vty directory)
  1422. dnl -------------------------------
  1423. dnl Quagga sources should always be
  1424. dnl current wrt interfaces. Dont
  1425. dnl allow deprecated interfaces to
  1426. dnl be exposed.
  1427. dnl -------------------------------
  1428. AC_DEFINE(QUAGGA_NO_DEPRECATED_INTERFACES, 1, Hide deprecated interfaces)
  1429. dnl ---------------------------
  1430. dnl Check htonl works correctly
  1431. dnl ---------------------------
  1432. AC_MSG_CHECKING(for working htonl)
  1433. AC_CACHE_VAL(ac_cv_htonl_works,
  1434. [AC_LINK_IFELSE([AC_LANG_PROGRAM([QUAGGA_INCLUDES],[htonl (0);])],
  1435. [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
  1436. ]
  1437. )
  1438. AC_MSG_RESULT($ac_cv_htonl_works)
  1439. AC_CONFIG_FILES([Makefile lib/Makefile zebra/Makefile ripd/Makefile
  1440. ripngd/Makefile bgpd/Makefile ospfd/Makefile watchquagga/Makefile
  1441. ospf6d/Makefile isisd/Makefile babeld/Makefile vtysh/Makefile
  1442. doc/Makefile ospfclient/Makefile tests/Makefile m4/Makefile
  1443. pimd/Makefile
  1444. tests/bgpd.tests/Makefile
  1445. tests/libzebra.tests/Makefile
  1446. redhat/Makefile
  1447. pkgsrc/Makefile
  1448. redhat/quagga.spec
  1449. lib/version.h
  1450. doc/defines.texi
  1451. isisd/topology/Makefile
  1452. pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
  1453. pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh])
  1454. AC_CONFIG_FILES([solaris/Makefile])
  1455. AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
  1456. ## Hack, but working solution to avoid rebuilding of quagga.info.
  1457. ## It's already in CVS until texinfo 4.7 is more common.
  1458. AC_OUTPUT
  1459. echo "
  1460. Quagga configuration
  1461. --------------------
  1462. quagga version : ${PACKAGE_VERSION}
  1463. host operating system : ${host_os}
  1464. source code location : ${srcdir}
  1465. compiler : ${CC}
  1466. compiler flags : ${CFLAGS}
  1467. make : ${MAKE-make}
  1468. includes : ${INCLUDES}
  1469. linker flags : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
  1470. state file directory : ${quagga_statedir}
  1471. config file directory : `eval echo \`echo ${sysconfdir}\``
  1472. example directory : `eval echo \`echo ${exampledir}\``
  1473. user to run as : ${enable_user}
  1474. group to run as : ${enable_group}
  1475. group for vty sockets : ${enable_vty_group}
  1476. config file mask : ${enable_configfile_mask}
  1477. log file mask : ${enable_logfile_mask}
  1478. The above user and group must have read/write access to the state file
  1479. directory and to the config files in the config file directory."
  1480. if test x"$quagga_cv_gnu_make" = x"no"; then echo "
  1481. Warning: The ${MAKE-make} programme detected, either in your path or
  1482. via the MAKE variable, is not GNU Make. GNU make may be installed as
  1483. gmake on some systems. and is required to complete a build of Quagga
  1484. " > /dev/stderr
  1485. fi