configure.ac 48 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677787980818283848586878889909192939495969798991001011021031041051061071081091101111121131141151161171181191201211221231241251261271281291301311321331341351361371381391401411421431441451461471481491501511521531541551561571581591601611621631641651661671681691701711721731741751761771781791801811821831841851861871881891901911921931941951961971981992002012022032042052062072082092102112122132142152162172182192202212222232242252262272282292302312322332342352362372382392402412422432442452462472482492502512522532542552562572582592602612622632642652662672682692702712722732742752762772782792802812822832842852862872882892902912922932942952962972982993003013023033043053063073083093103113123133143153163173183193203213223233243253263273283293303313323333343353363373383393403413423433443453463473483493503513523533543553563573583593603613623633643653663673683693703713723733743753763773783793803813823833843853863873883893903913923933943953963973983994004014024034044054064074084094104114124134144154164174184194204214224234244254264274284294304314324334344354364374384394404414424434444454464474484494504514524534544554564574584594604614624634644654664674684694704714724734744754764774784794804814824834844854864874884894904914924934944954964974984995005015025035045055065075085095105115125135145155165175185195205215225235245255265275285295305315325335345355365375385395405415425435445455465475485495505515525535545555565575585595605615625635645655665675685695705715725735745755765775785795805815825835845855865875885895905915925935945955965975985996006016026036046056066076086096106116126136146156166176186196206216226236246256266276286296306316326336346356366376386396406416426436446456466476486496506516526536546556566576586596606616626636646656666676686696706716726736746756766776786796806816826836846856866876886896906916926936946956966976986997007017027037047057067077087097107117127137147157167177187197207217227237247257267277287297307317327337347357367377387397407417427437447457467477487497507517527537547557567577587597607617627637647657667677687697707717727737747757767777787797807817827837847857867877887897907917927937947957967977987998008018028038048058068078088098108118128138148158168178188198208218228238248258268278288298308318328338348358368378388398408418428438448458468478488498508518528538548558568578588598608618628638648658668678688698708718728738748758768778788798808818828838848858868878888898908918928938948958968978988999009019029039049059069079089099109119129139149159169179189199209219229239249259269279289299309319329339349359369379389399409419429439449459469479489499509519529539549559569579589599609619629639649659669679689699709719729739749759769779789799809819829839849859869879889899909919929939949959969979989991000100110021003100410051006100710081009101010111012101310141015101610171018101910201021102210231024102510261027102810291030103110321033103410351036103710381039104010411042104310441045104610471048104910501051105210531054105510561057105810591060106110621063106410651066106710681069107010711072107310741075107610771078107910801081108210831084108510861087108810891090109110921093109410951096109710981099110011011102110311041105110611071108110911101111111211131114111511161117111811191120112111221123112411251126112711281129113011311132113311341135113611371138113911401141114211431144114511461147114811491150115111521153115411551156115711581159116011611162116311641165116611671168116911701171117211731174117511761177117811791180118111821183118411851186118711881189119011911192119311941195119611971198119912001201120212031204120512061207120812091210121112121213121412151216121712181219122012211222122312241225122612271228122912301231123212331234123512361237123812391240124112421243124412451246124712481249125012511252125312541255125612571258125912601261126212631264126512661267126812691270127112721273127412751276127712781279128012811282128312841285128612871288128912901291129212931294129512961297129812991300130113021303130413051306130713081309131013111312131313141315131613171318131913201321132213231324132513261327132813291330133113321333133413351336133713381339134013411342134313441345134613471348134913501351135213531354135513561357135813591360136113621363136413651366136713681369137013711372137313741375137613771378137913801381138213831384138513861387138813891390139113921393139413951396139713981399140014011402140314041405140614071408140914101411141214131414141514161417141814191420142114221423142414251426142714281429143014311432143314341435143614371438143914401441144214431444144514461447144814491450145114521453145414551456145714581459146014611462146314641465146614671468146914701471147214731474147514761477147814791480148114821483148414851486148714881489149014911492149314941495149614971498149915001501150215031504150515061507150815091510151115121513151415151516151715181519152015211522152315241525152615271528152915301531153215331534153515361537153815391540154115421543154415451546154715481549155015511552155315541555155615571558155915601561156215631564156515661567156815691570157115721573157415751576157715781579158015811582158315841585158615871588
  1. ##
  2. ## Configure template file for Quagga.
  3. ## autoconf will generate configure script.
  4. ##
  5. ## Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
  6. ## Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
  7. ##
  8. AC_PREREQ(2.60)
  9. AC_INIT(Quagga, 1.0.20160315, [https://bugzilla.quagga.net])
  10. CONFIG_ARGS="$*"
  11. AC_SUBST(CONFIG_ARGS)
  12. AC_CONFIG_SRCDIR(lib/zebra.h)
  13. AC_CONFIG_MACRO_DIR([m4])
  14. dnl -----------------------------------
  15. dnl Get hostname and other information.
  16. dnl -----------------------------------
  17. AC_CANONICAL_BUILD()
  18. AC_CANONICAL_HOST()
  19. AC_CANONICAL_TARGET()
  20. AM_INIT_AUTOMAKE(1.6)
  21. AM_SILENT_RULES([yes])
  22. AC_CONFIG_HEADERS(config.h)
  23. AC_PATH_PROG(PERL, perl)
  24. AC_CHECK_PROG([GAWK],[gawk],[gawk],[not-in-PATH])
  25. if test "x$GAWK" = "xnot-in-PATH" ; then
  26. AC_MSG_ERROR([GNU awk is required for lib/memtype.h made by memtypes.awk.
  27. BSD awk complains: awk: gensub doesn't support backreferences (subst "\1") ])
  28. fi
  29. AC_ARG_VAR([GAWK],[GNU AWK])
  30. dnl default is to match previous behavior
  31. exampledir=${sysconfdir}
  32. AC_ARG_ENABLE([exampledir],
  33. AS_HELP_STRING([--enable-exampledir],
  34. [specify alternate directory for examples]),
  35. exampledir="$enableval",)
  36. dnl XXX add --exampledir to autoconf standard directory list somehow
  37. AC_SUBST(exampledir)
  38. dnl default is to match previous behavior
  39. pkgsrcrcdir=""
  40. pkgsrcdir=""
  41. AC_ARG_ENABLE([pkgsrcrcdir],
  42. AS_HELP_STRING([--enable-pkgsrcrcdir],
  43. [specify directory for rc.d scripts]),
  44. pkgsrcrcdir="$enableval"; pkgsrcdir="pkgsrc",)
  45. dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  46. AC_SUBST(pkgsrcdir)
  47. AC_SUBST(pkgsrcrcdir)
  48. dnl ------------
  49. dnl Check CFLAGS
  50. dnl ------------
  51. AC_ARG_WITH(cflags,
  52. [ --with-cflags Set CFLAGS for use in compilation.])
  53. if test "x$with_cflags" != "x" ; then
  54. CFLAGS="$with_cflags" ; cflags_specified=yes ;
  55. elif test -n "$CFLAGS" ; then
  56. cflags_specified=yes ;
  57. fi
  58. dnl --------------------
  59. dnl Check CC and friends
  60. dnl --------------------
  61. AC_LANG([C])
  62. AC_PROG_CC
  63. AC_PROG_CPP
  64. AM_PROG_CC_C_O
  65. AC_PROG_RANLIB
  66. AC_PROG_EGREP
  67. dnl autoconf 2.59 appears not to support AC_PROG_SED
  68. dnl AC_PROG_SED
  69. AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
  70. dnl pdflatex and latexmk are needed to build HACKING.pdf
  71. AC_CHECK_PROG([PDFLATEX],[pdflatex],[pdflatex],[/bin/false])
  72. AC_CHECK_PROG([LATEXMK],[latexmk],[latexmk],[/bin/false])
  73. if test "x$PDFLATEX" = "x/bin/false" -o "x$LATEXMK" = "x/bin/false"; then
  74. AC_MSG_WARN([Will not be able to make PDF versions of TeX documents])
  75. else
  76. HAVE_LATEX=true
  77. fi
  78. AM_CONDITIONAL([HAVE_LATEX], [test "x$HAVE_LATEX" = "xtrue"])
  79. if test "x${GCC}" != "xyes" ; then
  80. AC_MSG_CHECKING([whether we are using SunPro compiler])
  81. AC_EGREP_CPP([^__SUNPRO_C.*0x5(7|8|9)], ["__SUNPRO_C" __SUNPRO_C],
  82. [AC_MSG_RESULT([no])],
  83. [COMPILER="SUNPRO"
  84. AC_MSG_RESULT([yes])]
  85. )
  86. fi
  87. dnl ---------------------------------------------
  88. dnl If CLFAGS doesn\'t exist set default value
  89. dnl AC_PROG_CC will have set minimal default
  90. dnl already, eg "-O2 -g" for gcc, "-g" for others
  91. dnl (Wall is gcc specific... have to make sure
  92. dnl gcc is being used before setting it)
  93. dnl
  94. dnl Sun Studio 10 / SunPro 5.7 is also supported,
  95. dnl so lets set some sane CFLAGS for it.
  96. dnl ---------------------------------------------
  97. AC_USE_SYSTEM_EXTENSIONS()
  98. AC_DEFUN([AC_C_FLAG], [{
  99. AC_LANG_PUSH(C)
  100. ac_c_flag_save="$CFLAGS"
  101. CFLAGS="$CFLAGS $1"
  102. AC_MSG_CHECKING([[whether $CC supports $1]])
  103. AC_COMPILE_IFELSE(
  104. [AC_LANG_PROGRAM([[]])],
  105. [
  106. AC_MSG_RESULT([yes])
  107. m4_if([$3], [], [], [
  108. CFLAGS="$ac_c_flag_save"
  109. $3
  110. ])
  111. ], [
  112. CFLAGS="$ac_c_flag_save"
  113. AC_MSG_RESULT([no])
  114. $2
  115. ])
  116. AC_LANG_POP(C)
  117. }])
  118. AC_MSG_CHECKING([whether to set a default CFLAGS])
  119. if test "x${cflags_specified}" = "x" ; then
  120. case ${COMPILER} in
  121. "SUNPRO")
  122. CFLAGS="-xO4 -v -g -xspace -xcode=pic32 -xstrconst -xc99"
  123. AC_MSG_RESULT([SunPro default])
  124. ;;
  125. *)
  126. AC_MSG_RESULT([autodetecting])
  127. AC_C_FLAG([-diag-error 10006])
  128. AC_C_FLAG([-std=gnu99])
  129. AC_C_FLAG([-g])
  130. AC_C_FLAG([-Os], [
  131. AC_C_FLAG([-O2])
  132. ])
  133. AC_C_FLAG([-fpie])
  134. AC_C_FLAG([-fno-omit-frame-pointer])
  135. AC_C_FLAG([-Wall])
  136. AC_C_FLAG([-Wextra])
  137. AC_C_FLAG([-Wmissing-prototypes])
  138. AC_C_FLAG([-Wmissing-declarations])
  139. AC_C_FLAG([-Wpointer-arith])
  140. AC_C_FLAG([-Wbad-function-cast])
  141. AC_C_FLAG([-Wwrite-strings])
  142. if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
  143. AC_C_FLAG([-Wcast-qual])
  144. AC_C_FLAG([-Wstrict-prototypes])
  145. AC_C_FLAG([-Wmissing-noreturn])
  146. AC_C_FLAG([-Wmissing-format-attribute])
  147. AC_C_FLAG([-Wunreachable-code])
  148. AC_C_FLAG([-Wpacked])
  149. AC_C_FLAG([-Wpadded])
  150. else
  151. AC_C_FLAG([-Wno-unused-result])
  152. fi
  153. AC_C_FLAG([-Wno-unused-parameter])
  154. AC_C_FLAG([-Wno-missing-field-initializers])
  155. # ICC emits a broken warning for const char *x = a ? "b" : "c";
  156. # for some reason the string consts get 'promoted' to char *,
  157. # triggering a const to non-const conversion warning.
  158. AC_C_FLAG([-diag-disable 3179])
  159. ;;
  160. esac
  161. else
  162. AC_MSG_RESULT([CFLAGS supplied by user])
  163. fi
  164. if test x"${enable_werror}" = x"yes" ; then
  165. WERROR="-Werror"
  166. fi
  167. AC_SUBST(WERROR)
  168. dnl --------------
  169. dnl Check programs
  170. dnl --------------
  171. AC_PROG_INSTALL
  172. AC_PROG_LN_S
  173. AC_PROG_MAKE_SET
  174. AC_CHECK_TOOL(AR, ar)
  175. dnl ---------------------------
  176. dnl We, perhaps unfortunately,
  177. dnl depend on GNU Make specific
  178. dnl constructs.
  179. dnl Give the user a warning if
  180. dnl not GNU Make.
  181. dnl ---------------------------
  182. AC_CACHE_CHECK([if ${MAKE-make} is GNU make], [quagga_cv_gnu_make],
  183. [quagga_cv_gnu_make=no
  184. if ${MAKE-make} --version 2>/dev/null | \
  185. grep '^GNU Make ' >/dev/null ; then
  186. quagga_cv_gnu_make=yes;
  187. fi
  188. ]
  189. )
  190. dnl -----------------
  191. dnl System extensions
  192. dnl -----------------
  193. AC_GNU_SOURCE
  194. dnl -------
  195. dnl libtool
  196. dnl -------
  197. LT_INIT
  198. dnl ----------------------
  199. dnl Packages configuration
  200. dnl ----------------------
  201. AC_ARG_WITH(pkg-extra-version,
  202. AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
  203. [EXTRAVERSION=$withval],)
  204. AC_ARG_WITH(pkg-git-version,
  205. AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
  206. [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
  207. AC_ARG_ENABLE(vtysh,
  208. AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for Quagga]))
  209. AC_ARG_ENABLE(doc,
  210. AS_HELP_STRING([--disable-doc], [do not build docs]))
  211. AC_ARG_ENABLE(zebra,
  212. AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
  213. AC_ARG_ENABLE(bgpd,
  214. AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
  215. AC_ARG_ENABLE(ripd,
  216. AS_HELP_STRING([--disable-ripd], [do not build ripd]))
  217. AC_ARG_ENABLE(ripngd,
  218. AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
  219. AC_ARG_ENABLE(ospfd,
  220. AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
  221. AC_ARG_ENABLE(ospf6d,
  222. AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
  223. AC_ARG_ENABLE(watchquagga,
  224. AS_HELP_STRING([--disable-watchquagga], [do not build watchquagga]))
  225. AC_ARG_ENABLE(isisd,
  226. AS_HELP_STRING([--disable-isisd], [do not build isisd]))
  227. AC_ARG_ENABLE(pimd,
  228. AS_HELP_STRING([--disable-pimd], [do not build pimd]))
  229. AC_ARG_ENABLE(bgp-announce,
  230. AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
  231. AC_ARG_ENABLE(snmp,
  232. AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
  233. AC_ARG_WITH(libpam,
  234. AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
  235. AC_ARG_ENABLE(tcp-zebra,
  236. AS_HELP_STRING([--enable-tcp-zebra], [enable TCP/IP socket connection between zebra and protocol daemon]))
  237. AC_ARG_ENABLE(ospfapi,
  238. AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
  239. AC_ARG_ENABLE(ospfclient,
  240. AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
  241. (this is the default if --disable-ospfapi is set)]))
  242. AC_ARG_ENABLE(multipath,
  243. AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
  244. AC_ARG_ENABLE(user,
  245. AS_HELP_STRING([--enable-user=USER], [user to run Quagga suite as (default quagga)]))
  246. AC_ARG_ENABLE(group,
  247. AS_HELP_STRING([--enable-group=GROUP], [group to run Quagga suite as (default quagga)]))
  248. AC_ARG_ENABLE(vty_group,
  249. AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
  250. AC_ARG_ENABLE(configfile_mask,
  251. AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
  252. AC_ARG_ENABLE(logfile_mask,
  253. AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
  254. AC_ARG_ENABLE(rtadv,
  255. AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
  256. AC_ARG_ENABLE(irdp,
  257. AS_HELP_STRING([--enable-irdp], [enable IRDP server support in zebra]))
  258. AC_ARG_ENABLE(isis_topology,
  259. AS_HELP_STRING([--enable-isis-topology], [enable IS-IS topology generator]))
  260. AC_ARG_ENABLE(capabilities,
  261. AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
  262. AC_ARG_ENABLE(rusage,
  263. AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
  264. AC_ARG_ENABLE(gcc_ultra_verbose,
  265. AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
  266. AC_ARG_ENABLE(linux24_tcp_md5,
  267. AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
  268. AC_ARG_ENABLE(gcc-rdynamic,
  269. AS_HELP_STRING([--enable-gcc-rdynamic], [enable linking with -rdynamic for better backtraces (default if gcc)]))
  270. AC_ARG_ENABLE(backtrace,
  271. AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
  272. AC_ARG_ENABLE(time-check,
  273. AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
  274. AC_ARG_ENABLE(pcreposix,
  275. AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
  276. AC_ARG_ENABLE(fpm,
  277. AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
  278. AC_ARG_ENABLE(werror,
  279. AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
  280. if test x"${enable_gcc_rdynamic}" != x"no" ; then
  281. if test x"${enable_gcc_rdynamic}" = x"yes" -o x"$COMPILER" = x"GCC"; then
  282. LDFLAGS="${LDFLAGS} -rdynamic"
  283. fi
  284. fi
  285. if test x"${enable_time_check}" != x"no" ; then
  286. if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
  287. AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
  288. else
  289. AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
  290. fi
  291. fi
  292. if test "${enable_fpm}" = "yes"; then
  293. AC_DEFINE(HAVE_FPM,,Forwarding Plane Manager support)
  294. fi
  295. if test "${enable_tcp_zebra}" = "yes"; then
  296. AC_DEFINE(HAVE_TCP_ZEBRA,,Use TCP for zebra communication)
  297. fi
  298. if test "${enable_linux24_tcp_md5}" = "yes"; then
  299. AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
  300. fi
  301. AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
  302. if test "${enable_rtadv}" != "no"; then
  303. AC_MSG_RESULT(yes)
  304. AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
  305. else
  306. AC_MSG_RESULT(no)
  307. fi
  308. if test "${enable_irdp}" = "yes"; then
  309. AC_DEFINE(HAVE_IRDP,, IRDP )
  310. fi
  311. if test "${enable_isisd}" != "no" && test "${enable_isis_topology}" = yes; then
  312. AC_DEFINE(TOPOLOGY_GENERATE,,Enable IS-IS topology generator code)
  313. ISIS_TOPOLOGY_INCLUDES="-I\$(srcdir)/topology"
  314. ISIS_TOPOLOGY_DIR="topology"
  315. ISIS_TOPOLOGY_LIB="./topology/libtopology.a"
  316. fi
  317. AC_SUBST(ISIS_TOPOLOGY_INCLUDES)
  318. AC_SUBST(ISIS_TOPOLOGY_DIR)
  319. AC_SUBST(ISIS_TOPOLOGY_LIB)
  320. if test "${enable_user}" = "yes" || test x"${enable_user}" = x""; then
  321. enable_user="quagga"
  322. elif test "${enable_user}" = "no"; then
  323. enable_user="root"
  324. fi
  325. if test "${enable_group}" = "yes" || test x"${enable_group}" = x""; then
  326. enable_group="quagga"
  327. elif test "${enable_group}" = "no"; then
  328. enable_group="root"
  329. fi
  330. if test x"${enable_vty_group}" = x"yes" ; then
  331. AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
  332. elif test x"${enable_vty_group}" != x""; then
  333. if test x"${enable_vty_group}" != x"no"; then
  334. AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
  335. fi
  336. fi
  337. AC_SUBST([enable_user])
  338. AC_SUBST([enable_group])
  339. AC_SUBST([enable_vty_group])
  340. AC_DEFINE_UNQUOTED(QUAGGA_USER, "${enable_user}", Quagga User)
  341. AC_DEFINE_UNQUOTED(QUAGGA_GROUP, "${enable_group}", Quagga Group)
  342. enable_configfile_mask=${enable_configfile_mask:-0600}
  343. AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
  344. enable_logfile_mask=${enable_logfile_mask:-0600}
  345. AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
  346. MPATH_NUM=1
  347. case "${enable_multipath}" in
  348. 0)
  349. MPATH_NUM=64
  350. ;;
  351. [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
  352. MPATH_NUM="${enable_multipath}"
  353. ;;
  354. "")
  355. ;;
  356. *)
  357. AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
  358. ;;
  359. esac
  360. AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
  361. dnl -----------------------------------
  362. dnl Add extra version string to package
  363. dnl name, string and version fields.
  364. dnl -----------------------------------
  365. if test "x${EXTRAVERSION}" != "x" ; then
  366. VERSION="${VERSION}${EXTRAVERSION}"
  367. PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
  368. PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
  369. fi
  370. if test "x$with_pkg_git_version" = "xyes"; then
  371. if test -d "${srcdir}/.git"; then
  372. AC_DEFINE(GIT_VERSION, [1], [include git version info])
  373. else with_pkg_git_version="no"
  374. AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
  375. fi
  376. fi
  377. AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
  378. dnl ------------------------------------
  379. dnl Check C keywords and standard types
  380. dnl ------------------------------------
  381. AC_C_CONST
  382. AC_C_INLINE
  383. AC_C_RESTRICT
  384. AC_C_VOLATILE
  385. AC_HEADER_STDC
  386. AC_HEADER_TIME
  387. AC_HEADER_SYS_WAIT
  388. AC_HEADER_STDBOOL
  389. dnl AC_TYPE_PID_T
  390. AC_TYPE_UID_T
  391. AC_TYPE_MODE_T
  392. AC_TYPE_SIZE_T
  393. AC_STRUCT_TM
  394. dnl -------------------------
  395. dnl Check other header files.
  396. dnl -------------------------
  397. AC_CHECK_HEADERS([stropts.h sys/ksym.h sys/times.h sys/select.h \
  398. sys/types.h linux/version.h netdb.h asm/types.h \
  399. sys/cdefs.h sys/param.h limits.h signal.h \
  400. sys/socket.h netinet/in.h time.h sys/time.h])
  401. dnl Utility macro to avoid retyping includes all the time
  402. m4_define([QUAGGA_INCLUDES],
  403. [#ifdef SUNOS_5
  404. #define _XPG4_2
  405. #define __EXTENSIONS__
  406. #endif
  407. #include <stdio.h>
  408. #if STDC_HEADERS
  409. # include <stdlib.h>
  410. # include <stddef.h>
  411. #else
  412. # if HAVE_STDLIB_H
  413. # include <stdlib.h>
  414. # endif
  415. #endif
  416. #if HAVE_SYS_TYPES_H
  417. # include <sys/types.h>
  418. #endif
  419. /* sys/conf.h depends on param.h on FBSD at least */
  420. #if HAVE_SYS_PARAM_H
  421. # include <sys/param.h>
  422. #endif
  423. /* Required for MAXSIG */
  424. #if HAVE_SIGNAL_H
  425. # include <signal.h>
  426. #endif
  427. #if HAVE_SYS_SOCKET_H
  428. # include <sys/socket.h>
  429. #endif
  430. #ifdef __APPLE__
  431. # define __APPLE_USE_RFC_3542
  432. #endif
  433. #if HAVE_NETINET_IN_H
  434. # include <netinet/in.h>
  435. #endif
  436. #ifdef TIME_WITH_SYS_TIME
  437. # include <sys/time.h>
  438. # include <time.h>
  439. #else
  440. # ifdef HAVE_SYS_TIME_H
  441. # include <sys/time.h>
  442. # else
  443. # include <time.h>
  444. # endif
  445. #endif /* TIME_WITH_SYS_TIME */
  446. ])dnl
  447. dnl HAVE_NET_IF_H must be discovered by the time the longer AC_CHECK_HEADERS
  448. dnl round below execution begins, otherwise it doesn't properly detect
  449. dnl HAVE_NETINET6_IN6_VAR_H, HAVE_NET_IF_VAR_H and HAVE_STRUCT_IN6_ALIASREQ
  450. dnl on FreeBSD (BZ#408).
  451. AC_CHECK_HEADERS([net/if.h], [], [], QUAGGA_INCLUDES)
  452. m4_define([QUAGGA_INCLUDES],
  453. QUAGGA_INCLUDES
  454. [#if HAVE_NET_IF_H
  455. # include <net/if.h>
  456. #endif
  457. ])dnl
  458. dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
  459. dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
  460. dnl an additional round for it.
  461. AC_CHECK_HEADERS([net/if_var.h], [], [], QUAGGA_INCLUDES)
  462. m4_define([QUAGGA_INCLUDES],
  463. QUAGGA_INCLUDES
  464. [#if HAVE_NET_IF_VAR_H
  465. # include <net/if_var.h>
  466. #endif
  467. ])dnl
  468. AC_CHECK_HEADERS([sys/un.h netinet/in_systm.h netinet/in_var.h \
  469. net/if_dl.h net/netopt.h net/route.h \
  470. inet/nd.h arpa/inet.h netinet/ip_icmp.h \
  471. fcntl.h stddef.h sys/ioctl.h syslog.h wchar.h wctype.h \
  472. sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
  473. [], [], QUAGGA_INCLUDES)
  474. AC_CHECK_HEADERS([ucontext.h], [], [],
  475. [#ifndef __USE_GNU
  476. #define __USE_GNU
  477. #endif /* __USE_GNU */
  478. QUAGGA_INCLUDES
  479. ])
  480. m4_define([UCONTEXT_INCLUDES],
  481. [#include <ucontext.h>])dnl
  482. AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
  483. [], [], [UCONTEXT_INCLUDES])
  484. AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
  485. [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
  486. [], [], [UCONTEXT_INCLUDES])],
  487. [], [UCONTEXT_INCLUDES])
  488. AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
  489. [], [], [UCONTEXT_INCLUDES])
  490. m4_define([QUAGGA_INCLUDES],
  491. QUAGGA_INCLUDES
  492. [#if HAVE_SYS_UN_H
  493. # include <sys/un.h>
  494. #endif
  495. #if HAVE_NETINET_IN_SYSTM_H
  496. # include <netinet/in_systm.h>
  497. #endif
  498. #if HAVE_NETINET_IN_VAR_H
  499. # include <netinet/in_var.h>
  500. #endif
  501. #if HAVE_NET_IF_DL_H
  502. # include <net/if_dl.h>
  503. #endif
  504. #if HAVE_NET_NETOPT_H
  505. # include <net/netopt.h>
  506. #endif
  507. #if HAVE_NET_ROUTE_H
  508. # include <net/route.h>
  509. #endif
  510. #if HAVE_INET_ND_H
  511. # include <inet/nd.h>
  512. #endif
  513. #if HAVE_ARPA_INET_H
  514. # include <arpa/inet.h>
  515. #endif
  516. /* Required for IDRP */
  517. #if HAVE_NETINET_IP_ICMP_H
  518. # include <netinet/ip_icmp.h>
  519. #endif
  520. ])dnl
  521. dnl V6 headers are checked below, after we check for v6
  522. dnl Some systems (Solaris 2.x) require libnsl (Network Services Library)
  523. case "$host" in
  524. [*-sunos5.[6-7]*] | [*-solaris2.[6-7]*])
  525. opsys=sol2-6
  526. AC_DEFINE(SUNOS_56, 1, SunOS 5.6 to 5.7)
  527. AC_DEFINE(SUNOS_5, 1, SunOS 5)
  528. AC_CHECK_LIB(xnet, main)
  529. CURSES=-lcurses
  530. SOLARIS="solaris"
  531. ;;
  532. [*-sunos5.[8-9]] \
  533. | [*-sunos5.1[0-9]] \
  534. | [*-sunos5.1[0-9].[0-9]] \
  535. | [*-solaris2.[8-9]] \
  536. | [*-solaris2.1[0-9]] \
  537. | [*-solaris2.1[0-9].[0-9]])
  538. opsys=sol8
  539. AC_DEFINE(SUNOS_59, 1, [SunOS 5.8 up])
  540. AC_DEFINE(SUNOS_5, 1, [SunOS 5])
  541. AC_CHECK_LIB(socket, main)
  542. AC_CHECK_LIB(nsl, main)
  543. AC_CHECK_LIB(umem, main)
  544. AC_CHECK_FUNCS([printstack],
  545. [AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
  546. AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
  547. ])
  548. CURSES=-lcurses
  549. SOLARIS="solaris"
  550. ;;
  551. *-sunos5* | *-solaris2*)
  552. AC_DEFINE(SUNOS_5,,SunOS 5, Unknown SunOS)
  553. AC_CHECK_LIB(socket, main)
  554. AC_CHECK_LIB(nsl, main)
  555. CURSES=-lcurses
  556. SOLARIS="solaris"
  557. ;;
  558. *-linux*)
  559. opsys=gnu-linux
  560. AC_DEFINE(GNU_LINUX,,GNU Linux)
  561. ;;
  562. *-openbsd*)
  563. opsys=openbsd
  564. AC_DEFINE(OPEN_BSD,,OpenBSD)
  565. ;;
  566. esac
  567. AC_SYS_LARGEFILE
  568. dnl ---------------------
  569. dnl Integrated VTY option
  570. dnl ---------------------
  571. case "${enable_vtysh}" in
  572. "no") VTYSH="";;
  573. *) VTYSH="vtysh";
  574. AC_DEFINE(VTYSH,,VTY shell)
  575. dnl Vtysh uses libreadline, which looks for termcap functions at
  576. dnl configure time. We follow readlines search order.
  577. dnl The required procedures are in libtermcap on NetBSD, in
  578. dnl [TODO] on Linux, and in [TODO] on Solaris.
  579. AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
  580. [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
  581. [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
  582. [AC_CHECK_LIB(ncurses, tputs,
  583. LIBREADLINE="$LIBREADLINE -lncurses")]
  584. )]
  585. )]
  586. )
  587. AC_CHECK_LIB(readline, main, LIBREADLINE="$LIBREADLINE -lreadline",,
  588. "$LIBREADLINE")
  589. if test $ac_cv_lib_readline_main = no; then
  590. AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
  591. fi
  592. AC_CHECK_HEADER(readline/history.h)
  593. if test $ac_cv_header_readline_history_h = no;then
  594. AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
  595. fi
  596. AC_CHECK_LIB(readline, rl_completion_matches,
  597. LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
  598. if test $ac_cv_lib_readline_rl_completion_matches = no; then
  599. AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
  600. fi
  601. ;;
  602. "no" ) VTYSH="";;
  603. esac
  604. AC_SUBST(LIBREADLINE)
  605. AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
  606. dnl ----------
  607. dnl PAM module
  608. dnl
  609. dnl Quagga detects the PAM library it is built against by checking for a
  610. dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
  611. dnl is known to #include pam_appl.h, the standard header of a PAM library, and
  612. dnl openpam.h doesn't do that, although depends on the header too. Hence a
  613. dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
  614. dnl of OpenPAM.
  615. dnl ----------
  616. if test "$with_libpam" = "yes"; then
  617. AC_CHECK_HEADER([security/pam_misc.h],
  618. [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
  619. AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
  620. pam_conv_func="misc_conv"
  621. ],
  622. [], QUAGGA_INCLUDES)
  623. AC_CHECK_HEADER([security/openpam.h],
  624. [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
  625. AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
  626. pam_conv_func="openpam_ttyconv"
  627. ],
  628. [], QUAGGA_INCLUDES[#include <security/pam_appl.h>])
  629. if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
  630. AC_MSG_WARN([*** pam support will not be built ***])
  631. with_libpam="no"
  632. fi
  633. fi
  634. if test "$with_libpam" = "yes"; then
  635. dnl took this test from proftpds configure.in and suited to our needs
  636. dnl -------------------------------------------------------------------------
  637. dnl
  638. dnl This next check looks funky due to a linker problem with some versions
  639. dnl of the PAM library. Prior to 0.72 release, the Linux PAM shared library
  640. dnl omitted requiring libdl linking information. PAM-0.72 or better ships
  641. dnl with RedHat 6.2 and Debian 2.2 or better.
  642. AC_CHECK_LIB(pam, pam_start,
  643. [AC_CHECK_LIB(pam, $pam_conv_func,
  644. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  645. LIBPAM="-lpam"],
  646. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  647. LIBPAM="-lpam -lpam_misc"]
  648. )
  649. ],
  650. [AC_CHECK_LIB(pam, pam_end,
  651. [AC_CHECK_LIB(pam, $pam_conv_func,
  652. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  653. LIBPAM="-lpam -ldl"],
  654. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  655. LIBPAM="-lpam -ldl -lpam_misc"]
  656. )
  657. ],AC_MSG_WARN([*** pam support will not be built ***]),
  658. [-ldl])
  659. ]
  660. )
  661. fi
  662. AC_SUBST(LIBPAM)
  663. dnl -------------------------------
  664. dnl Endian-ness check
  665. dnl -------------------------------
  666. AC_WORDS_BIGENDIAN
  667. dnl -------------------------------
  668. dnl check the size in byte of the C
  669. dnl -------------------------------
  670. dnl AC_CHECK_SIZEOF(char)
  671. dnl AC_CHECK_SIZEOF(int)
  672. dnl AC_CHECK_SIZEOF(short)
  673. dnl AC_CHECK_SIZEOF(long)
  674. dnl ----------------------------
  675. dnl check existance of functions
  676. dnl ----------------------------
  677. AC_FUNC_CHOWN
  678. AC_FUNC_FNMATCH
  679. AC_FUNC_FORK
  680. AC_FUNC_MEMCMP
  681. AC_FUNC_MKTIME
  682. AC_FUNC_STRFTIME
  683. AC_FUNC_STAT
  684. AC_FUNC_SELECT_ARGTYPES
  685. AC_FUNC_STRFTIME
  686. dnl Avoid AC_FUNC_STRNLEN because it pulls in AC_SYSTEM_EXTENSIONS which
  687. dnl can lead to strange side effects. So we just check for strnlen
  688. dnl directly, see below.
  689. dnl AC_FUNC_STRNLENdnl
  690. AC_FUNC_VPRINTF
  691. dnl -------------------------------
  692. dnl bgpd needs pow() and hence libm
  693. dnl -------------------------------
  694. TMPLIBS="$LIBS"
  695. AC_CHECK_HEADER([math.h],
  696. [AC_CHECK_LIB([m], [pow],
  697. [LIBM="-lm"
  698. LIBS="$LIBS $LIBM"
  699. AC_DEFINE(HAVE_LIBM,, Have libm)
  700. AC_CHECK_FUNCS(pow,[],[LIBM=""])
  701. ])
  702. ])
  703. if test x"$LIBM" = x ; then
  704. AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
  705. fi
  706. LIBS="$TMPLIBS"
  707. AC_SUBST(LIBM)
  708. dnl ---------------
  709. dnl other functions
  710. dnl ---------------
  711. AC_CHECK_FUNCS([dup2 ftruncate getcwd gethostbyname getpagesize gettimeofday \
  712. inet_ntoa inet_aton strnlen \
  713. memchr memmove memset select socket \
  714. strcasecmp strchr strcspn strdup strerror \
  715. strncasecmp strndup strrchr strspn strstr \
  716. strtol strtoul strlcat strlcpy \
  717. daemon snprintf vsnprintf \
  718. if_nametoindex if_indextoname getifaddrs \
  719. uname fcntl getgrouplist])
  720. AC_CHECK_FUNCS(setproctitle, ,
  721. [AC_CHECK_LIB(util, setproctitle,
  722. [LIBS="$LIBS -lutil"
  723. AC_DEFINE(HAVE_SETPROCTITLE,, Have setproctitle)
  724. ]
  725. )
  726. ]
  727. )
  728. AC_CHECK_HEADER([asm-generic/unistd.h],
  729. [AC_CHECK_DECL(__NR_setns,
  730. AC_DEFINE(HAVE_NETNS,, Have netns),,
  731. QUAGGA_INCLUDES [#include <asm-generic/unistd.h>
  732. ])
  733. AC_CHECK_FUNCS(setns, AC_DEFINE(HAVE_SETNS,, Have setns))]
  734. )
  735. dnl ------------------------------------
  736. dnl Determine routing get and set method
  737. dnl ------------------------------------
  738. AC_MSG_CHECKING(zebra between kernel interface method)
  739. if test x"$opsys" = x"gnu-linux"; then
  740. AC_MSG_RESULT(netlink)
  741. RT_METHOD=rt_netlink.o
  742. AC_DEFINE(HAVE_NETLINK,,netlink)
  743. netlink=yes
  744. else
  745. AC_MSG_RESULT(Route socket)
  746. KERNEL_METHOD="kernel_socket.o"
  747. RT_METHOD="rt_socket.o"
  748. fi
  749. AC_SUBST(RT_METHOD)
  750. AC_SUBST(KERNEL_METHOD)
  751. AM_CONDITIONAL([HAVE_NETLINK], [test "x$netlink" = "xyes"])
  752. dnl --------------------------
  753. dnl Determine IS-IS I/O method
  754. dnl --------------------------
  755. AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
  756. AC_DEFINE(ISIS_METHOD_DLPI, 2, [ constant value for isis method dlpi ])
  757. AC_DEFINE(ISIS_METHOD_BPF, 3, [ constant value for isis method bpf ])
  758. AC_CHECK_HEADER(net/bpf.h)
  759. AC_CHECK_HEADER(sys/dlpi.h)
  760. AC_MSG_CHECKING(zebra IS-IS I/O method)
  761. if test x"$opsys" = x"gnu-linux"; then
  762. AC_MSG_RESULT(pfpacket)
  763. ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
  764. elif test x"$opsys" = x"sol2-6" -o x"$opsys" = x"sol8"; then
  765. AC_MSG_RESULT(DLPI)
  766. ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
  767. else
  768. if test $ac_cv_header_net_bpf_h = no; then
  769. if test $ac_cv_header_sys_dlpi_h = no; then
  770. AC_MSG_RESULT(none)
  771. AC_MSG_WARN([*** IS-IS support will not be built ***])
  772. ISISD=""
  773. else
  774. AC_MSG_RESULT(DLPI)
  775. fi
  776. ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
  777. else
  778. AC_MSG_RESULT(BPF)
  779. ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
  780. fi
  781. fi
  782. AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
  783. dnl ------------------------------------
  784. dnl check for broken CMSG_FIRSTHDR macro
  785. dnl ------------------------------------
  786. AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
  787. AC_RUN_IFELSE([AC_LANG_SOURCE([[
  788. #ifdef SUNOS_5
  789. #define _XPG4_2
  790. #define __EXTENSIONS__
  791. #endif
  792. #ifdef HAVE_STDLIB_H
  793. # include <stdlib.h>
  794. #endif
  795. #ifdef HAVE_SYS_TYPES_H
  796. #include <sys/types.h>
  797. #endif
  798. #ifdef HAVE_SYS_SOCKET_H
  799. #include <sys/socket.h>
  800. #endif
  801. main()
  802. {
  803. struct msghdr msg;
  804. char buf[4];
  805. msg.msg_control = buf;
  806. msg.msg_controllen = 0;
  807. if (CMSG_FIRSTHDR(&msg) != NULL)
  808. exit(0);
  809. exit (1);
  810. }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
  811. [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
  812. dnl ------------------------------
  813. dnl check kernel route read method
  814. dnl ------------------------------
  815. AC_CACHE_CHECK([route read method], [quagga_cv_rtread_method],
  816. [if test "x$netlink" = xyes; then
  817. quagga_cv_rtread_method="netlink"
  818. else
  819. for quagga_cv_rtread_method in /dev/ip /dev/null;
  820. do
  821. test x`ls $quagga_cv_rtread_method 2>/dev/null` = x"$quagga_cv_rtread_method" && break
  822. done
  823. case $quagga_cv_rtread_method in
  824. "/dev/ip")
  825. case "$host" in
  826. *-freebsd*) quagga_cv_rtread_method="sysctl";;
  827. *) quagga_cv_rtread_method="getmsg";;
  828. esac;;
  829. *)
  830. quagga_cv_rtread_method="sysctl";;
  831. esac
  832. fi])
  833. RTREAD_METHOD=rtread_${quagga_cv_rtread_method}.o
  834. AC_SUBST(RTREAD_METHOD)
  835. dnl -----------------------------
  836. dnl check interface lookup method
  837. dnl -----------------------------
  838. IOCTL_METHOD=ioctl.o
  839. AC_MSG_CHECKING(interface looking up method)
  840. if test "$netlink" = yes; then
  841. AC_MSG_RESULT(netlink)
  842. IF_METHOD=if_netlink.o
  843. elif test "$opsys" = "sol2-6";then
  844. AC_MSG_RESULT(Solaris GIF)
  845. IF_METHOD=if_ioctl.o
  846. elif test "$opsys" = "sol8";then
  847. AC_MSG_RESULT(Solaris GLIF)
  848. IF_METHOD=if_ioctl_solaris.o
  849. IOCTL_METHOD=ioctl_solaris.o
  850. elif test "$opsys" = "openbsd";then
  851. AC_MSG_RESULT(openbsd)
  852. IF_METHOD=if_ioctl.o
  853. elif grep NET_RT_IFLIST /usr/include/sys/socket.h >/dev/null 2>&1; then
  854. AC_MSG_RESULT(sysctl)
  855. IF_METHOD=if_sysctl.o
  856. AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
  857. else
  858. AC_MSG_RESULT(ioctl)
  859. IF_METHOD=if_ioctl.o
  860. fi
  861. AC_SUBST(IF_METHOD)
  862. AC_SUBST(IOCTL_METHOD)
  863. dnl ---------------------------------------------------------------
  864. dnl figure out how to specify an interface in multicast sockets API
  865. dnl ---------------------------------------------------------------
  866. AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], QUAGGA_INCLUDES)
  867. AC_CHECK_HEADERS([linux/mroute.h], [], [],
  868. [
  869. #if HAVE_NETINET_IN_H
  870. #include<netinet/in.h>
  871. #endif])
  872. AC_MSG_CHECKING([for BSD struct ip_mreq hack])
  873. AC_TRY_COMPILE([#ifdef HAVE_SYS_PARAM_H
  874. #include <sys/param.h>
  875. #endif],[#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
  876. return (0);
  877. #else
  878. #error No support for BSD struct ip_mreq hack detected
  879. #endif],[AC_MSG_RESULT(yes)
  880. AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
  881. AC_MSG_RESULT(no))
  882. AC_MSG_CHECKING([for RFC3678 protocol-independed API])
  883. AC_TRY_COMPILE([
  884. #include <sys/types.h>
  885. #include <netinet/in.h>
  886. ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
  887. ], [AC_MSG_RESULT(yes)
  888. AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
  889. AC_MSG_RESULT(no))
  890. dnl ---------------------------------------------------------------
  891. dnl figure out how to check link-state
  892. dnl ---------------------------------------------------------------
  893. AC_CHECK_HEADER([net/if.h],
  894. [AC_CHECK_HEADER( [net/if_media.h],
  895. [m4_define([LINK_DETECT_INCLUDES],
  896. QUAGGA_INCLUDES
  897. [#include <net/if_media.h>
  898. ])
  899. AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
  900. AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
  901. [], LINK_DETECT_INCLUDES)],
  902. [],
  903. QUAGGA_INCLUDES)],
  904. [], QUAGGA_INCLUDES )
  905. dnl ---------------------------------------------------------------
  906. dnl Additional, newer way to check link-state using ifi_link_state.
  907. dnl Not available in all BSD's when ifmediareq available
  908. dnl ---------------------------------------------------------------
  909. AC_CHECK_HEADER([net/if.h],
  910. AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
  911. AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
  912. [], QUAGGA_INCLUDES),
  913. ,)
  914. dnl ------------------------
  915. dnl TCP_MD5SIG socket option
  916. dnl ------------------------
  917. AC_CHECK_HEADER([netinet/tcp.h],
  918. [m4_define([MD5_INCLUDES],
  919. QUAGGA_INCLUDES
  920. [#include <netinet/tcp.h>
  921. ])
  922. AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
  923. [],
  924. QUAGGA_INCLUDES)
  925. if test $ac_cv_have_decl_TCP_MD5SIG = no; then
  926. AC_CHECK_HEADER([linux/tcp.h],
  927. [m4_define([MD5_INCLUDES],
  928. QUAGGA_INCLUDES
  929. [#include <linux/tcp.h>
  930. ])
  931. AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
  932. fi
  933. dnl -----------------------------
  934. dnl check ipforward detect method
  935. dnl -----------------------------
  936. AC_CACHE_CHECK([ipforward method], [quagga_cv_ipforward_method],
  937. [if test x$cross_compiling = xyes; then
  938. if test x"$opsys" = x"gnu-linux"; then
  939. quagga_cv_ipforward_method=/proc/net/snmp
  940. else
  941. quagga_cv_ipforward_method=/dev/ip
  942. fi
  943. else
  944. for quagga_cv_ipforward_method in /proc/net/snmp /dev/ip /dev/null;
  945. do
  946. test x`ls $quagga_cv_ipforward_method 2>/dev/null` = x"$quagga_cv_ipforward_method" && break
  947. done
  948. fi
  949. case $quagga_cv_ipforward_method in
  950. "/proc/net/snmp") quagga_cv_ipforward_method="proc";;
  951. "/dev/ip")
  952. case "$host" in
  953. *-freebsd*) quagga_cv_ipforward_method="sysctl";;
  954. *) quagga_cv_ipforward_method="solaris";;
  955. esac;;
  956. *) quagga_cv_ipforward_method="sysctl";;
  957. esac])
  958. IPFORWARD=ipforward_${quagga_cv_ipforward_method}.o
  959. AC_SUBST(IPFORWARD)
  960. AC_CHECK_FUNCS(getaddrinfo, [have_getaddrinfo=yes], [have_getaddrinfo=no])
  961. dnl ----------
  962. dnl IPv6 check
  963. dnl ----------
  964. AC_MSG_CHECKING(whether does this OS have IPv6 stack)
  965. dnl ---------
  966. dnl KAME IPv6
  967. dnl ---------
  968. if grep WIDE /usr/include/netinet6/in6.h >/dev/null 2>&1; then
  969. AC_DEFINE(KAME,1,KAME IPv6)
  970. AC_MSG_RESULT(KAME)
  971. dnl ------------------------------------
  972. dnl Solaris 9, 10 and potentially higher
  973. dnl ------------------------------------
  974. elif test x"$opsys" = x"sol8"; then
  975. AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
  976. AC_MSG_RESULT(Solaris IPv6)
  977. dnl ----------
  978. dnl Linux IPv6
  979. dnl ----------
  980. elif test x"$opsys" = x"gnu-linux"; then
  981. AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
  982. AC_MSG_RESULT(Linux IPv6)
  983. else
  984. AC_MSG_ERROR([Failed to detect IPv6 stack])
  985. fi
  986. dnl this is unconditial, for compatibility
  987. AC_DEFINE(HAVE_IPV6,1,IPv6)
  988. dnl ------------------
  989. dnl IPv6 header checks
  990. dnl ------------------
  991. AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h netinet/icmp6.h \
  992. netinet6/in6_var.h netinet6/nd6.h], [], [],
  993. QUAGGA_INCLUDES)
  994. m4_define([QUAGGA_INCLUDES],dnl
  995. QUAGGA_INCLUDES
  996. [#if HAVE_NETINET6_IN6_H
  997. #include <netinet6/in6.h>
  998. #endif
  999. #if HAVE_NETINET_IN6_VAR_H
  1000. #include <netinet/in6_var.h>
  1001. #endif
  1002. #if HAVE_NETINET_ICMP6_H
  1003. # include <netinet/icmp6.h>
  1004. #endif
  1005. #if HAVE_NETINET6_IN6_VAR_H
  1006. # include <netinet6/in6_var.h>
  1007. #endif
  1008. #if HAVE_NETINET6_ND6_H
  1009. # include <netinet6/nd6.h>
  1010. #endif
  1011. ])dnl
  1012. dnl disable doc check
  1013. if test "${enable_doc}" = "no";then
  1014. DOC=""
  1015. else
  1016. DOC="doc"
  1017. fi
  1018. dnl --------------------
  1019. dnl Daemon disable check
  1020. dnl --------------------
  1021. if test "${enable_zebra}" = "no";then
  1022. ZEBRA=""
  1023. else
  1024. ZEBRA="zebra"
  1025. fi
  1026. AM_CONDITIONAL(ZEBRA, test "x$ZEBRA" = "xzebra")
  1027. if test "${enable_bgpd}" = "no";then
  1028. BGPD=""
  1029. else
  1030. BGPD="bgpd"
  1031. fi
  1032. AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
  1033. if test "${enable_ripd}" = "no";then
  1034. RIPD=""
  1035. else
  1036. RIPD="ripd"
  1037. fi
  1038. AM_CONDITIONAL(RIPD, test "x$RIPD" = "xripd")
  1039. if test "${enable_ospfd}" = "no";then
  1040. OSPFD=""
  1041. else
  1042. OSPFD="ospfd"
  1043. fi
  1044. AM_CONDITIONAL(OSPFD, test "x$OSPFD" = "xospfd")
  1045. if test "${enable_watchquagga}" = "no";then
  1046. WATCHQUAGGA=""
  1047. else
  1048. WATCHQUAGGA="watchquagga"
  1049. fi
  1050. AM_CONDITIONAL(WATCHQUAGGA, test "x$WATCHQUAGGA" = "xwatchquagga")
  1051. OSPFCLIENT=""
  1052. if test "${enable_ospfapi}" != "no";then
  1053. AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
  1054. if test "${enable_ospfclient}" != "no";then
  1055. OSPFCLIENT="ospfclient"
  1056. fi
  1057. fi
  1058. AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
  1059. case "${enable_ripngd}" in
  1060. "no" ) RIPNGD="";;
  1061. * ) RIPNGD="ripngd";;
  1062. esac
  1063. AM_CONDITIONAL(RIPNGD, test "x$RIPNGD" = "xripngd")
  1064. case "${enable_ospf6d}" in
  1065. "no" ) OSPF6D="";;
  1066. * ) OSPF6D="ospf6d";;
  1067. esac
  1068. AM_CONDITIONAL(OSPF6D, test "x$OSPF6D" = "xospf6d")
  1069. case "${enable_isisd}" in
  1070. "no" ) ISISD="";;
  1071. * ) ISISD="isisd";;
  1072. esac
  1073. AM_CONDITIONAL(ISISD, test "x$ISISD" = "xisisd")
  1074. case "${enable_pimd}" in
  1075. "no" ) PIMD="";;
  1076. * ) PIMD="pimd";;
  1077. esac
  1078. AM_CONDITIONAL(PIMD, test "x$PIMD" = "xpimd")
  1079. if test "${enable_bgp_announce}" = "no";then
  1080. AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
  1081. else
  1082. AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
  1083. fi
  1084. AC_SUBST(DOC)
  1085. AC_SUBST(ZEBRA)
  1086. AC_SUBST(BGPD)
  1087. AC_SUBST(RIPD)
  1088. AC_SUBST(RIPNGD)
  1089. AC_SUBST(OSPFD)
  1090. AC_SUBST(OSPF6D)
  1091. AC_SUBST(WATCHQUAGGA)
  1092. AC_SUBST(ISISD)
  1093. AC_SUBST(PIMD)
  1094. AC_SUBST(SOLARIS)
  1095. AC_SUBST(VTYSH)
  1096. AC_SUBST(CURSES)
  1097. AC_SUBST(OSPFCLIENT)
  1098. AC_SUBST(OSPFAPI)
  1099. AC_CHECK_LIB(c, inet_ntop, [AC_DEFINE(HAVE_INET_NTOP,,inet_ntop)])
  1100. AC_CHECK_LIB(c, inet_pton, [AC_DEFINE(HAVE_INET_PTON,,inet_pton)])
  1101. AC_CHECK_LIB(crypt, crypt)
  1102. AC_CHECK_LIB(resolv, res_init)
  1103. dnl ---------------------------
  1104. dnl check system has PCRE regexp
  1105. dnl ---------------------------
  1106. if test "x$enable_pcreposix" = "xyes"; then
  1107. AC_CHECK_LIB(pcreposix, pcreposix_regexec, ,[enable_pcreposix=no
  1108. AC_MSG_WARN([*** falling back to other regex library ***]) ])
  1109. fi
  1110. if test "x$enable_pcreposix" != "xyes"; then
  1111. dnl ---------------------------
  1112. dnl check system has GNU regexp
  1113. dnl ---------------------------
  1114. AC_MSG_CHECKING(whether system has GNU regex)
  1115. AC_CHECK_LIB(c, regexec,
  1116. [AC_DEFINE(HAVE_GNU_REGEX,,GNU regexp library)
  1117. LIB_REGEX=""],
  1118. [LIB_REGEX="regex.o"])
  1119. fi
  1120. AC_SUBST(HAVE_LIBPCREPOSIX)
  1121. AC_SUBST(LIB_REGEX)
  1122. dnl ------------------
  1123. dnl check Net-SNMP library
  1124. dnl ------------------
  1125. if test "${enable_snmp}" != ""; then
  1126. AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
  1127. if test x"$NETSNMP_CONFIG" = x"no"; then
  1128. AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
  1129. fi
  1130. LIBS="$LIBS `${NETSNMP_CONFIG} --agent-libs`"
  1131. CFLAGS="`${NETSNMP_CONFIG} --base-cflags` $CFLAGS"
  1132. AC_MSG_CHECKING([whether we can link to Net-SNMP])
  1133. AC_LINK_IFELSE([AC_LANG_PROGRAM([
  1134. int main(void);
  1135. ],
  1136. [
  1137. {
  1138. return 0;
  1139. }
  1140. ])],[AC_MSG_RESULT(yes)],[
  1141. AC_MSG_RESULT(no)
  1142. AC_MSG_ERROR([--enable-snmp given but not usable])])
  1143. AC_DEFINE(HAVE_SNMP,,SNMP)
  1144. case "${enable_snmp}" in
  1145. yes)
  1146. SNMP_METHOD=agentx
  1147. ;;
  1148. smux|agentx)
  1149. SNMP_METHOD="${enable_snmp}"
  1150. ;;
  1151. *)
  1152. AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
  1153. ;;
  1154. esac
  1155. AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
  1156. AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
  1157. AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
  1158. fi
  1159. dnl ---------------------------
  1160. dnl sockaddr and netinet checks
  1161. dnl ---------------------------
  1162. AC_CHECK_TYPES([struct sockaddr, struct sockaddr_in,
  1163. struct sockaddr_in6, struct sockaddr_un, struct sockaddr_dl,
  1164. socklen_t, struct vifctl, struct mfcctl, struct sioc_sg_req,
  1165. vifi_t, struct sioc_vif_req, struct igmpmsg,
  1166. struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
  1167. struct nd_opt_adv_interval, struct rt_addrinfo,
  1168. struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
  1169. [], [], QUAGGA_INCLUDES)
  1170. AC_CHECK_MEMBERS([struct sockaddr.sa_len,
  1171. struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
  1172. struct sockaddr_in6.sin6_scope_id,
  1173. struct sockaddr_dl.sdl_len,
  1174. struct if6_aliasreq.ifra_lifetime,
  1175. struct nd_opt_adv_interval.nd_opt_ai_type],
  1176. [], [], QUAGGA_INCLUDES)
  1177. dnl ---------------------------
  1178. dnl IRDP/pktinfo/icmphdr checks
  1179. dnl ---------------------------
  1180. AC_CHECK_TYPES([struct in_pktinfo],
  1181. [AC_CHECK_TYPES([struct icmphdr],
  1182. [if test "${enable_irdp}" != "no"; then
  1183. AC_DEFINE(HAVE_IRDP,, IRDP)
  1184. fi],
  1185. [if test "${enable_irdp}" = "yes"; then
  1186. AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
  1187. fi], [QUAGGA_INCLUDES])],
  1188. [if test "${enable_irdp}" = "yes"; then
  1189. AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
  1190. fi], [QUAGGA_INCLUDES])
  1191. dnl -----------------------
  1192. dnl checking for IP_PKTINFO
  1193. dnl -----------------------
  1194. AC_MSG_CHECKING(for IP_PKTINFO)
  1195. AC_TRY_COMPILE([#include <netdb.h>], [
  1196. int opt = IP_PKTINFO;
  1197. ], [
  1198. AC_MSG_RESULT(yes)
  1199. AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
  1200. ], [
  1201. AC_MSG_RESULT(no)
  1202. ])
  1203. dnl ---------------------------
  1204. dnl checking for IP_RECVDSTADDR
  1205. dnl ---------------------------
  1206. AC_MSG_CHECKING(for IP_RECVDSTADDR)
  1207. AC_TRY_COMPILE([#include <netinet/in.h>], [
  1208. int opt = IP_RECVDSTADDR;
  1209. ], [
  1210. AC_MSG_RESULT(yes)
  1211. AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
  1212. ], [
  1213. AC_MSG_RESULT(no)
  1214. ])
  1215. dnl ----------------------
  1216. dnl checking for IP_RECVIF
  1217. dnl ----------------------
  1218. AC_MSG_CHECKING(for IP_RECVIF)
  1219. AC_TRY_COMPILE([#include <netinet/in.h>], [
  1220. int opt = IP_RECVIF;
  1221. ], [
  1222. AC_MSG_RESULT(yes)
  1223. AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
  1224. ], [
  1225. AC_MSG_RESULT(no)
  1226. ])
  1227. dnl --------------------------------------
  1228. dnl checking for getrusage struct and call
  1229. dnl --------------------------------------
  1230. if test "${enable_rusage}" != "no"; then
  1231. AC_MSG_CHECKING(whether getrusage is available)
  1232. AC_TRY_COMPILE([#include <sys/resource.h>],[struct rusage ac_x; getrusage (RUSAGE_SELF, &ac_x);],
  1233. [AC_MSG_RESULT(yes)
  1234. AC_DEFINE(HAVE_RUSAGE,,rusage)],
  1235. AC_MSG_RESULT(no))
  1236. fi
  1237. dnl --------------------------------------
  1238. dnl checking for clock_time monotonic struct and call
  1239. dnl --------------------------------------
  1240. AC_CHECK_DECL(CLOCK_MONOTONIC,
  1241. [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
  1242. AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
  1243. ], [AC_MSG_RESULT(no)], [QUAGGA_INCLUDES])
  1244. dnl -------------------
  1245. dnl capabilities checks
  1246. dnl -------------------
  1247. if test "${enable_capabilities}" != "no"; then
  1248. AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
  1249. AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
  1250. [AC_MSG_RESULT(yes)
  1251. AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
  1252. quagga_ac_keepcaps="yes"],
  1253. AC_MSG_RESULT(no)
  1254. )
  1255. if test x"${quagga_ac_keepcaps}" = x"yes"; then
  1256. AC_CHECK_HEADERS(sys/capability.h)
  1257. fi
  1258. if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
  1259. AC_CHECK_LIB(cap, cap_init,
  1260. [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
  1261. LIBCAP="-lcap"
  1262. quagga_ac_lcaps="yes"]
  1263. )
  1264. else
  1265. AC_CHECK_HEADERS(priv.h,
  1266. [AC_MSG_CHECKING(Solaris style privileges are available)
  1267. AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
  1268. [AC_MSG_RESULT(yes)
  1269. AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
  1270. quagga_ac_scaps="yes"],
  1271. AC_MSG_RESULT(no)
  1272. )
  1273. ]
  1274. )
  1275. fi
  1276. if test x"${quagga_ac_scaps}" = x"yes" \
  1277. -o x"${quagga_ac_lcaps}" = x"yes"; then
  1278. AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
  1279. fi
  1280. fi
  1281. AC_SUBST(LIBCAP)
  1282. dnl ---------------------------------------------------------------------------
  1283. dnl http://www.gnu.org/software/autoconf-archive/ax_sys_weak_alias.html
  1284. dnl Check for and set one of the following = 1
  1285. dnl HAVE_SYS_WEAK_ALIAS_ATTRIBUTE
  1286. dnl HAVE_SYS_WEAK_ALIAS_PRAGMA
  1287. dnl HAVE_SYS_WEAK_ALIAS_HPSECONDARY
  1288. dnl HAVE_SYS_WEAK_ALIAS_CRIDUPLICATE
  1289. dnl If any scheme is found, set
  1290. dnl HAVE_SYS_WEAK_ALIAS=1
  1291. dnl The following variable is set to text value
  1292. dnl WEAK_ALIAS = "attribute" || "pragma" || "hpsecondary" || "criduplicate" || "no"
  1293. dnl If weak alias can cross object file boundaries
  1294. dnl WEAK_ALIAS_CROSSFILE = "yes" || "no"
  1295. dnl ---------------------------------------------------------------------------
  1296. AX_SYS_WEAK_ALIAS
  1297. dnl ---------------------------
  1298. dnl check for glibc 'backtrace'
  1299. dnl ---------------------------
  1300. if test x"${enable_backtrace}" != x"no" ; then
  1301. backtrace_ok=no
  1302. AC_CHECK_HEADER([execinfo.h], [
  1303. AC_SEARCH_LIBS([backtrace], [execinfo], [
  1304. AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
  1305. AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
  1306. backtrace_ok=yes
  1307. ],, [-lm])
  1308. ])
  1309. if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
  1310. dnl user explicitly requested backtrace but we failed to find support
  1311. AC_MSG_FAILURE([failed to find backtrace support])
  1312. fi
  1313. fi
  1314. dnl -----------------------------------------
  1315. dnl check for malloc mallinfo struct and call
  1316. dnl this must try and link using LIBS, in
  1317. dnl order to check no alternative allocator
  1318. dnl has been specified, which might not provide
  1319. dnl mallinfo, e.g. such as Umem on Solaris.
  1320. dnl -----------------------------------------
  1321. AC_CHECK_HEADER([malloc.h],
  1322. [AC_MSG_CHECKING(whether mallinfo is available)
  1323. AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
  1324. [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
  1325. [AC_MSG_RESULT(yes)
  1326. AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
  1327. AC_MSG_RESULT(no)
  1328. )
  1329. ], [], QUAGGA_INCLUDES)
  1330. dnl ----------
  1331. dnl configure date
  1332. dnl ----------
  1333. CONFDATE=`date '+%Y%m%d'`
  1334. AC_SUBST(CONFDATE)
  1335. dnl -------
  1336. dnl DejaGNU
  1337. dnl -------
  1338. if test x"$DEJAGNU" = x
  1339. then
  1340. DEJAGNU="\$(top_srcdir)/tests/global-conf.exp"
  1341. fi
  1342. RUNTESTDEFAULTFLAGS="-x --tool \$\$tool"
  1343. AC_SUBST(DEJAGNU)
  1344. AC_SUBST(RUNTESTDEFAULTFLAGS)
  1345. dnl ------------------------------
  1346. dnl set paths for state directory
  1347. dnl ------------------------------
  1348. AC_MSG_CHECKING(directory to use for state file)
  1349. if test "${prefix}" = "NONE"; then
  1350. quagga_statedir_prefix="";
  1351. else
  1352. quagga_statedir_prefix=${prefix}
  1353. fi
  1354. if test "${localstatedir}" = '${prefix}/var'; then
  1355. for QUAGGA_STATE_DIR in ${quagga_statedir_prefix}/var/run dnl
  1356. ${quagga_statedir_prefix}/var/adm dnl
  1357. ${quagga_statedir_prefix}/etc dnl
  1358. /var/run dnl
  1359. /var/adm dnl
  1360. /etc dnl
  1361. /dev/null;
  1362. do
  1363. test -d $QUAGGA_STATE_DIR && break
  1364. done
  1365. quagga_statedir=$QUAGGA_STATE_DIR
  1366. else
  1367. quagga_statedir=${localstatedir}
  1368. fi
  1369. if test $quagga_statedir = "/dev/null"; then
  1370. AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
  1371. fi
  1372. AC_MSG_RESULT(${quagga_statedir})
  1373. AC_SUBST(quagga_statedir)
  1374. AC_DEFINE_UNQUOTED(PATH_ZEBRA_PID, "$quagga_statedir/zebra.pid",zebra PID)
  1375. AC_DEFINE_UNQUOTED(PATH_RIPD_PID, "$quagga_statedir/ripd.pid",ripd PID)
  1376. AC_DEFINE_UNQUOTED(PATH_RIPNGD_PID, "$quagga_statedir/ripngd.pid",ripngd PID)
  1377. AC_DEFINE_UNQUOTED(PATH_BGPD_PID, "$quagga_statedir/bgpd.pid",bgpd PID)
  1378. AC_DEFINE_UNQUOTED(PATH_OSPFD_PID, "$quagga_statedir/ospfd.pid",ospfd PID)
  1379. AC_DEFINE_UNQUOTED(PATH_OSPF6D_PID, "$quagga_statedir/ospf6d.pid",ospf6d PID)
  1380. AC_DEFINE_UNQUOTED(PATH_ISISD_PID, "$quagga_statedir/isisd.pid",isisd PID)
  1381. AC_DEFINE_UNQUOTED(PATH_PIMD_PID, "$quagga_statedir/pimd.pid",pimd PID)
  1382. AC_DEFINE_UNQUOTED(PATH_WATCHQUAGGA_PID, "$quagga_statedir/watchquagga.pid",watchquagga PID)
  1383. AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$quagga_statedir/zserv.api",zebra api socket)
  1384. AC_DEFINE_UNQUOTED(ZEBRA_VTYSH_PATH, "$quagga_statedir/zebra.vty",zebra vty socket)
  1385. AC_DEFINE_UNQUOTED(RIP_VTYSH_PATH, "$quagga_statedir/ripd.vty",rip vty socket)
  1386. AC_DEFINE_UNQUOTED(RIPNG_VTYSH_PATH, "$quagga_statedir/ripngd.vty",ripng vty socket)
  1387. AC_DEFINE_UNQUOTED(BGP_VTYSH_PATH, "$quagga_statedir/bgpd.vty",bgpd vty socket)
  1388. AC_DEFINE_UNQUOTED(OSPF_VTYSH_PATH, "$quagga_statedir/ospfd.vty",ospfd vty socket)
  1389. AC_DEFINE_UNQUOTED(OSPF6_VTYSH_PATH, "$quagga_statedir/ospf6d.vty",ospf6d vty socket)
  1390. AC_DEFINE_UNQUOTED(ISIS_VTYSH_PATH, "$quagga_statedir/isisd.vty",isisd vty socket)
  1391. AC_DEFINE_UNQUOTED(PIM_VTYSH_PATH, "$quagga_statedir/pimd.vty",pimd vty socket)
  1392. AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$quagga_statedir",daemon vty directory)
  1393. dnl -------------------------------
  1394. dnl Quagga sources should always be
  1395. dnl current wrt interfaces. Dont
  1396. dnl allow deprecated interfaces to
  1397. dnl be exposed.
  1398. dnl -------------------------------
  1399. AC_DEFINE(QUAGGA_NO_DEPRECATED_INTERFACES, 1, Hide deprecated interfaces)
  1400. dnl ---------------------------
  1401. dnl Check htonl works correctly
  1402. dnl ---------------------------
  1403. AC_MSG_CHECKING(for working htonl)
  1404. AC_CACHE_VAL(ac_cv_htonl_works,
  1405. [AC_LINK_IFELSE([AC_LANG_PROGRAM([QUAGGA_INCLUDES],[htonl (0);])],
  1406. [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
  1407. ]
  1408. )
  1409. AC_MSG_RESULT($ac_cv_htonl_works)
  1410. AC_CONFIG_FILES([Makefile lib/Makefile zebra/Makefile ripd/Makefile
  1411. ripngd/Makefile bgpd/Makefile ospfd/Makefile watchquagga/Makefile
  1412. ospf6d/Makefile isisd/Makefile vtysh/Makefile
  1413. doc/Makefile ospfclient/Makefile tests/Makefile m4/Makefile
  1414. pimd/Makefile
  1415. tests/bgpd.tests/Makefile
  1416. tests/libzebra.tests/Makefile
  1417. redhat/Makefile
  1418. pkgsrc/Makefile
  1419. redhat/quagga.spec
  1420. lib/version.h
  1421. doc/defines.texi
  1422. isisd/topology/Makefile
  1423. pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
  1424. pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh])
  1425. AC_CONFIG_FILES([solaris/Makefile])
  1426. AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
  1427. ## Hack, but working solution to avoid rebuilding of quagga.info.
  1428. ## It's already in CVS until texinfo 4.7 is more common.
  1429. AC_OUTPUT
  1430. echo "
  1431. Quagga configuration
  1432. --------------------
  1433. quagga version : ${PACKAGE_VERSION}
  1434. host operating system : ${host_os}
  1435. source code location : ${srcdir}
  1436. compiler : ${CC}
  1437. compiler flags : ${CFLAGS}
  1438. make : ${MAKE-make}
  1439. linker flags : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
  1440. state file directory : ${quagga_statedir}
  1441. config file directory : `eval echo \`echo ${sysconfdir}\``
  1442. example directory : `eval echo \`echo ${exampledir}\``
  1443. user to run as : ${enable_user}
  1444. group to run as : ${enable_group}
  1445. group for vty sockets : ${enable_vty_group}
  1446. config file mask : ${enable_configfile_mask}
  1447. log file mask : ${enable_logfile_mask}
  1448. The above user and group must have read/write access to the state file
  1449. directory and to the config files in the config file directory."
  1450. if test x"$quagga_cv_gnu_make" = x"no"; then echo "
  1451. Warning: The ${MAKE-make} programme detected, either in your path or
  1452. via the MAKE variable, is not GNU Make. GNU make may be installed as
  1453. gmake on some systems. and is required to complete a build of Quagga
  1454. " > /dev/stderr
  1455. fi