configure.ac 53 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795796797798799800801802803804805806807808809810811812813814815816817818819820821822823824825826827828829830831832833834835836837838839840841842843844845846847848849850851852853854855856857858859860861862863864865866867868869870871872873874875876877878879880881882883884885886887888889890891892893894895896897898899900901902903904905906907908909910911912913914915916917918919920921922923924925926927928929930931932933934935936937938939940941942943944945946947948949950951952953954955956957958959960961962963964965966967968969970971972973974975976977978979980981982983984985986987988989990991992993994995996997998999100010011002100310041005100610071008100910101011101210131014101510161017101810191020102110221023102410251026102710281029103010311032103310341035103610371038103910401041104210431044104510461047104810491050105110521053105410551056105710581059106010611062106310641065106610671068106910701071107210731074107510761077107810791080108110821083108410851086108710881089109010911092109310941095109610971098109911001101110211031104110511061107110811091110111111121113111411151116111711181119112011211122112311241125112611271128112911301131113211331134113511361137113811391140114111421143114411451146114711481149115011511152115311541155115611571158115911601161116211631164116511661167116811691170117111721173117411751176117711781179118011811182118311841185118611871188118911901191119211931194119511961197119811991200120112021203120412051206120712081209121012111212121312141215121612171218121912201221122212231224122512261227122812291230123112321233123412351236123712381239124012411242124312441245124612471248124912501251125212531254125512561257125812591260126112621263126412651266126712681269127012711272127312741275127612771278127912801281128212831284128512861287128812891290129112921293129412951296129712981299130013011302130313041305130613071308130913101311131213131314131513161317131813191320132113221323132413251326132713281329133013311332133313341335133613371338133913401341134213431344134513461347134813491350135113521353135413551356135713581359136013611362136313641365136613671368136913701371137213731374137513761377137813791380138113821383138413851386138713881389139013911392139313941395139613971398139914001401140214031404140514061407140814091410141114121413141414151416141714181419142014211422142314241425142614271428142914301431143214331434143514361437143814391440144114421443144414451446144714481449145014511452145314541455145614571458145914601461146214631464146514661467146814691470147114721473147414751476147714781479148014811482148314841485148614871488148914901491149214931494149514961497149814991500150115021503150415051506150715081509151015111512151315141515151615171518151915201521152215231524152515261527152815291530153115321533153415351536153715381539154015411542154315441545154615471548154915501551155215531554155515561557155815591560156115621563156415651566156715681569157015711572157315741575157615771578157915801581158215831584158515861587158815891590159115921593159415951596159715981599160016011602160316041605160616071608160916101611161216131614161516161617161816191620162116221623162416251626162716281629163016311632163316341635163616371638163916401641164216431644164516461647164816491650165116521653165416551656165716581659166016611662166316641665166616671668166916701671167216731674167516761677167816791680168116821683168416851686168716881689169016911692169316941695169616971698169917001701170217031704170517061707170817091710171117121713171417151716171717181719172017211722172317241725172617271728172917301731173217331734173517361737173817391740174117421743174417451746174717481749175017511752175317541755
  1. ##
  2. ## Configure template file for Quagga.
  3. ## autoconf will generate configure script.
  4. ##
  5. ## Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
  6. ## Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
  7. ##
  8. AC_PREREQ(2.53)
  9. AC_INIT(Quagga, 0.99.23, [https://bugzilla.quagga.net])
  10. AC_CONFIG_SRCDIR(lib/zebra.h)
  11. AC_CONFIG_MACRO_DIR([m4])
  12. dnl -----------------------------------
  13. dnl Get hostname and other information.
  14. dnl -----------------------------------
  15. AC_CANONICAL_BUILD()
  16. AC_CANONICAL_HOST()
  17. AC_CANONICAL_TARGET()
  18. AM_INIT_AUTOMAKE(1.6)
  19. AC_CONFIG_HEADERS(config.h)
  20. AC_PATH_PROG(PERL, perl)
  21. AC_CHECK_PROG([GAWK],[gawk],[gawk],[not-in-PATH])
  22. if test "x$GAWK" = "xnot-in-PATH" ; then
  23. AC_MSG_ERROR([GNU awk is required for lib/memtype.h made by memtypes.awk.
  24. BSD awk complains: awk: gensub doesn't support backreferences (subst "\1") ])
  25. fi
  26. AC_ARG_VAR([GAWK],[GNU AWK])
  27. dnl default is to match previous behavior
  28. exampledir=${sysconfdir}
  29. AC_ARG_ENABLE([exampledir],
  30. AC_HELP_STRING([--enable-exampledir],
  31. [specify alternate directory for examples]),
  32. exampledir="$enableval",)
  33. dnl XXX add --exampledir to autoconf standard directory list somehow
  34. AC_SUBST(exampledir)
  35. dnl default is to match previous behavior
  36. pkgsrcrcdir=""
  37. pkgsrcdir=""
  38. AC_ARG_ENABLE([pkgsrcrcdir],
  39. AC_HELP_STRING([--enable-pkgsrcrcdir],
  40. [specify directory for rc.d scripts]),
  41. pkgsrcrcdir="$enableval"; pkgsrcdir="pkgsrc",)
  42. dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  43. AC_SUBST(pkgsrcdir)
  44. AC_SUBST(pkgsrcrcdir)
  45. dnl ------------
  46. dnl Check CFLAGS
  47. dnl ------------
  48. AC_ARG_WITH(cflags,
  49. [ --with-cflags Set CFLAGS for use in compilation.])
  50. if test "x$with_cflags" != "x" ; then
  51. CFLAGS="$with_cflags" ; cflags_specified=yes ;
  52. elif test -n "$CFLAGS" ; then
  53. cflags_specified=yes ;
  54. fi
  55. dnl --------------------
  56. dnl Check CC and friends
  57. dnl --------------------
  58. AC_LANG([C])
  59. AC_PROG_CC
  60. AC_PROG_CPP
  61. AM_PROG_CC_C_O
  62. AC_PROG_EGREP
  63. dnl autoconf 2.59 appears not to support AC_PROG_SED
  64. dnl AC_PROG_SED
  65. AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
  66. dnl pdflatex and latexmk are needed to build HACKING.pdf
  67. AC_CHECK_PROG([PDFLATEX],[pdflatex],[pdflatex],[/bin/false])
  68. AC_CHECK_PROG([LATEXMK],[latexmk],[latexmk],[/bin/false])
  69. if test "x$PDFLATEX" = "x/bin/false" -o "x$LATEXMK" = "x/bin/false"; then
  70. AC_MSG_WARN([Will not be able to make PDF versions of TeX documents])
  71. else
  72. HAVE_LATEX=true
  73. fi
  74. AM_CONDITIONAL([HAVE_LATEX], [test "x$HAVE_LATEX" = "xtrue"])
  75. dnl ------------------------------------------------------------------
  76. dnl Intel compiler check. Although Intel tries really hard to make icc
  77. dnl look like gcc, there are some differences. It's very verbose with
  78. dnl -Wall and it doesn't support the individual -W options.
  79. dnl ------------------------------------------------------------------
  80. if test "x${GCC}" = "xyes" ; then
  81. COMPILER="GCC"
  82. AC_MSG_CHECKING([whether we are using the Intel compiler])
  83. AC_EGREP_CPP([^__INTEL_COMPILER], [__INTEL_COMPILER],
  84. [AC_MSG_RESULT([no])],
  85. [COMPILER="ICC"
  86. AC_MSG_RESULT([yes])]
  87. )
  88. else
  89. AC_MSG_CHECKING([whether we are using SunPro compiler])
  90. AC_EGREP_CPP([^__SUNPRO_C.*0x5(7|8|9)], ["__SUNPRO_C" __SUNPRO_C],
  91. [AC_MSG_RESULT([no])],
  92. [COMPILER="SUNPRO"
  93. AC_MSG_RESULT([yes])]
  94. )
  95. fi
  96. dnl ---------------------------------------------
  97. dnl If CLFAGS doesn\'t exist set default value
  98. dnl AC_PROG_CC will have set minimal default
  99. dnl already, eg "-O2 -g" for gcc, "-g" for others
  100. dnl (Wall is gcc specific... have to make sure
  101. dnl gcc is being used before setting it)
  102. dnl
  103. dnl Intel icc 8.0 also sets __GNUC__,
  104. dnl but doesn't support all these fancy -W options.
  105. dnl Intel compiler warnings we ignore:
  106. dnl 279: controlling expression is constant.
  107. dnl 869: parameter "xxx" was never referenced - to avoid massive warnings
  108. dnl about "self", "vty", "argc" and "argv" never referenced in DEFUN
  109. dnl macro.
  110. dnl 981: operands are evaluated in unspecified order.
  111. dnl
  112. dnl Sun Studio 10 / SunPro 5.7 is also supported,
  113. dnl so lets set some sane CFLAGS for it.
  114. dnl ---------------------------------------------
  115. AC_MSG_CHECKING([whether to set a default CFLAGS])
  116. if test "x${cflags_specified}" = "x" ; then
  117. case ${COMPILER} in
  118. "ICC")
  119. CFLAGS="-Os -g -Wall"
  120. AC_MSG_RESULT([Intel default])
  121. ;;
  122. "GCC")
  123. CFLAGS="-Os -fno-omit-frame-pointer -g -std=gnu99 -Wall"
  124. CFLAGS="${CFLAGS} -Wsign-compare -Wpointer-arith"
  125. CFLAGS="${CFLAGS} -Wbad-function-cast -Wwrite-strings"
  126. CFLAGS="${CFLAGS} -Wmissing-prototypes -Wmissing-declarations"
  127. CFLAGS="${CFLAGS} -Wchar-subscripts -Wcast-qual"
  128. # TODO: conditionally addd -Wpacked if handled
  129. AC_MSG_RESULT([gcc default])
  130. ;;
  131. "SUNPRO")
  132. CFLAGS="-xO4 -v -g -xspace -xcode=pic32 -xstrconst -xc99"
  133. AC_MSG_RESULT([SunPro default])
  134. ;;
  135. *)
  136. AC_MSG_RESULT([unknown compiler])
  137. ;;
  138. esac
  139. else
  140. AC_MSG_RESULT([CFLAGS supplied by user])
  141. fi
  142. dnl --------------
  143. dnl Check programs
  144. dnl --------------
  145. AC_PROG_INSTALL
  146. AC_PROG_LN_S
  147. AC_PROG_MAKE_SET
  148. AC_CHECK_TOOL(AR, ar)
  149. dnl ---------------------------
  150. dnl We, perhaps unfortunately,
  151. dnl depend on GNU Make specific
  152. dnl constructs.
  153. dnl Give the user a warning if
  154. dnl not GNU Make.
  155. dnl ---------------------------
  156. AC_CACHE_CHECK([if ${MAKE-make} is GNU make], [quagga_cv_gnu_make],
  157. [quagga_cv_gnu_make=no
  158. if ${MAKE-make} --version 2>/dev/null | \
  159. grep '^GNU Make ' >/dev/null ; then
  160. quagga_cv_gnu_make=yes;
  161. fi
  162. ]
  163. )
  164. dnl -----------------
  165. dnl System extensions
  166. dnl -----------------
  167. AC_GNU_SOURCE
  168. dnl -------
  169. dnl libtool
  170. dnl -------
  171. AC_PROG_LIBTOOL
  172. dnl ----------------------
  173. dnl Packages configuration
  174. dnl ----------------------
  175. AC_ARG_WITH(pkg-extra-version,
  176. AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
  177. [EXTRAVERSION=$withval],)
  178. AC_ARG_WITH(pkg-git-version,
  179. AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
  180. [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
  181. AC_ARG_ENABLE(vtysh,
  182. [ --enable-vtysh include integrated vty shell for Quagga])
  183. AC_ARG_ENABLE(ipv6,
  184. [ --disable-ipv6 turn off IPv6 related features and daemons])
  185. AC_ARG_ENABLE(doc,
  186. [ --disable-doc do not build docs])
  187. AC_ARG_ENABLE(zebra,
  188. [ --disable-zebra do not build zebra daemon])
  189. AC_ARG_ENABLE(bgpd,
  190. [ --disable-bgpd do not build bgpd])
  191. AC_ARG_ENABLE(ripd,
  192. [ --disable-ripd do not build ripd])
  193. AC_ARG_ENABLE(ripngd,
  194. [ --disable-ripngd do not build ripngd])
  195. AC_ARG_ENABLE(ospfd,
  196. [ --disable-ospfd do not build ospfd])
  197. AC_ARG_ENABLE(ospf6d,
  198. [ --disable-ospf6d do not build ospf6d])
  199. AC_ARG_ENABLE(babeld,
  200. [ --disable-babeld do not build babeld])
  201. AC_ARG_ENABLE(watchquagga,
  202. [ --disable-watchquagga do not build watchquagga])
  203. AC_ARG_ENABLE(isisd,
  204. [ --enable-isisd build isisd])
  205. AC_ARG_ENABLE(solaris,
  206. [ --enable-solaris build solaris])
  207. AC_ARG_ENABLE(bgp-announce,
  208. [ --disable-bgp-announce, turn off BGP route announcement])
  209. AC_ARG_ENABLE(netlink,
  210. [ --enable-netlink force to use Linux netlink interface])
  211. AC_ARG_ENABLE(broken-aliases,
  212. [ --enable-broken-aliases enable aliases as distinct interfaces for Linux 2.2.X])
  213. AC_ARG_ENABLE(snmp,
  214. [ --enable-snmp=ARG enable SNMP support (smux or agentx)])
  215. AC_ARG_WITH(libpam,
  216. [ --with-libpam use libpam for PAM support in vtysh])
  217. AC_ARG_ENABLE(tcp-zebra,
  218. [ --enable-tcp-zebra enable TCP/IP socket connection between zebra and protocol daemon])
  219. AC_ARG_ENABLE(opaque-lsa,
  220. AC_HELP_STRING([--disable-opaque-lsa],[do not build OSPF Opaque-LSA with OSPFAPI support (RFC2370)]))
  221. AC_ARG_ENABLE(ospfapi,
  222. [ --disable-ospfapi do not build OSPFAPI to access the OSPF LSA Database])
  223. AC_ARG_ENABLE(ospfclient,
  224. [ --disable-ospfclient do not build OSPFAPI client for OSPFAPI,
  225. (this is the default if --disable-ospfapi is set)])
  226. AC_ARG_ENABLE(ospf-te,
  227. AC_HELP_STRING([--disable-ospf-te],[disable Traffic Engineering Extension to OSPF]))
  228. AC_ARG_ENABLE(multipath,
  229. [ --enable-multipath=ARG enable multipath function, ARG must be digit])
  230. AC_ARG_ENABLE(user,
  231. AC_HELP_STRING([--enable-user=user], [user to run Quagga suite as (default quagga)]))
  232. AC_ARG_ENABLE(group,
  233. AC_HELP_STRING([--enable-group=group], [group to run Quagga suite as (default quagga)]))
  234. AC_ARG_ENABLE(vty_group,
  235. [ --enable-vty-group=ARG set vty sockets to have specified group as owner])
  236. AC_ARG_ENABLE(configfile_mask,
  237. [ --enable-configfile-mask=ARG set mask for config files])
  238. AC_ARG_ENABLE(logfile_mask,
  239. [ --enable-logfile-mask=ARG set mask for log files])
  240. AC_ARG_ENABLE(rtadv,
  241. [ --disable-rtadv disable IPV6 router advertisement feature])
  242. AC_ARG_ENABLE(irdp,
  243. [ --enable-irdp enable IRDP server support in zebra])
  244. AC_ARG_ENABLE(isis_topology,
  245. [ --enable-isis-topology enable IS-IS topology generator])
  246. AC_ARG_ENABLE(capabilities,
  247. [ --disable-capabilities disable using POSIX capabilities])
  248. AC_ARG_ENABLE(rusage,
  249. [ --disable-rusage disable using getrusage])
  250. AC_ARG_ENABLE(gcc_ultra_verbose,
  251. [ --enable-gcc-ultra-verbose enable ultra verbose GCC warnings])
  252. AC_ARG_ENABLE(linux24_tcp_md5,
  253. [ --enable-linux24-tcp-md5 enable support for old, Linux-2.4 RFC2385 patch])
  254. AC_ARG_ENABLE(gcc-rdynamic,
  255. [ --enable-gcc-rdynamic enable linking with -rdynamic for better backtraces (default if gcc)])
  256. AC_ARG_ENABLE(backtrace,
  257. [ --disable-backtrace, disable crash backtraces (default autodetect)])
  258. AC_ARG_ENABLE(time-check,
  259. [ --disable-time-check disable slow thread warning messages])
  260. AC_ARG_ENABLE(pcreposix,
  261. [ --enable-pcreposix enable using PCRE Posix libs for regex functions])
  262. AC_ARG_ENABLE(fpm,
  263. [ --enable-fpm enable Forwarding Plane Manager support])
  264. if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
  265. CFLAGS="${CFLAGS} -W -Wcast-qual -Wstrict-prototypes"
  266. CFLAGS="${CFLAGS} -Wmissing-declarations -Wmissing-noreturn"
  267. CFLAGS="${CFLAGS} -Wmissing-format-attribute -Wunreachable-code"
  268. CFLAGS="${CFLAGS} -Wpacked -Wpadded"
  269. fi
  270. if test x"${enable_gcc_rdynamic}" != x"no" ; then
  271. if test x"${enable_gcc_rdynamic}" = x"yes" -o x"$COMPILER" = x"GCC"; then
  272. LDFLAGS="${LDFLAGS} -rdynamic"
  273. fi
  274. fi
  275. if test x"${enable_time_check}" != x"no" ; then
  276. if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
  277. AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
  278. else
  279. AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
  280. fi
  281. fi
  282. if test "${enable_fpm}" = "yes"; then
  283. AC_DEFINE(HAVE_FPM,,Forwarding Plane Manager support)
  284. fi
  285. if test "${enable_broken_aliases}" = "yes"; then
  286. if test "${enable_netlink}" = "yes"
  287. then
  288. AC_MSG_FAILURE([Sorry you can not use netlink with broken aliases])
  289. fi
  290. AC_DEFINE(HAVE_BROKEN_ALIASES,,Broken Alias)
  291. enable_netlink=no
  292. fi
  293. if test "${enable_tcp_zebra}" = "yes"; then
  294. AC_DEFINE(HAVE_TCP_ZEBRA,,Use TCP for zebra communication)
  295. fi
  296. if test "${enable_opaque_lsa}" != "no"; then
  297. AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
  298. fi
  299. if test "${enable_ospf_te}" != "no"; then
  300. AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
  301. AC_DEFINE(HAVE_OSPF_TE,,OSPF TE)
  302. fi
  303. if test "${enable_linux24_tcp_md5}" = "yes"; then
  304. AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
  305. fi
  306. AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
  307. if test "${enable_rtadv}" != "no"; then
  308. AC_MSG_RESULT(yes)
  309. AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
  310. else
  311. AC_MSG_RESULT(no)
  312. fi
  313. if test "${enable_irdp}" = "yes"; then
  314. AC_DEFINE(HAVE_IRDP,, IRDP )
  315. fi
  316. if test "${enable_isisd}" = "yes" && test "${enable_isis_topology}" = yes; then
  317. AC_DEFINE(TOPOLOGY_GENERATE,,Enable IS-IS topology generator code)
  318. ISIS_TOPOLOGY_INCLUDES="-I\$(srcdir)/topology"
  319. ISIS_TOPOLOGY_DIR="topology"
  320. ISIS_TOPOLOGY_LIB="./topology/libtopology.a"
  321. fi
  322. AC_SUBST(ISIS_TOPOLOGY_INCLUDES)
  323. AC_SUBST(ISIS_TOPOLOGY_DIR)
  324. AC_SUBST(ISIS_TOPOLOGY_LIB)
  325. if test "${enable_user}" = "yes" || test x"${enable_user}" = x""; then
  326. enable_user="quagga"
  327. elif test "${enable_user}" = "no"; then
  328. enable_user="root"
  329. fi
  330. if test "${enable_group}" = "yes" || test x"${enable_group}" = x""; then
  331. enable_group="quagga"
  332. elif test "${enable_group}" = "no"; then
  333. enable_group="root"
  334. fi
  335. if test x"${enable_vty_group}" = x"yes" ; then
  336. AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
  337. elif test x"${enable_vty_group}" != x""; then
  338. if test x"${enable_vty_group}" != x"no"; then
  339. AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
  340. fi
  341. fi
  342. AC_SUBST([enable_user])
  343. AC_SUBST([enable_group])
  344. AC_SUBST([enable_vty_group])
  345. AC_DEFINE_UNQUOTED(QUAGGA_USER, "${enable_user}", Quagga User)
  346. AC_DEFINE_UNQUOTED(QUAGGA_GROUP, "${enable_group}", Quagga Group)
  347. enable_configfile_mask=${enable_configfile_mask:-0600}
  348. AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
  349. enable_logfile_mask=${enable_logfile_mask:-0600}
  350. AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
  351. MULTIPATH_NUM=1
  352. case "${enable_multipath}" in
  353. [[0-9]|[1-9][0-9]])
  354. MULTIPATH_NUM="${enable_multipath}"
  355. ;;
  356. "")
  357. ;;
  358. *)
  359. AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
  360. ;;
  361. esac
  362. AC_SUBST(MULTIPATH_NUM)
  363. dnl -----------------------------------
  364. dnl Add extra version string to package
  365. dnl name, string and version fields.
  366. dnl -----------------------------------
  367. if test "x${EXTRAVERSION}" != "x" ; then
  368. VERSION="${VERSION}${EXTRAVERSION}"
  369. PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
  370. PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
  371. fi
  372. if test "x$with_pkg_git_version" = "xyes"; then
  373. if test -d "${srcdir}/.git"; then
  374. AC_DEFINE(GIT_VERSION, [1], [include git version info])
  375. else with_pkg_git_version="no"
  376. AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
  377. fi
  378. fi
  379. AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
  380. dnl ------------------------------------
  381. dnl Check C keywords and standard types
  382. dnl ------------------------------------
  383. AC_C_CONST
  384. AC_C_INLINE
  385. AC_C_RESTRICT
  386. AC_C_VOLATILE
  387. AC_HEADER_STDC
  388. AC_HEADER_TIME
  389. AC_HEADER_SYS_WAIT
  390. dnl AC_TYPE_PID_T
  391. AC_TYPE_UID_T
  392. AC_TYPE_MODE_T
  393. AC_TYPE_SIZE_T
  394. AC_TYPE_SIGNAL
  395. AC_STRUCT_TM
  396. dnl -------------------------
  397. dnl Check other header files.
  398. dnl -------------------------
  399. AC_CHECK_HEADERS([stropts.h sys/ksym.h sys/times.h sys/select.h \
  400. sys/types.h linux/version.h netdb.h asm/types.h \
  401. sys/cdefs.h sys/param.h limits.h signal.h \
  402. sys/socket.h netinet/in.h time.h sys/time.h])
  403. dnl Utility macro to avoid retyping includes all the time
  404. m4_define([QUAGGA_INCLUDES],
  405. [#ifdef SUNOS_5
  406. #define _XPG4_2
  407. #define __EXTENSIONS__
  408. #endif
  409. #include <stdio.h>
  410. #if STDC_HEADERS
  411. # include <stdlib.h>
  412. # include <stddef.h>
  413. #else
  414. # if HAVE_STDLIB_H
  415. # include <stdlib.h>
  416. # endif
  417. #endif
  418. #if HAVE_SYS_TYPES_H
  419. # include <sys/types.h>
  420. #endif
  421. /* sys/conf.h depends on param.h on FBSD at least */
  422. #if HAVE_SYS_PARAM_H
  423. # include <sys/param.h>
  424. #endif
  425. /* Required for MAXSIG */
  426. #if HAVE_SIGNAL_H
  427. # include <signal.h>
  428. #endif
  429. #if HAVE_SYS_SOCKET_H
  430. # include <sys/socket.h>
  431. #endif
  432. #ifdef __APPLE__
  433. # define __APPLE_USE_RFC_3542
  434. #endif
  435. #if HAVE_NETINET_IN_H
  436. # include <netinet/in.h>
  437. #endif
  438. #ifdef TIME_WITH_SYS_TIME
  439. # include <sys/time.h>
  440. # include <time.h>
  441. #else
  442. # ifdef HAVE_SYS_TIME_H
  443. # include <sys/time.h>
  444. # else
  445. # include <time.h>
  446. # endif
  447. #endif /* TIME_WITH_SYS_TIME */
  448. ])dnl
  449. dnl HAVE_NET_IF_H must be discovered by the time the longer AC_CHECK_HEADERS
  450. dnl round below execution begins, otherwise it doesn't properly detect
  451. dnl HAVE_NETINET6_IN6_VAR_H, HAVE_NET_IF_VAR_H and HAVE_STRUCT_IN6_ALIASREQ
  452. dnl on FreeBSD (BZ#408).
  453. AC_CHECK_HEADERS([net/if.h], [], [], QUAGGA_INCLUDES)
  454. m4_define([QUAGGA_INCLUDES],
  455. QUAGGA_INCLUDES
  456. [#if HAVE_NET_IF_H
  457. # include <net/if.h>
  458. #endif
  459. ])dnl
  460. dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
  461. dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
  462. dnl an additional round for it.
  463. AC_CHECK_HEADERS([net/if_var.h], [], [], QUAGGA_INCLUDES)
  464. m4_define([QUAGGA_INCLUDES],
  465. QUAGGA_INCLUDES
  466. [#if HAVE_NET_IF_VAR_H
  467. # include <net/if_var.h>
  468. #endif
  469. ])dnl
  470. AC_CHECK_HEADERS([sys/un.h netinet/in_systm.h netinet/in_var.h \
  471. net/if_dl.h net/netopt.h net/route.h \
  472. inet/nd.h arpa/inet.h netinet/ip_icmp.h \
  473. fcntl.h stddef.h sys/ioctl.h syslog.h wchar.h wctype.h \
  474. sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
  475. [], [], QUAGGA_INCLUDES)
  476. AC_CHECK_HEADERS([ucontext.h], [], [],
  477. [#ifndef __USE_GNU
  478. #define __USE_GNU
  479. #endif /* __USE_GNU */
  480. QUAGGA_INCLUDES
  481. ])
  482. m4_define([QUAGGA_INCLUDES],
  483. QUAGGA_INCLUDES
  484. [#if HAVE_SYS_UN_H
  485. # include <sys/un.h>
  486. #endif
  487. #if HAVE_NETINET_IN_SYSTM_H
  488. # include <netinet/in_systm.h>
  489. #endif
  490. #if HAVE_NETINET_IN_VAR_H
  491. # include <netinet/in_var.h>
  492. #endif
  493. #if HAVE_NET_IF_DL_H
  494. # include <net/if_dl.h>
  495. #endif
  496. #if HAVE_NET_NETOPT_H
  497. # include <net/netopt.h>
  498. #endif
  499. #if HAVE_NET_ROUTE_H
  500. # include <net/route.h>
  501. #endif
  502. #if HAVE_INET_ND_H
  503. # include <inet/nd.h>
  504. #endif
  505. #if HAVE_ARPA_INET_H
  506. # include <arpa/inet.h>
  507. #endif
  508. /* Required for IDRP */
  509. #if HAVE_NETINET_IP_ICMP_H
  510. # include <netinet/ip_icmp.h>
  511. #endif
  512. ])dnl
  513. dnl V6 headers are checked below, after we check for v6
  514. dnl Some systems (Solaris 2.x) require libnsl (Network Services Library)
  515. case "$host" in
  516. [*-sunos5.[6-7]*] | [*-solaris2.[6-7]*])
  517. opsys=sol2-6
  518. AC_DEFINE(SUNOS_56, 1, SunOS 5.6 to 5.7)
  519. AC_DEFINE(SUNOS_5, 1, SunOS 5)
  520. AC_CHECK_LIB(xnet, main)
  521. CURSES=-lcurses
  522. ;;
  523. [*-sunos5.[8-9]] \
  524. | [*-sunos5.1[0-9]] \
  525. | [*-sunos5.1[0-9].[0-9]] \
  526. | [*-solaris2.[8-9]] \
  527. | [*-solaris2.1[0-9]] \
  528. | [*-solaris2.1[0-9].[0-9]])
  529. opsys=sol8
  530. AC_DEFINE(SUNOS_59, 1, [SunOS 5.8 up])
  531. AC_DEFINE(SUNOS_5, 1, [SunOS 5])
  532. AC_CHECK_LIB(socket, main)
  533. AC_CHECK_LIB(nsl, main)
  534. AC_CHECK_LIB(umem, main)
  535. AC_CHECK_FUNCS([printstack],
  536. [AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
  537. AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
  538. ])
  539. CURSES=-lcurses
  540. ;;
  541. *-sunos5* | *-solaris2*)
  542. AC_DEFINE(SUNOS_5,,SunOS 5, Unknown SunOS)
  543. AC_CHECK_LIB(socket, main)
  544. AC_CHECK_LIB(nsl, main)
  545. CURSES=-lcurses
  546. ;;
  547. *-linux*)
  548. opsys=gnu-linux
  549. AC_DEFINE(GNU_LINUX,,GNU Linux)
  550. ;;
  551. *-nec-sysv4*)
  552. AC_CHECK_LIB(nsl, gethostbyname)
  553. AC_CHECK_LIB(socket, socket)
  554. ;;
  555. *-openbsd*)
  556. opsys=openbsd
  557. AC_DEFINE(OPEN_BSD,,OpenBSD)
  558. ;;
  559. *-bsdi*)
  560. opsys=bsdi
  561. OTHER_METHOD="mtu_kvm.o"
  562. AC_CHECK_LIB(kvm, main)
  563. ;;
  564. *-irix6.5)
  565. opsys=irix
  566. AC_DEFINE(IRIX_65,,IRIX 6.5)
  567. ;;
  568. esac
  569. AC_SYS_LARGEFILE
  570. dnl ---------------------
  571. dnl Integrated VTY option
  572. dnl ---------------------
  573. case "${enable_vtysh}" in
  574. "yes") VTYSH="vtysh";
  575. AC_DEFINE(VTYSH,,VTY shell)
  576. dnl Vtysh uses libreadline, which looks for termcap functions at
  577. dnl configure time. We follow readlines search order.
  578. dnl The required procedures are in libtermcap on NetBSD, in
  579. dnl [TODO] on Linux, and in [TODO] on Solaris.
  580. AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
  581. [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
  582. [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
  583. [AC_CHECK_LIB(ncurses, tputs,
  584. LIBREADLINE="$LIBREADLINE -lncurses")]
  585. )]
  586. )]
  587. )
  588. AC_CHECK_LIB(readline, main, LIBREADLINE="$LIBREADLINE -lreadline",,
  589. "$LIBREADLINE")
  590. if test $ac_cv_lib_readline_main = no; then
  591. AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
  592. fi
  593. AC_CHECK_HEADER(readline/history.h)
  594. if test $ac_cv_header_readline_history_h = no;then
  595. AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
  596. fi
  597. AC_CHECK_LIB(readline, rl_completion_matches,
  598. LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
  599. if test $ac_cv_lib_readline_rl_completion_matches = no; then
  600. AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
  601. fi
  602. ;;
  603. "no" ) VTYSH="";;
  604. * ) ;;
  605. esac
  606. AC_SUBST(LIBREADLINE)
  607. AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
  608. dnl ----------
  609. dnl PAM module
  610. dnl
  611. dnl Quagga detects the PAM library it is built against by checking for a
  612. dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
  613. dnl is known to #include pam_appl.h, the standard header of a PAM library, and
  614. dnl openpam.h doesn't do that, although depends on the header too. Hence a
  615. dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
  616. dnl of OpenPAM.
  617. dnl ----------
  618. if test "$with_libpam" = "yes"; then
  619. AC_CHECK_HEADER([security/pam_misc.h],
  620. [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
  621. AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
  622. pam_conv_func="misc_conv"
  623. ],
  624. [], QUAGGA_INCLUDES)
  625. AC_CHECK_HEADER([security/openpam.h],
  626. [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
  627. AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
  628. pam_conv_func="openpam_ttyconv"
  629. ],
  630. [], QUAGGA_INCLUDES[#include <security/pam_appl.h>])
  631. if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
  632. AC_MSG_WARN([*** pam support will not be built ***])
  633. with_libpam="no"
  634. fi
  635. fi
  636. if test "$with_libpam" = "yes"; then
  637. dnl took this test from proftpds configure.in and suited to our needs
  638. dnl -------------------------------------------------------------------------
  639. dnl
  640. dnl This next check looks funky due to a linker problem with some versions
  641. dnl of the PAM library. Prior to 0.72 release, the Linux PAM shared library
  642. dnl omitted requiring libdl linking information. PAM-0.72 or better ships
  643. dnl with RedHat 6.2 and Debian 2.2 or better.
  644. AC_CHECK_LIB(pam, pam_start,
  645. [AC_CHECK_LIB(pam, $pam_conv_func,
  646. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  647. LIBPAM="-lpam"],
  648. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  649. LIBPAM="-lpam -lpam_misc"]
  650. )
  651. ],
  652. [AC_CHECK_LIB(pam, pam_end,
  653. [AC_CHECK_LIB(pam, $pam_conv_func,
  654. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  655. LIBPAM="-lpam -ldl"],
  656. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  657. LIBPAM="-lpam -ldl -lpam_misc"]
  658. )
  659. ],AC_MSG_WARN([*** pam support will not be built ***]),
  660. [-ldl])
  661. ]
  662. )
  663. fi
  664. AC_SUBST(LIBPAM)
  665. dnl -------------------------------
  666. dnl Endian-ness check
  667. dnl -------------------------------
  668. AC_WORDS_BIGENDIAN
  669. dnl -------------------------------
  670. dnl check the size in byte of the C
  671. dnl -------------------------------
  672. dnl AC_CHECK_SIZEOF(char)
  673. dnl AC_CHECK_SIZEOF(int)
  674. dnl AC_CHECK_SIZEOF(short)
  675. dnl AC_CHECK_SIZEOF(long)
  676. dnl ----------------------------
  677. dnl check existance of functions
  678. dnl ----------------------------
  679. AC_FUNC_CHOWN
  680. AC_FUNC_FNMATCH
  681. AC_FUNC_FORK
  682. AC_FUNC_MEMCMP
  683. AC_FUNC_MKTIME
  684. AC_FUNC_STRFTIME
  685. AC_FUNC_STAT
  686. AC_FUNC_SELECT_ARGTYPES
  687. AC_FUNC_STRFTIME
  688. dnl Avoid AC_FUNC_STRNLEN because it pulls in AC_SYSTEM_EXTENSIONS which
  689. dnl can lead to strange side effects. So we just check for strnlen
  690. dnl directly, see below.
  691. dnl AC_FUNC_STRNLENdnl
  692. AC_FUNC_VPRINTF
  693. dnl -------------------------------
  694. dnl bgpd needs pow() and hence libm
  695. dnl -------------------------------
  696. TMPLIBS="$LIBS"
  697. AC_CHECK_HEADER([math.h],
  698. [AC_CHECK_LIB([m], [pow],
  699. [LIBM="-lm"
  700. LIBS="$LIBS $LIBM"
  701. AC_DEFINE(HAVE_LIBM,, Have libm)
  702. AC_CHECK_FUNCS(pow,[],[LIBM=""])
  703. ])
  704. ])
  705. if test x"$LIBM" = x ; then
  706. AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
  707. fi
  708. LIBS="$TMPLIBS"
  709. AC_SUBST(LIBM)
  710. dnl ---------------
  711. dnl other functions
  712. dnl ---------------
  713. AC_CHECK_FUNCS([dup2 ftruncate getcwd gethostbyname getpagesize gettimeofday \
  714. inet_ntoa inet_aton strnlen \
  715. memchr memmove memset select socket \
  716. strcasecmp strchr strcspn strdup strerror \
  717. strncasecmp strndup strrchr strspn strstr \
  718. strtol strtoul strlcat strlcpy \
  719. daemon snprintf vsnprintf \
  720. if_nametoindex if_indextoname getifaddrs \
  721. uname fcntl])
  722. AC_CHECK_FUNCS(setproctitle, ,
  723. [AC_CHECK_LIB(util, setproctitle,
  724. [LIBS="$LIBS -lutil"
  725. AC_DEFINE(HAVE_SETPROCTITLE,, Have setproctitle)
  726. ]
  727. )
  728. ]
  729. )
  730. dnl ------------------------------------
  731. dnl Determine routing get and set method
  732. dnl ------------------------------------
  733. AC_MSG_CHECKING(zebra between kernel interface method)
  734. if test x"$opsys" = x"gnu-linux"; then
  735. if test "${enable_netlink}" = "yes";then
  736. AC_MSG_RESULT(netlink)
  737. RT_METHOD=rt_netlink.o
  738. AC_DEFINE(HAVE_NETLINK,,netlink)
  739. netlink=yes
  740. elif test "${enable_netlink}" = "no"; then
  741. AC_MSG_RESULT(ioctl)
  742. RT_METHOD=rt_ioctl.o
  743. netlink=no
  744. else
  745. AC_MSG_RESULT(netlink)
  746. RT_METHOD=rt_netlink.o
  747. AC_DEFINE(HAVE_NETLINK,,netlink)
  748. netlink=yes
  749. fi
  750. elif test x"$opsys" = x"sol2-6";then
  751. AC_MSG_RESULT(Route socket)
  752. KERNEL_METHOD="kernel_socket.o"
  753. RT_METHOD="rt_socket.o"
  754. elif test x"$opsys" = x"sol8";then
  755. AC_MSG_RESULT(Route socket)
  756. KERNEL_METHOD="kernel_socket.o"
  757. RT_METHOD="rt_socket.o"
  758. elif test "$opsys" = "irix" ; then
  759. AC_MSG_RESULT(Route socket)
  760. KERNEL_METHOD="kernel_socket.o"
  761. RT_METHOD="rt_socket.o"
  762. else
  763. AC_TRY_RUN([#include <errno.h>
  764. #include <sys/types.h>
  765. #include <sys/socket.h>
  766. main ()
  767. {
  768. int ac_sock;
  769. ac_sock = socket (AF_ROUTE, SOCK_RAW, 0);
  770. if (ac_sock < 0 && errno == EINVAL)
  771. exit (1);
  772. exit (0);
  773. }],
  774. [KERNEL_METHOD=kernel_socket.o
  775. RT_METHOD=rt_socket.o
  776. AC_MSG_RESULT(socket)],
  777. [RT_METHOD=rt_ioctl.o
  778. AC_MSG_RESULT(ioctl)],
  779. [KERNEL_METHOD=kernel_socket.o
  780. RT_METHOD=rt_socket.o
  781. AC_MSG_RESULT(socket)])
  782. fi
  783. AC_SUBST(RT_METHOD)
  784. AC_SUBST(KERNEL_METHOD)
  785. AC_SUBST(OTHER_METHOD)
  786. AM_CONDITIONAL([HAVE_NETLINK], [test "x$netlink" = "xyes"])
  787. dnl --------------------------
  788. dnl Determine IS-IS I/O method
  789. dnl --------------------------
  790. AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
  791. AC_DEFINE(ISIS_METHOD_DLPI, 2, [ constant value for isis method dlpi ])
  792. AC_DEFINE(ISIS_METHOD_BPF, 3, [ constant value for isis method bpf ])
  793. AC_CHECK_HEADER(net/bpf.h)
  794. AC_CHECK_HEADER(sys/dlpi.h)
  795. AC_MSG_CHECKING(zebra IS-IS I/O method)
  796. if test x"$opsys" = x"gnu-linux"; then
  797. AC_MSG_RESULT(pfpacket)
  798. ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
  799. elif test x"$opsys" = x"sol2-6" -o x"$opsys" = x"sol8"; then
  800. AC_MSG_RESULT(DLPI)
  801. ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
  802. else
  803. if test $ac_cv_header_net_bpf_h = no; then
  804. if test $ac_cv_header_sys_dlpi_h = no; then
  805. AC_MSG_RESULT(none)
  806. AC_MSG_WARN([*** IS-IS support will not be built ***])
  807. ISISD=""
  808. else
  809. AC_MSG_RESULT(DLPI)
  810. fi
  811. ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
  812. else
  813. AC_MSG_RESULT(BPF)
  814. ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
  815. fi
  816. fi
  817. AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
  818. dnl ------------------------------------
  819. dnl check for broken CMSG_FIRSTHDR macro
  820. dnl ------------------------------------
  821. AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
  822. AC_RUN_IFELSE([AC_LANG_SOURCE([[
  823. #ifdef SUNOS_5
  824. #define _XPG4_2
  825. #define __EXTENSIONS__
  826. #endif
  827. #ifdef HAVE_STDLIB_H
  828. # include <stdlib.h>
  829. #endif
  830. #ifdef HAVE_SYS_TYPES_H
  831. #include <sys/types.h>
  832. #endif
  833. #ifdef HAVE_SYS_SOCKET_H
  834. #include <sys/socket.h>
  835. #endif
  836. main()
  837. {
  838. struct msghdr msg;
  839. char buf[4];
  840. msg.msg_control = buf;
  841. msg.msg_controllen = 0;
  842. if (CMSG_FIRSTHDR(&msg) != NULL)
  843. exit(0);
  844. exit (1);
  845. }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
  846. [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
  847. dnl ------------------------------
  848. dnl check kernel route read method
  849. dnl ------------------------------
  850. AC_CACHE_CHECK([route read method], [quagga_cv_rtread_method],
  851. [if test "x$netlink" = xyes; then
  852. quagga_cv_rtread_method="netlink"
  853. else
  854. for quagga_cv_rtread_method in /proc/net/route /dev/ip /dev/null;
  855. do
  856. test x`ls $quagga_cv_rtread_method 2>/dev/null` = x"$quagga_cv_rtread_method" && break
  857. done
  858. case $quagga_cv_rtread_method in
  859. "/proc/net/route") quagga_cv_rtread_method="proc";;
  860. "/dev/ip")
  861. case "$host" in
  862. *-freebsd*) quagga_cv_rtread_method="sysctl";;
  863. *) quagga_cv_rtread_method="getmsg";;
  864. esac;;
  865. *)
  866. quagga_cv_rtread_method="sysctl";;
  867. esac
  868. fi])
  869. RTREAD_METHOD=rtread_${quagga_cv_rtread_method}.o
  870. AC_SUBST(RTREAD_METHOD)
  871. dnl -----------------------------
  872. dnl check interface lookup method
  873. dnl -----------------------------
  874. IOCTL_METHOD=ioctl.o
  875. AC_MSG_CHECKING(interface looking up method)
  876. if test "$netlink" = yes; then
  877. AC_MSG_RESULT(netlink)
  878. IF_METHOD=if_netlink.o
  879. elif test "$opsys" = "sol2-6";then
  880. AC_MSG_RESULT(Solaris GIF)
  881. IF_METHOD=if_ioctl.o
  882. elif test "$opsys" = "sol8";then
  883. AC_MSG_RESULT(Solaris GLIF)
  884. IF_METHOD=if_ioctl_solaris.o
  885. IOCTL_METHOD=ioctl_solaris.o
  886. elif test "$opsys" = "irix" ; then
  887. AC_MSG_RESULT(IRIX)
  888. IF_METHOD=if_ioctl.o
  889. elif test "$opsys" = "openbsd";then
  890. AC_MSG_RESULT(openbsd)
  891. IF_METHOD=if_ioctl.o
  892. elif grep NET_RT_IFLIST /usr/include/sys/socket.h >/dev/null 2>&1; then
  893. AC_MSG_RESULT(sysctl)
  894. IF_METHOD=if_sysctl.o
  895. AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
  896. else
  897. AC_MSG_RESULT(ioctl)
  898. IF_METHOD=if_ioctl.o
  899. fi
  900. AC_SUBST(IF_METHOD)
  901. AC_SUBST(IOCTL_METHOD)
  902. dnl ---------------------------------------------------------------
  903. dnl figure out how to specify an interface in multicast sockets API
  904. dnl ---------------------------------------------------------------
  905. AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], QUAGGA_INCLUDES)
  906. AC_MSG_CHECKING([for BSD struct ip_mreq hack])
  907. AC_TRY_COMPILE([#ifdef HAVE_SYS_PARAM_H
  908. #include <sys/param.h>
  909. #endif],[#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__)
  910. return (0);
  911. #else
  912. #error No support for BSD struct ip_mreq hack detected
  913. #endif],[AC_MSG_RESULT(yes)
  914. AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
  915. AC_MSG_RESULT(no))
  916. AC_MSG_CHECKING([for RFC3678 protocol-independed API])
  917. AC_TRY_COMPILE([
  918. #include <sys/types.h>
  919. #include <netinet/in.h>
  920. ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
  921. ], [AC_MSG_RESULT(yes)
  922. AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
  923. AC_MSG_RESULT(no))
  924. dnl ---------------------------------------------------------------
  925. dnl figure out how to check link-state
  926. dnl ---------------------------------------------------------------
  927. AC_CHECK_HEADER([net/if.h],
  928. [AC_CHECK_HEADER( [net/if_media.h],
  929. [m4_define([LINK_DETECT_INCLUDES],
  930. QUAGGA_INCLUDES
  931. [#include <net/if_media.h>
  932. ])
  933. AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
  934. AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
  935. [], LINK_DETECT_INCLUDES)],
  936. [],
  937. QUAGGA_INCLUDES)],
  938. [], QUAGGA_INCLUDES )
  939. dnl ---------------------------------------------------------------
  940. dnl Additional, newer way to check link-state using ifi_link_state.
  941. dnl Not available in all BSD's when ifmediareq available
  942. dnl ---------------------------------------------------------------
  943. AC_CHECK_HEADER([net/if.h],
  944. AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
  945. AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
  946. [], QUAGGA_INCLUDES),
  947. ,)
  948. dnl ------------------------
  949. dnl TCP_MD5SIG socket option
  950. dnl ------------------------
  951. AC_CHECK_HEADER([netinet/tcp.h],
  952. [m4_define([MD5_INCLUDES],
  953. QUAGGA_INCLUDES
  954. [#include <netinet/tcp.h>
  955. ])
  956. AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
  957. [],
  958. QUAGGA_INCLUDES)
  959. if test $ac_cv_have_decl_TCP_MD5SIG = no; then
  960. AC_CHECK_HEADER([linux/tcp.h],
  961. [m4_define([MD5_INCLUDES],
  962. QUAGGA_INCLUDES
  963. [#include <linux/tcp.h>
  964. ])
  965. AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
  966. fi
  967. dnl -----------------------
  968. dnl check proc file system.
  969. dnl -----------------------
  970. if test "$netlink" != yes; then
  971. if test -r /proc/net/dev; then
  972. AC_DEFINE(HAVE_PROC_NET_DEV,,/proc/net/dev)
  973. IF_PROC=if_proc.o
  974. fi
  975. if test -r /proc/net/if_inet6; then
  976. AC_DEFINE(HAVE_PROC_NET_IF_INET6,,/proc/net/if_inet6)
  977. IF_PROC=if_proc.o
  978. fi
  979. fi
  980. AC_SUBST(IF_PROC)
  981. dnl -----------------------------
  982. dnl check ipforward detect method
  983. dnl -----------------------------
  984. AC_CACHE_CHECK([ipforward method], [quagga_cv_ipforward_method],
  985. [if test x$cross_compiling = xyes; then
  986. if test x"$opsys" = x"gnu-linux"; then
  987. quagga_cv_ipforward_method=/proc/net/snmp
  988. else
  989. quagga_cv_ipforward_method=/dev/ip
  990. fi
  991. else
  992. for quagga_cv_ipforward_method in /proc/net/snmp /dev/ip /dev/null;
  993. do
  994. test x`ls $quagga_cv_ipforward_method 2>/dev/null` = x"$quagga_cv_ipforward_method" && break
  995. done
  996. fi
  997. case $quagga_cv_ipforward_method in
  998. "/proc/net/snmp") quagga_cv_ipforward_method="proc";;
  999. "/dev/ip")
  1000. case "$host" in
  1001. *-nec-sysv4*) quagga_cv_ipforward_method="ews";;
  1002. *-freebsd*) quagga_cv_ipforward_method="sysctl";;
  1003. *) quagga_cv_ipforward_method="solaris";;
  1004. esac;;
  1005. *) quagga_cv_ipforward_method="sysctl";;
  1006. esac])
  1007. IPFORWARD=ipforward_${quagga_cv_ipforward_method}.o
  1008. AC_SUBST(IPFORWARD)
  1009. AC_CHECK_FUNCS(getaddrinfo, [have_getaddrinfo=yes], [have_getaddrinfo=no])
  1010. dnl ----------
  1011. dnl IPv6 check
  1012. dnl ----------
  1013. AC_MSG_CHECKING(whether does this OS have IPv6 stack)
  1014. if test "${enable_ipv6}" = "no"; then
  1015. AC_MSG_RESULT(disabled)
  1016. else
  1017. dnl ----------
  1018. dnl INRIA IPv6
  1019. dnl ----------
  1020. if grep IPV6_INRIA_VERSION /usr/include/netinet/in.h >/dev/null 2>&1; then
  1021. zebra_cv_ipv6=yes
  1022. AC_DEFINE(HAVE_IPV6,1,INRIA IPv6)
  1023. AC_DEFINE(INRIA_IPV6,1,INRIA IPv6)
  1024. RIPNGD="ripngd"
  1025. OSPF6D="ospf6d"
  1026. LIB_IPV6=""
  1027. AC_MSG_RESULT(INRIA IPv6)
  1028. dnl ---------
  1029. dnl KAME IPv6
  1030. dnl ---------
  1031. elif grep WIDE /usr/include/netinet6/in6.h >/dev/null 2>&1; then
  1032. zebra_cv_ipv6=yes
  1033. AC_DEFINE(HAVE_IPV6,1,KAME IPv6)
  1034. AC_DEFINE(KAME,1,KAME IPv6)
  1035. RIPNGD="ripngd"
  1036. OSPF6D="ospf6d"
  1037. if test -d /usr/local/v6/lib -a -f /usr/local/v6/lib/libinet6.a; then
  1038. LIB_IPV6="-L/usr/local/v6/lib -linet6"
  1039. fi
  1040. AC_MSG_RESULT(KAME)
  1041. dnl -------------------------
  1042. dnl MUSICA IPv6
  1043. dnl default host check
  1044. dnl It is not used by Kheops
  1045. dnl -------------------------
  1046. elif grep MUSICA /usr/include6/netinet6/in6.h >/dev/null 2>&1; then
  1047. zebra_cv_ipv6=yes
  1048. AC_DEFINE(HAVE_IPV6,1,Musicia IPv6)
  1049. AC_DEFINE(MUSICA,1,Musica IPv6 stack)
  1050. AC_DEFINE(KAME,1,KAME IPv6 stack)
  1051. RIPNGD="ripngd"
  1052. OSPF6D="ospf6d"
  1053. if test -d /usr/local/v6/lib -a -f /usr/local/v6/lib/libinet6.a; then
  1054. LIB_IPV6="-L/usr/local/v6/lib -linet6"
  1055. fi
  1056. AC_MSG_RESULT(MUSICA)
  1057. dnl ---------
  1058. dnl NRL check
  1059. dnl ---------
  1060. elif grep NRL /usr/include/netinet6/in6.h >/dev/null 2>&1; then
  1061. zebra_cv_ipv6=yes
  1062. AC_DEFINE(HAVE_IPV6,1,NRL IPv6)
  1063. AC_DEFINE(NRL,1,NRL)
  1064. RIPNGD="ripngd"
  1065. OSPF6D="ospf6d"
  1066. if test x"$opsys" = x"bsdi";then
  1067. AC_DEFINE(BSDI_NRL,,BSDI)
  1068. AC_MSG_RESULT(BSDI_NRL)
  1069. else
  1070. AC_MSG_RESULT(NRL)
  1071. fi
  1072. dnl ------------------------------------
  1073. dnl Solaris 9, 10 and potentially higher
  1074. dnl ------------------------------------
  1075. elif test x"$opsys" = x"sol8"; then
  1076. zebra_cv_ipv6=yes;
  1077. AC_DEFINE(HAVE_IPV6, 1, IPv6)
  1078. AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
  1079. RIPNGD="ripngd"
  1080. OSPF6D="ospf6d"
  1081. AC_MSG_RESULT(Solaris IPv6)
  1082. dnl ----------
  1083. dnl Linux IPv6
  1084. dnl ----------
  1085. elif test "${enable_ipv6}" = "yes"; then
  1086. AC_EGREP_CPP(yes, [
  1087. #include <linux/version.h>
  1088. /* 2.1.128 or later */
  1089. #if LINUX_VERSION_CODE >= 0x020180
  1090. yes
  1091. #endif],
  1092. [zebra_cv_ipv6=yes
  1093. zebra_cv_linux_ipv6=yes
  1094. AC_MSG_RESULT(Linux IPv6)])
  1095. else
  1096. if test x`ls /proc/net/ipv6_route 2>/dev/null` = x"/proc/net/ipv6_route"
  1097. then
  1098. zebra_cv_ipv6=yes
  1099. zebra_cv_linux_ipv6=yes
  1100. AC_MSG_RESULT(Linux IPv6)
  1101. fi
  1102. fi
  1103. if test "$zebra_cv_linux_ipv6" = "yes";then
  1104. AC_MSG_CHECKING(whether libc has IPv6 support)
  1105. AC_TRY_LINK([#include <netinet/in.h>
  1106. ],[ int a; a = (int) in6addr_any.s6_addr[0]; if (a != 12345) return a; ],
  1107. [AC_MSG_RESULT(yes)
  1108. zebra_cv_ipv6=yes
  1109. zebra_cv_linux_ipv6=yes],
  1110. [AC_MSG_RESULT(no)
  1111. zebra_cv_ipv6=no
  1112. zebra_cv_linux_ipv6=no])
  1113. fi
  1114. if test "$zebra_cv_linux_ipv6" = "yes";then
  1115. AC_MSG_CHECKING(for GNU libc >= 2.1)
  1116. AC_DEFINE(HAVE_IPV6,1,Linux IPv6)
  1117. AC_EGREP_CPP(yes, [
  1118. #include <features.h>
  1119. #if __GLIBC__ >= 2 && __GLIBC_MINOR__ >= 1
  1120. yes
  1121. #endif],
  1122. [glibc=yes
  1123. AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
  1124. AC_MSG_RESULT(yes)],
  1125. AC_MSG_RESULT(no)
  1126. )
  1127. RIPNGD="ripngd"
  1128. OSPF6D="ospf6d"
  1129. if test "$glibc" != "yes"; then
  1130. INCLUDES="-I/usr/inet6/include"
  1131. if test x`ls /usr/inet6/lib/libinet6.a 2>/dev/null` != x;then
  1132. LIB_IPV6="-L/usr/inet6/lib -linet6"
  1133. fi
  1134. fi
  1135. fi
  1136. dnl -----------------------
  1137. dnl Set IPv6 related values
  1138. dnl -----------------------
  1139. LIBS="$LIB_IPV6 $LIBS"
  1140. AC_SUBST(LIB_IPV6)
  1141. if test x"$RIPNGD" = x""; then
  1142. AC_MSG_RESULT(IPv4 only)
  1143. fi
  1144. fi
  1145. dnl ------------------
  1146. dnl IPv6 header checks
  1147. dnl ------------------
  1148. if test "x${zebra_cv_ipv6}" = "xyes"; then
  1149. AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h netinet/icmp6.h \
  1150. netinet6/in6_var.h netinet6/nd6.h], [], [],
  1151. QUAGGA_INCLUDES)
  1152. fi
  1153. m4_define([QUAGGA_INCLUDES],dnl
  1154. QUAGGA_INCLUDES
  1155. [#if HAVE_NETINET6_IN6_H
  1156. #include <netinet6/in6.h>
  1157. #endif
  1158. #if HAVE_NETINET_IN6_VAR_H
  1159. #include <netinet/in6_var.h>
  1160. #endif
  1161. #if HAVE_NETINET_ICMP6_H
  1162. # include <netinet/icmp6.h>
  1163. #endif
  1164. #if HAVE_NETINET6_IN6_VAR_H
  1165. # include <netinet6/in6_var.h>
  1166. #endif
  1167. #if HAVE_NETINET6_ND6_H
  1168. # include <netinet6/nd6.h>
  1169. #endif
  1170. ])dnl
  1171. dnl disable doc check
  1172. if test "${enable_doc}" = "no";then
  1173. DOC=""
  1174. else
  1175. DOC="doc"
  1176. fi
  1177. dnl --------------------
  1178. dnl Daemon disable check
  1179. dnl --------------------
  1180. if test "${enable_zebra}" = "no";then
  1181. ZEBRA=""
  1182. else
  1183. ZEBRA="zebra"
  1184. fi
  1185. AM_CONDITIONAL(ZEBRA, test "x$ZEBRA" = "xzebra")
  1186. if test "${enable_bgpd}" = "no";then
  1187. BGPD=""
  1188. else
  1189. BGPD="bgpd"
  1190. fi
  1191. AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
  1192. if test "${enable_ripd}" = "no";then
  1193. RIPD=""
  1194. else
  1195. RIPD="ripd"
  1196. fi
  1197. AM_CONDITIONAL(RIPD, test "x$RIPD" = "xripd")
  1198. if test "${enable_ospfd}" = "no";then
  1199. OSPFD=""
  1200. else
  1201. OSPFD="ospfd"
  1202. fi
  1203. AM_CONDITIONAL(OSPFD, test "x$OSPFD" = "xospfd")
  1204. if test "${enable_babeld}" = "no";then
  1205. BABELD=""
  1206. else
  1207. BABELD="babeld"
  1208. fi
  1209. AM_CONDITIONAL(BABELD, test "x$BABELD" = "xbabeld")
  1210. if test "${enable_watchquagga}" = "no";then
  1211. WATCHQUAGGA=""
  1212. else
  1213. WATCHQUAGGA="watchquagga"
  1214. fi
  1215. AM_CONDITIONAL(WATCHQUAGGA, test "x$WATCHQUAGGA" = "xwatchquagga")
  1216. OSPFCLIENT=""
  1217. if test "${enable_opaque_lsa}" != "no"; then
  1218. if test "${enable_ospfapi}" != "no";then
  1219. AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
  1220. if test "${enable_ospfclient}" != "no";then
  1221. OSPFCLIENT="ospfclient"
  1222. fi
  1223. fi
  1224. fi
  1225. AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
  1226. case "${enable_ripngd}" in
  1227. "yes") RIPNGD="ripngd";;
  1228. "no" ) RIPNGD="";;
  1229. * ) ;;
  1230. esac
  1231. AM_CONDITIONAL(RIPNGD, test "x$RIPNGD" = "xripngd")
  1232. case "${enable_ospf6d}" in
  1233. "yes") OSPF6D="ospf6d";;
  1234. "no" ) OSPF6D="";;
  1235. * ) ;;
  1236. esac
  1237. AM_CONDITIONAL(OSPF6D, test "x$OSPF6D" = "xospf6d")
  1238. case "${enable_isisd}" in
  1239. "yes") ISISD="isisd";;
  1240. "no" ) ISISD="";;
  1241. * ) ;;
  1242. esac
  1243. AM_CONDITIONAL(ISISD, test "x$ISISD" = "xisisd")
  1244. # XXX Perhaps auto-enable on Solaris, but that's messy for cross builds.
  1245. case "${enable_solaris}" in
  1246. "yes") SOLARIS="solaris";;
  1247. "no" ) SOLARIS="";;
  1248. * ) ;;
  1249. esac
  1250. if test "${enable_bgp_announce}" = "no";then
  1251. AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
  1252. else
  1253. AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
  1254. fi
  1255. AC_SUBST(DOC)
  1256. AC_SUBST(ZEBRA)
  1257. AC_SUBST(BGPD)
  1258. AC_SUBST(RIPD)
  1259. AC_SUBST(RIPNGD)
  1260. AC_SUBST(OSPFD)
  1261. AC_SUBST(OSPF6D)
  1262. AC_SUBST(BABELD)
  1263. AC_SUBST(WATCHQUAGGA)
  1264. AC_SUBST(ISISD)
  1265. AC_SUBST(SOLARIS)
  1266. AC_SUBST(VTYSH)
  1267. AC_SUBST(INCLUDES)
  1268. AC_SUBST(CURSES)
  1269. AC_SUBST(OSPFCLIENT)
  1270. AC_SUBST(OSPFAPI)
  1271. AC_CHECK_LIB(c, inet_ntop, [AC_DEFINE(HAVE_INET_NTOP,,inet_ntop)])
  1272. AC_CHECK_LIB(c, inet_pton, [AC_DEFINE(HAVE_INET_PTON,,inet_pton)])
  1273. AC_CHECK_LIB(crypt, crypt)
  1274. AC_CHECK_LIB(resolv, res_init)
  1275. dnl ---------------------------------------------------
  1276. dnl BSD/OS 4.1 define inet_XtoY function as __inet_XtoY
  1277. dnl ---------------------------------------------------
  1278. AC_CHECK_FUNC(__inet_ntop, AC_DEFINE(HAVE_INET_NTOP,,__inet_ntop))
  1279. AC_CHECK_FUNC(__inet_pton, AC_DEFINE(HAVE_INET_PTON,,__inet_pton))
  1280. AC_CHECK_FUNC(__inet_aton, AC_DEFINE(HAVE_INET_ATON,,__inet_aton))
  1281. dnl ---------------------------
  1282. dnl check system has PCRE regexp
  1283. dnl ---------------------------
  1284. if test "x$enable_pcreposix" = "xyes"; then
  1285. AC_CHECK_LIB(pcreposix, pcreposix_regexec, ,[enable_pcreposix=no
  1286. AC_MSG_WARN([*** falling back to other regex library ***]) ])
  1287. fi
  1288. if test "x$enable_pcreposix" != "xyes"; then
  1289. dnl ---------------------------
  1290. dnl check system has GNU regexp
  1291. dnl ---------------------------
  1292. AC_MSG_CHECKING(whether system has GNU regex)
  1293. AC_CHECK_LIB(c, regexec,
  1294. [AC_DEFINE(HAVE_GNU_REGEX,,GNU regexp library)
  1295. LIB_REGEX=""],
  1296. [LIB_REGEX="regex.o"])
  1297. fi
  1298. AC_SUBST(HAVE_LIBPCREPOSIX)
  1299. AC_SUBST(LIB_REGEX)
  1300. dnl ------------------
  1301. dnl check Net-SNMP library
  1302. dnl ------------------
  1303. if test "${enable_snmp}" != ""; then
  1304. AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
  1305. if test x"$NETSNMP_CONFIG" = x"no"; then
  1306. AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
  1307. fi
  1308. LIBS="$LIBS `${NETSNMP_CONFIG} --agent-libs`"
  1309. CFLAGS="`${NETSNMP_CONFIG} --base-cflags` $CFLAGS"
  1310. AC_MSG_CHECKING([whether we can link to Net-SNMP])
  1311. AC_LINK_IFELSE([AC_LANG_PROGRAM([
  1312. int main(void);
  1313. ],
  1314. [
  1315. {
  1316. return 0;
  1317. }
  1318. ])],[AC_MSG_RESULT(yes)],[
  1319. AC_MSG_RESULT(no)
  1320. AC_MSG_ERROR([--enable-snmp given but not usable])])
  1321. AC_DEFINE(HAVE_SNMP,,SNMP)
  1322. case "${enable_snmp}" in
  1323. yes)
  1324. SNMP_METHOD=agentx
  1325. ;;
  1326. smux|agentx)
  1327. SNMP_METHOD="${enable_snmp}"
  1328. ;;
  1329. *)
  1330. AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
  1331. ;;
  1332. esac
  1333. AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
  1334. AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
  1335. AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
  1336. fi
  1337. dnl ---------------------------
  1338. dnl sockaddr and netinet checks
  1339. dnl ---------------------------
  1340. AC_CHECK_TYPES([struct sockaddr, struct sockaddr_in,
  1341. struct sockaddr_in6, struct sockaddr_un, struct sockaddr_dl,
  1342. socklen_t,
  1343. struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
  1344. struct nd_opt_adv_interval, struct rt_addrinfo,
  1345. struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
  1346. [], [], QUAGGA_INCLUDES)
  1347. AC_CHECK_MEMBERS([struct sockaddr.sa_len,
  1348. struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
  1349. struct sockaddr_in6.sin6_scope_id,
  1350. struct sockaddr_dl.sdl_len,
  1351. struct if6_aliasreq.ifra_lifetime,
  1352. struct nd_opt_adv_interval.nd_opt_ai_type],
  1353. [], [], QUAGGA_INCLUDES)
  1354. dnl ---------------------------
  1355. dnl IRDP/pktinfo/icmphdr checks
  1356. dnl ---------------------------
  1357. AC_CHECK_TYPES([struct in_pktinfo],
  1358. [AC_CHECK_TYPES([struct icmphdr],
  1359. [if test "${enable_irdp}" != "no"; then
  1360. AC_DEFINE(HAVE_IRDP,, IRDP)
  1361. fi],
  1362. [if test "${enable_irdp}" = "yes"; then
  1363. AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
  1364. fi], [QUAGGA_INCLUDES])],
  1365. [if test "${enable_irdp}" = "yes"; then
  1366. AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
  1367. fi], [QUAGGA_INCLUDES])
  1368. dnl --------------------------------------
  1369. dnl checking for getrusage struct and call
  1370. dnl --------------------------------------
  1371. if test "${enable_rusage}" != "no"; then
  1372. AC_MSG_CHECKING(whether getrusage is available)
  1373. AC_TRY_COMPILE([#include <sys/resource.h>],[struct rusage ac_x; getrusage (RUSAGE_SELF, &ac_x);],
  1374. [AC_MSG_RESULT(yes)
  1375. AC_DEFINE(HAVE_RUSAGE,,rusage)],
  1376. AC_MSG_RESULT(no))
  1377. fi
  1378. dnl --------------------------------------
  1379. dnl checking for clock_time monotonic struct and call
  1380. dnl --------------------------------------
  1381. AC_CHECK_DECL(CLOCK_MONOTONIC,
  1382. [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
  1383. AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
  1384. ], [AC_MSG_RESULT(no)], [QUAGGA_INCLUDES])
  1385. dnl -------------------
  1386. dnl capabilities checks
  1387. dnl -------------------
  1388. if test "${enable_capabilities}" != "no"; then
  1389. AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
  1390. AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
  1391. [AC_MSG_RESULT(yes)
  1392. AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
  1393. quagga_ac_keepcaps="yes"],
  1394. AC_MSG_RESULT(no)
  1395. )
  1396. if test x"${quagga_ac_keepcaps}" = x"yes"; then
  1397. AC_CHECK_HEADERS(sys/capability.h)
  1398. fi
  1399. if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
  1400. AC_CHECK_LIB(cap, cap_init,
  1401. [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
  1402. LIBCAP="-lcap"
  1403. quagga_ac_lcaps="yes"]
  1404. )
  1405. else
  1406. AC_CHECK_HEADERS(priv.h,
  1407. [AC_MSG_CHECKING(Solaris style privileges are available)
  1408. AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
  1409. [AC_MSG_RESULT(yes)
  1410. AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
  1411. quagga_ac_scaps="yes"],
  1412. AC_MSG_RESULT(no)
  1413. )
  1414. ]
  1415. )
  1416. fi
  1417. if test x"${quagga_ac_scaps}" = x"yes" \
  1418. -o x"${quagga_ac_lcaps}" = x"yes"; then
  1419. AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
  1420. fi
  1421. fi
  1422. AC_SUBST(LIBCAP)
  1423. dnl ---------------------------------------------------------------------------
  1424. dnl http://www.gnu.org/software/autoconf-archive/ax_sys_weak_alias.html
  1425. dnl Check for and set one of the following = 1
  1426. dnl HAVE_SYS_WEAK_ALIAS_ATTRIBUTE
  1427. dnl HAVE_SYS_WEAK_ALIAS_PRAGMA
  1428. dnl HAVE_SYS_WEAK_ALIAS_HPSECONDARY
  1429. dnl HAVE_SYS_WEAK_ALIAS_CRIDUPLICATE
  1430. dnl If any scheme is found, set
  1431. dnl HAVE_SYS_WEAK_ALIAS=1
  1432. dnl The following variable is set to text value
  1433. dnl WEAK_ALIAS = "attribute" || "pragma" || "hpsecondary" || "criduplicate" || "no"
  1434. dnl If weak alias can cross object file boundaries
  1435. dnl WEAK_ALIAS_CROSSFILE = "yes" || "no"
  1436. dnl ---------------------------------------------------------------------------
  1437. AX_SYS_WEAK_ALIAS
  1438. dnl ---------------------------
  1439. dnl check for glibc 'backtrace'
  1440. dnl ---------------------------
  1441. if test x"${enable_backtrace}" != x"no" ; then
  1442. backtrace_ok=no
  1443. AC_CHECK_HEADER([execinfo.h], [
  1444. AC_SEARCH_LIBS([backtrace], [execinfo], [
  1445. AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
  1446. AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
  1447. backtrace_ok=yes
  1448. ],, [-lm])
  1449. ])
  1450. if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
  1451. dnl user explicitly requested backtrace but we failed to find support
  1452. AC_MSG_FAILURE([failed to find backtrace support])
  1453. fi
  1454. fi
  1455. dnl -----------------------------------------
  1456. dnl check for malloc mallinfo struct and call
  1457. dnl this must try and link using LIBS, in
  1458. dnl order to check no alternative allocator
  1459. dnl has been specified, which might not provide
  1460. dnl mallinfo, e.g. such as Umem on Solaris.
  1461. dnl -----------------------------------------
  1462. AC_CHECK_HEADER([malloc.h],
  1463. [AC_MSG_CHECKING(whether mallinfo is available)
  1464. AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
  1465. [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
  1466. [AC_MSG_RESULT(yes)
  1467. AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
  1468. AC_MSG_RESULT(no)
  1469. )
  1470. ], [], QUAGGA_INCLUDES)
  1471. dnl ----------
  1472. dnl configure date
  1473. dnl ----------
  1474. CONFDATE=`date '+%Y%m%d'`
  1475. AC_SUBST(CONFDATE)
  1476. dnl Conditionally enable PIE support for GNU toolchains.
  1477. AC_ARG_ENABLE(pie, AS_HELP_STRING([--disable-pie], [Do not build tools as a Position Independent Executables]))
  1478. if test "$enable_pie" != "no"; then
  1479. AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
  1480. save_CFLAGS=$CFLAGS
  1481. save_LDFLAGS=$LDFLAGS
  1482. CFLAGS="$CFLAGS -fPIE"
  1483. LDFLAGS="$LDFLAGS -pie"
  1484. AC_LINK_IFELSE([AC_LANG_SOURCE([[static int foo[30000]; int main () { return 0; }]])],
  1485. [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no]
  1486. )
  1487. CFLAGS=$save_CFLAGS
  1488. LDFLAGS=$save_LDFLAGS
  1489. ])
  1490. if test "$ap_cv_cc_pie" = "yes"; then
  1491. PICFLAGS="-fPIE"
  1492. PILDFLAGS="-pie"
  1493. fi
  1494. fi
  1495. AC_SUBST(PICFLAGS)
  1496. AC_SUBST(PILDFLAGS)
  1497. dnl -------
  1498. dnl DejaGNU
  1499. dnl -------
  1500. if test x"$DEJAGNU" = x
  1501. then
  1502. DEJAGNU="\$(top_srcdir)/tests/global-conf.exp"
  1503. fi
  1504. RUNTESTDEFAULTFLAGS="-x --tool \$\$tool"
  1505. AC_SUBST(DEJAGNU)
  1506. AC_SUBST(RUNTESTDEFAULTFLAGS)
  1507. dnl ------------------------------
  1508. dnl set paths for state directory
  1509. dnl ------------------------------
  1510. AC_MSG_CHECKING(directory to use for state file)
  1511. if test "${prefix}" = "NONE"; then
  1512. quagga_statedir_prefix="";
  1513. else
  1514. quagga_statedir_prefix=${prefix}
  1515. fi
  1516. if test "${localstatedir}" = '${prefix}/var'; then
  1517. for QUAGGA_STATE_DIR in ${quagga_statedir_prefix}/var/run dnl
  1518. ${quagga_statedir_prefix}/var/adm dnl
  1519. ${quagga_statedir_prefix}/etc dnl
  1520. /var/run dnl
  1521. /var/adm dnl
  1522. /etc dnl
  1523. /dev/null;
  1524. do
  1525. test -d $QUAGGA_STATE_DIR && break
  1526. done
  1527. quagga_statedir=$QUAGGA_STATE_DIR
  1528. else
  1529. quagga_statedir=${localstatedir}
  1530. fi
  1531. if test $quagga_statedir = "/dev/null"; then
  1532. AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
  1533. fi
  1534. AC_MSG_RESULT(${quagga_statedir})
  1535. AC_SUBST(quagga_statedir)
  1536. AC_DEFINE_UNQUOTED(PATH_ZEBRA_PID, "$quagga_statedir/zebra.pid",zebra PID)
  1537. AC_DEFINE_UNQUOTED(PATH_RIPD_PID, "$quagga_statedir/ripd.pid",ripd PID)
  1538. AC_DEFINE_UNQUOTED(PATH_RIPNGD_PID, "$quagga_statedir/ripngd.pid",ripngd PID)
  1539. AC_DEFINE_UNQUOTED(PATH_BGPD_PID, "$quagga_statedir/bgpd.pid",bgpd PID)
  1540. AC_DEFINE_UNQUOTED(PATH_OSPFD_PID, "$quagga_statedir/ospfd.pid",ospfd PID)
  1541. AC_DEFINE_UNQUOTED(PATH_OSPF6D_PID, "$quagga_statedir/ospf6d.pid",ospf6d PID)
  1542. AC_DEFINE_UNQUOTED(PATH_BABELD_PID, "$quagga_statedir/babeld.pid",babeld PID)
  1543. AC_DEFINE_UNQUOTED(PATH_ISISD_PID, "$quagga_statedir/isisd.pid",isisd PID)
  1544. AC_DEFINE_UNQUOTED(PATH_WATCHQUAGGA_PID, "$quagga_statedir/watchquagga.pid",watchquagga PID)
  1545. AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$quagga_statedir/zserv.api",zebra api socket)
  1546. AC_DEFINE_UNQUOTED(ZEBRA_VTYSH_PATH, "$quagga_statedir/zebra.vty",zebra vty socket)
  1547. AC_DEFINE_UNQUOTED(RIP_VTYSH_PATH, "$quagga_statedir/ripd.vty",rip vty socket)
  1548. AC_DEFINE_UNQUOTED(RIPNG_VTYSH_PATH, "$quagga_statedir/ripngd.vty",ripng vty socket)
  1549. AC_DEFINE_UNQUOTED(BGP_VTYSH_PATH, "$quagga_statedir/bgpd.vty",bgpd vty socket)
  1550. AC_DEFINE_UNQUOTED(OSPF_VTYSH_PATH, "$quagga_statedir/ospfd.vty",ospfd vty socket)
  1551. AC_DEFINE_UNQUOTED(OSPF6_VTYSH_PATH, "$quagga_statedir/ospf6d.vty",ospf6d vty socket)
  1552. AC_DEFINE_UNQUOTED(BABEL_VTYSH_PATH, "$quagga_statedir/babeld.vty",babeld vty socket)
  1553. AC_DEFINE_UNQUOTED(ISIS_VTYSH_PATH, "$quagga_statedir/isisd.vty",isisd vty socket)
  1554. AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$quagga_statedir",daemon vty directory)
  1555. dnl -------------------------------
  1556. dnl Quagga sources should always be
  1557. dnl current wrt interfaces. Dont
  1558. dnl allow deprecated interfaces to
  1559. dnl be exposed.
  1560. dnl -------------------------------
  1561. AC_DEFINE(QUAGGA_NO_DEPRECATED_INTERFACES, 1, Hide deprecated interfaces)
  1562. dnl ---------------------------
  1563. dnl Check htonl works correctly
  1564. dnl ---------------------------
  1565. AC_MSG_CHECKING(for working htonl)
  1566. AC_CACHE_VAL(ac_cv_htonl_works,
  1567. [AC_LINK_IFELSE([AC_LANG_PROGRAM([QUAGGA_INCLUDES],[htonl (0);])],
  1568. [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
  1569. ]
  1570. )
  1571. AC_MSG_RESULT($ac_cv_htonl_works)
  1572. AC_CONFIG_FILES([Makefile lib/Makefile zebra/Makefile ripd/Makefile
  1573. ripngd/Makefile bgpd/Makefile ospfd/Makefile watchquagga/Makefile
  1574. ospf6d/Makefile isisd/Makefile babeld/Makefile vtysh/Makefile
  1575. doc/Makefile ospfclient/Makefile tests/Makefile m4/Makefile
  1576. tests/bgpd.tests/Makefile
  1577. tests/libzebra.tests/Makefile
  1578. redhat/Makefile
  1579. pkgsrc/Makefile
  1580. redhat/quagga.spec
  1581. lib/version.h
  1582. doc/defines.texi
  1583. isisd/topology/Makefile
  1584. pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
  1585. pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh])
  1586. AC_CONFIG_FILES([solaris/Makefile])
  1587. AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
  1588. ## Hack, but working solution to avoid rebuilding of quagga.info.
  1589. ## It's already in CVS until texinfo 4.7 is more common.
  1590. AC_OUTPUT
  1591. echo "
  1592. Quagga configuration
  1593. --------------------
  1594. quagga version : ${PACKAGE_VERSION}
  1595. host operating system : ${host_os}
  1596. source code location : ${srcdir}
  1597. compiler : ${CC}
  1598. compiler flags : ${CFLAGS}
  1599. make : ${MAKE-make}
  1600. includes : ${INCLUDES}
  1601. linker flags : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
  1602. state file directory : ${quagga_statedir}
  1603. config file directory : `eval echo \`echo ${sysconfdir}\``
  1604. example directory : `eval echo \`echo ${exampledir}\``
  1605. user to run as : ${enable_user}
  1606. group to run as : ${enable_group}
  1607. group for vty sockets : ${enable_vty_group}
  1608. config file mask : ${enable_configfile_mask}
  1609. log file mask : ${enable_logfile_mask}
  1610. The above user and group must have read/write access to the state file
  1611. directory and to the config files in the config file directory."
  1612. if test x"$quagga_cv_gnu_make" = x"no"; then echo "
  1613. Warning: The ${MAKE-make} programme detected, either in your path or
  1614. via the MAKE variable, is not GNU Make. GNU make may be installed as
  1615. gmake on some systems. and is required to complete a build of Quagga
  1616. " > /dev/stderr
  1617. fi