configure.ac 50 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677787980818283848586878889909192939495969798991001011021031041051061071081091101111121131141151161171181191201211221231241251261271281291301311321331341351361371381391401411421431441451461471481491501511521531541551561571581591601611621631641651661671681691701711721731741751761771781791801811821831841851861871881891901911921931941951961971981992002012022032042052062072082092102112122132142152162172182192202212222232242252262272282292302312322332342352362372382392402412422432442452462472482492502512522532542552562572582592602612622632642652662672682692702712722732742752762772782792802812822832842852862872882892902912922932942952962972982993003013023033043053063073083093103113123133143153163173183193203213223233243253263273283293303313323333343353363373383393403413423433443453463473483493503513523533543553563573583593603613623633643653663673683693703713723733743753763773783793803813823833843853863873883893903913923933943953963973983994004014024034044054064074084094104114124134144154164174184194204214224234244254264274284294304314324334344354364374384394404414424434444454464474484494504514524534544554564574584594604614624634644654664674684694704714724734744754764774784794804814824834844854864874884894904914924934944954964974984995005015025035045055065075085095105115125135145155165175185195205215225235245255265275285295305315325335345355365375385395405415425435445455465475485495505515525535545555565575585595605615625635645655665675685695705715725735745755765775785795805815825835845855865875885895905915925935945955965975985996006016026036046056066076086096106116126136146156166176186196206216226236246256266276286296306316326336346356366376386396406416426436446456466476486496506516526536546556566576586596606616626636646656666676686696706716726736746756766776786796806816826836846856866876886896906916926936946956966976986997007017027037047057067077087097107117127137147157167177187197207217227237247257267277287297307317327337347357367377387397407417427437447457467477487497507517527537547557567577587597607617627637647657667677687697707717727737747757767777787797807817827837847857867877887897907917927937947957967977987998008018028038048058068078088098108118128138148158168178188198208218228238248258268278288298308318328338348358368378388398408418428438448458468478488498508518528538548558568578588598608618628638648658668678688698708718728738748758768778788798808818828838848858868878888898908918928938948958968978988999009019029039049059069079089099109119129139149159169179189199209219229239249259269279289299309319329339349359369379389399409419429439449459469479489499509519529539549559569579589599609619629639649659669679689699709719729739749759769779789799809819829839849859869879889899909919929939949959969979989991000100110021003100410051006100710081009101010111012101310141015101610171018101910201021102210231024102510261027102810291030103110321033103410351036103710381039104010411042104310441045104610471048104910501051105210531054105510561057105810591060106110621063106410651066106710681069107010711072107310741075107610771078107910801081108210831084108510861087108810891090109110921093109410951096109710981099110011011102110311041105110611071108110911101111111211131114111511161117111811191120112111221123112411251126112711281129113011311132113311341135113611371138113911401141114211431144114511461147114811491150115111521153115411551156115711581159116011611162116311641165116611671168116911701171117211731174117511761177117811791180118111821183118411851186118711881189119011911192119311941195119611971198119912001201120212031204120512061207120812091210121112121213121412151216121712181219122012211222122312241225122612271228122912301231123212331234123512361237123812391240124112421243124412451246124712481249125012511252125312541255125612571258125912601261126212631264126512661267126812691270127112721273127412751276127712781279128012811282128312841285128612871288128912901291129212931294129512961297129812991300130113021303130413051306130713081309131013111312131313141315131613171318131913201321132213231324132513261327132813291330133113321333133413351336133713381339134013411342134313441345134613471348134913501351135213531354135513561357135813591360136113621363136413651366136713681369137013711372137313741375137613771378137913801381138213831384138513861387138813891390139113921393139413951396139713981399140014011402140314041405140614071408140914101411141214131414141514161417141814191420142114221423142414251426142714281429143014311432143314341435143614371438143914401441144214431444144514461447144814491450145114521453145414551456145714581459146014611462146314641465146614671468146914701471147214731474147514761477147814791480148114821483148414851486148714881489149014911492149314941495149614971498149915001501150215031504150515061507150815091510151115121513151415151516151715181519152015211522152315241525152615271528152915301531153215331534153515361537153815391540154115421543154415451546154715481549155015511552155315541555155615571558155915601561156215631564156515661567156815691570157115721573157415751576157715781579158015811582158315841585158615871588158915901591159215931594159515961597159815991600160116021603160416051606160716081609161016111612161316141615161616171618161916201621162216231624162516261627162816291630
  1. ##
  2. ## Configure template file for Quagga.
  3. ## autoconf will generate configure script.
  4. ##
  5. ## Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
  6. ## Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
  7. ##
  8. AC_PREREQ(2.60)
  9. AC_INIT(Quagga, 1.0.20160315, [https://bugzilla.quagga.net])
  10. CONFIG_ARGS="$*"
  11. AC_SUBST(CONFIG_ARGS)
  12. AC_CONFIG_SRCDIR(lib/zebra.h)
  13. AC_CONFIG_MACRO_DIR([m4])
  14. dnl -----------------------------------
  15. dnl Get hostname and other information.
  16. dnl -----------------------------------
  17. AC_CANONICAL_BUILD()
  18. AC_CANONICAL_HOST()
  19. AC_CANONICAL_TARGET()
  20. # Disable portability warnings -- our automake code (in particular
  21. # common.am) uses some constructs specific to gmake.
  22. AM_INIT_AUTOMAKE([1.6 -Wno-portability])
  23. m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  24. AM_SILENT_RULES([yes])
  25. AC_CONFIG_HEADERS(config.h)
  26. AC_PATH_PROG(PERL, perl)
  27. AC_CHECK_PROG([GAWK],[gawk],[gawk],[not-in-PATH])
  28. if test "x$GAWK" = "xnot-in-PATH" ; then
  29. AC_MSG_ERROR([GNU awk is required for lib/memtype.h made by memtypes.awk.
  30. BSD awk complains: awk: gensub doesn't support backreferences (subst "\1") ])
  31. fi
  32. AC_ARG_VAR([GAWK],[GNU AWK])
  33. dnl default is to match previous behavior
  34. exampledir=${sysconfdir}
  35. AC_ARG_ENABLE([exampledir],
  36. AS_HELP_STRING([--enable-exampledir],
  37. [specify alternate directory for examples]),
  38. exampledir="$enableval",)
  39. dnl XXX add --exampledir to autoconf standard directory list somehow
  40. AC_SUBST(exampledir)
  41. dnl default is to match previous behavior
  42. pkgsrcrcdir=""
  43. pkgsrcdir=""
  44. AC_ARG_ENABLE([pkgsrcrcdir],
  45. AS_HELP_STRING([--enable-pkgsrcrcdir],
  46. [specify directory for rc.d scripts]),
  47. pkgsrcrcdir="$enableval"; pkgsrcdir="pkgsrc",)
  48. dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  49. AC_SUBST(pkgsrcdir)
  50. AC_SUBST(pkgsrcrcdir)
  51. dnl ------------
  52. dnl Check CFLAGS
  53. dnl ------------
  54. AC_ARG_WITH(cflags,
  55. [ --with-cflags Set CFLAGS for use in compilation.])
  56. if test "x$with_cflags" != "x" ; then
  57. CFLAGS="$with_cflags" ; cflags_specified=yes ;
  58. elif test -n "$CFLAGS" ; then
  59. cflags_specified=yes ;
  60. fi
  61. dnl --------------------
  62. dnl Check CC and friends
  63. dnl --------------------
  64. AC_LANG([C])
  65. AC_PROG_CC
  66. AC_PROG_CPP
  67. AM_PROG_CC_C_O
  68. AC_PROG_RANLIB
  69. AC_PROG_EGREP
  70. dnl autoconf 2.59 appears not to support AC_PROG_SED
  71. dnl AC_PROG_SED
  72. AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
  73. dnl pdflatex and latexmk are needed to build HACKING.pdf
  74. AC_CHECK_PROG([PDFLATEX],[pdflatex],[pdflatex],[/bin/false])
  75. AC_CHECK_PROG([LATEXMK],[latexmk],[latexmk],[/bin/false])
  76. if test "x$PDFLATEX" = "x/bin/false" -o "x$LATEXMK" = "x/bin/false"; then
  77. AC_MSG_WARN([Will not be able to make PDF versions of TeX documents])
  78. else
  79. HAVE_LATEX=true
  80. fi
  81. AM_CONDITIONAL([HAVE_LATEX], [test "x$HAVE_LATEX" = "xtrue"])
  82. if test "x${GCC}" != "xyes" ; then
  83. AC_MSG_CHECKING([whether we are using SunPro compiler])
  84. AC_EGREP_CPP([^__SUNPRO_C.*0x5(7|8|9)], ["__SUNPRO_C" __SUNPRO_C],
  85. [AC_MSG_RESULT([no])],
  86. [COMPILER="SUNPRO"
  87. AC_MSG_RESULT([yes])]
  88. )
  89. fi
  90. dnl ---------------------------------------------
  91. dnl If CLFAGS doesn\'t exist set default value
  92. dnl AC_PROG_CC will have set minimal default
  93. dnl already, eg "-O2 -g" for gcc, "-g" for others
  94. dnl (Wall is gcc specific... have to make sure
  95. dnl gcc is being used before setting it)
  96. dnl
  97. dnl Sun Studio 10 / SunPro 5.7 is also supported,
  98. dnl so lets set some sane CFLAGS for it.
  99. dnl ---------------------------------------------
  100. AC_USE_SYSTEM_EXTENSIONS()
  101. AC_DEFUN([AC_C_FLAG], [{
  102. AC_LANG_PUSH(C)
  103. ac_c_flag_save="$CFLAGS"
  104. CFLAGS="$CFLAGS $1"
  105. AC_MSG_CHECKING([[whether $CC supports $1]])
  106. AC_COMPILE_IFELSE(
  107. [AC_LANG_PROGRAM([[]])],
  108. [
  109. AC_MSG_RESULT([yes])
  110. m4_if([$3], [], [], [
  111. CFLAGS="$ac_c_flag_save"
  112. $3
  113. ])
  114. ], [
  115. CFLAGS="$ac_c_flag_save"
  116. AC_MSG_RESULT([no])
  117. $2
  118. ])
  119. AC_LANG_POP(C)
  120. }])
  121. AC_MSG_CHECKING([whether to set a default CFLAGS])
  122. if test "x${cflags_specified}" = "x" ; then
  123. case ${COMPILER} in
  124. "SUNPRO")
  125. CFLAGS="-xO4 -v -g -xspace -xcode=pic32 -xstrconst -xc99"
  126. AC_MSG_RESULT([SunPro default])
  127. ;;
  128. *)
  129. AC_MSG_RESULT([autodetecting])
  130. AC_C_FLAG([-diag-error 10006])
  131. AC_C_FLAG([-std=gnu99])
  132. AC_C_FLAG([-g])
  133. AC_C_FLAG([-Os], [
  134. AC_C_FLAG([-O2])
  135. ])
  136. AC_C_FLAG([-fpie])
  137. AC_C_FLAG([-fno-omit-frame-pointer])
  138. AC_C_FLAG([-Wall])
  139. AC_C_FLAG([-Wextra])
  140. AC_C_FLAG([-Wmissing-prototypes])
  141. AC_C_FLAG([-Wmissing-declarations])
  142. AC_C_FLAG([-Wpointer-arith])
  143. AC_C_FLAG([-Wbad-function-cast])
  144. AC_C_FLAG([-Wwrite-strings])
  145. if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
  146. AC_C_FLAG([-Wcast-qual])
  147. AC_C_FLAG([-Wstrict-prototypes])
  148. AC_C_FLAG([-Wmissing-noreturn])
  149. AC_C_FLAG([-Wmissing-format-attribute])
  150. AC_C_FLAG([-Wunreachable-code])
  151. AC_C_FLAG([-Wpacked])
  152. AC_C_FLAG([-Wpadded])
  153. else
  154. AC_C_FLAG([-Wno-unused-result])
  155. fi
  156. AC_C_FLAG([-Wno-unused-parameter])
  157. AC_C_FLAG([-Wno-missing-field-initializers])
  158. # ICC emits a broken warning for const char *x = a ? "b" : "c";
  159. # for some reason the string consts get 'promoted' to char *,
  160. # triggering a const to non-const conversion warning.
  161. AC_C_FLAG([-diag-disable 3179])
  162. ;;
  163. esac
  164. else
  165. AC_MSG_RESULT([CFLAGS supplied by user])
  166. fi
  167. if test x"${enable_werror}" = x"yes" ; then
  168. WERROR="-Werror"
  169. fi
  170. AC_SUBST(WERROR)
  171. dnl --------------
  172. dnl Check programs
  173. dnl --------------
  174. AC_PROG_INSTALL
  175. AC_PROG_LN_S
  176. AC_PROG_MAKE_SET
  177. AC_CHECK_TOOL(AR, ar)
  178. dnl ---------------------------
  179. dnl We, perhaps unfortunately,
  180. dnl depend on GNU Make specific
  181. dnl constructs.
  182. dnl Give the user a warning if
  183. dnl not GNU Make.
  184. dnl ---------------------------
  185. AC_CACHE_CHECK([if ${MAKE-make} is GNU make], [quagga_cv_gnu_make],
  186. [quagga_cv_gnu_make=no
  187. if ${MAKE-make} --version 2>/dev/null | \
  188. grep '^GNU Make ' >/dev/null ; then
  189. quagga_cv_gnu_make=yes;
  190. fi
  191. ]
  192. )
  193. dnl -----------------
  194. dnl System extensions
  195. dnl -----------------
  196. AC_GNU_SOURCE
  197. dnl -------
  198. dnl libtool
  199. dnl -------
  200. LT_INIT
  201. dnl ----------------------
  202. dnl Packages configuration
  203. dnl ----------------------
  204. AC_ARG_WITH(pkg-extra-version,
  205. AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
  206. [EXTRAVERSION=$withval],)
  207. AC_ARG_WITH(pkg-git-version,
  208. AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
  209. [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
  210. AC_ARG_ENABLE(vtysh,
  211. AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for Quagga]))
  212. AC_ARG_ENABLE(doc,
  213. AS_HELP_STRING([--disable-doc], [do not build docs]))
  214. AC_ARG_ENABLE(zebra,
  215. AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
  216. AC_ARG_ENABLE(bgpd,
  217. AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
  218. AC_ARG_ENABLE(ripd,
  219. AS_HELP_STRING([--disable-ripd], [do not build ripd]))
  220. AC_ARG_ENABLE(ripngd,
  221. AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
  222. AC_ARG_ENABLE(ospfd,
  223. AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
  224. AC_ARG_ENABLE(ospf6d,
  225. AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
  226. AC_ARG_ENABLE(watchquagga,
  227. AS_HELP_STRING([--disable-watchquagga], [do not build watchquagga]))
  228. AC_ARG_ENABLE(isisd,
  229. AS_HELP_STRING([--disable-isisd], [do not build isisd]))
  230. AC_ARG_ENABLE(pimd,
  231. AS_HELP_STRING([--disable-pimd], [do not build pimd]))
  232. AC_ARG_ENABLE(bgp-announce,
  233. AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
  234. AC_ARG_ENABLE(snmp,
  235. AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
  236. AC_ARG_WITH(libpam,
  237. AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
  238. AC_ARG_ENABLE(tcp-zebra,
  239. AS_HELP_STRING([--enable-tcp-zebra], [enable TCP/IP socket connection between zebra and protocol daemon]))
  240. AC_ARG_ENABLE(ospfapi,
  241. AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
  242. AC_ARG_ENABLE(ospfclient,
  243. AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
  244. (this is the default if --disable-ospfapi is set)]))
  245. AC_ARG_ENABLE(multipath,
  246. AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
  247. AC_ARG_ENABLE(user,
  248. AS_HELP_STRING([--enable-user=USER], [user to run Quagga suite as (default quagga)]))
  249. AC_ARG_ENABLE(group,
  250. AS_HELP_STRING([--enable-group=GROUP], [group to run Quagga suite as (default quagga)]))
  251. AC_ARG_ENABLE(vty_group,
  252. AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
  253. AC_ARG_ENABLE(configfile_mask,
  254. AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
  255. AC_ARG_ENABLE(logfile_mask,
  256. AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
  257. AC_ARG_ENABLE(rtadv,
  258. AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
  259. AC_ARG_ENABLE(irdp,
  260. AS_HELP_STRING([--enable-irdp], [enable IRDP server support in zebra]))
  261. AC_ARG_ENABLE(isis_topology,
  262. AS_HELP_STRING([--enable-isis-topology], [enable IS-IS topology generator]))
  263. AC_ARG_ENABLE(capabilities,
  264. AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
  265. AC_ARG_ENABLE(rusage,
  266. AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
  267. AC_ARG_ENABLE(gcc_ultra_verbose,
  268. AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
  269. AC_ARG_ENABLE(linux24_tcp_md5,
  270. AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
  271. AC_ARG_ENABLE(gcc-rdynamic,
  272. AS_HELP_STRING([--enable-gcc-rdynamic], [enable linking with -rdynamic for better backtraces (default if gcc)]))
  273. AC_ARG_ENABLE(backtrace,
  274. AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
  275. AC_ARG_ENABLE(time-check,
  276. AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
  277. AC_ARG_ENABLE(pcreposix,
  278. AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
  279. AC_ARG_ENABLE(fpm,
  280. AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
  281. AC_ARG_ENABLE(werror,
  282. AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
  283. AC_ARG_ENABLE([protobuf],
  284. AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
  285. if test x"${enable_gcc_rdynamic}" != x"no" ; then
  286. if test x"${enable_gcc_rdynamic}" = x"yes" -o x"$COMPILER" = x"GCC"; then
  287. LDFLAGS="${LDFLAGS} -rdynamic"
  288. fi
  289. fi
  290. if test x"${enable_time_check}" != x"no" ; then
  291. if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
  292. AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
  293. else
  294. AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
  295. fi
  296. fi
  297. if test "${enable_fpm}" = "yes"; then
  298. AC_DEFINE(HAVE_FPM,,Forwarding Plane Manager support)
  299. fi
  300. #
  301. # Logic for protobuf support.
  302. #
  303. if test "$enable_protobuf" = "yes"; then
  304. have_protobuf=yes
  305. # Check for protoc-c
  306. AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
  307. if test "x$PROTOC_C" = "x/bin/false"; then
  308. have_protobuf=no
  309. else
  310. found_protobuf_c=no
  311. PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
  312. [found_protobuf_c=yes],
  313. [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
  314. if test "x$found_protobuf_c" = "xyes"; then
  315. LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
  316. CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
  317. else
  318. AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
  319. [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
  320. fi
  321. fi
  322. fi
  323. # Fail if the user explicity enabled protobuf support and we couldn't
  324. # find the compiler or libraries.
  325. if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
  326. AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
  327. fi
  328. if test "x$have_protobuf" = "xyes"; then
  329. AC_DEFINE(HAVE_PROTOBUF,, protobuf)
  330. fi
  331. AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
  332. #
  333. # End of logic for protobuf support.
  334. #
  335. if test "${enable_tcp_zebra}" = "yes"; then
  336. AC_DEFINE(HAVE_TCP_ZEBRA,,Use TCP for zebra communication)
  337. fi
  338. if test "${enable_linux24_tcp_md5}" = "yes"; then
  339. AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
  340. fi
  341. AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
  342. if test "${enable_rtadv}" != "no"; then
  343. AC_MSG_RESULT(yes)
  344. AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
  345. else
  346. AC_MSG_RESULT(no)
  347. fi
  348. if test "${enable_irdp}" = "yes"; then
  349. AC_DEFINE(HAVE_IRDP,, IRDP )
  350. fi
  351. if test "${enable_isisd}" != "no" && test "${enable_isis_topology}" = yes; then
  352. AC_DEFINE(TOPOLOGY_GENERATE,,Enable IS-IS topology generator code)
  353. ISIS_TOPOLOGY_INCLUDES="-I\$(srcdir)/topology"
  354. ISIS_TOPOLOGY_DIR="topology"
  355. ISIS_TOPOLOGY_LIB="./topology/libtopology.a"
  356. fi
  357. AC_SUBST(ISIS_TOPOLOGY_INCLUDES)
  358. AC_SUBST(ISIS_TOPOLOGY_DIR)
  359. AC_SUBST(ISIS_TOPOLOGY_LIB)
  360. if test "${enable_user}" = "yes" || test x"${enable_user}" = x""; then
  361. enable_user="quagga"
  362. elif test "${enable_user}" = "no"; then
  363. enable_user="root"
  364. fi
  365. if test "${enable_group}" = "yes" || test x"${enable_group}" = x""; then
  366. enable_group="quagga"
  367. elif test "${enable_group}" = "no"; then
  368. enable_group="root"
  369. fi
  370. if test x"${enable_vty_group}" = x"yes" ; then
  371. AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
  372. elif test x"${enable_vty_group}" != x""; then
  373. if test x"${enable_vty_group}" != x"no"; then
  374. AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
  375. fi
  376. fi
  377. AC_SUBST([enable_user])
  378. AC_SUBST([enable_group])
  379. AC_SUBST([enable_vty_group])
  380. AC_DEFINE_UNQUOTED(QUAGGA_USER, "${enable_user}", Quagga User)
  381. AC_DEFINE_UNQUOTED(QUAGGA_GROUP, "${enable_group}", Quagga Group)
  382. enable_configfile_mask=${enable_configfile_mask:-0600}
  383. AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
  384. enable_logfile_mask=${enable_logfile_mask:-0600}
  385. AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
  386. MPATH_NUM=1
  387. case "${enable_multipath}" in
  388. 0)
  389. MPATH_NUM=64
  390. ;;
  391. [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
  392. MPATH_NUM="${enable_multipath}"
  393. ;;
  394. "")
  395. ;;
  396. *)
  397. AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
  398. ;;
  399. esac
  400. AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
  401. dnl -----------------------------------
  402. dnl Add extra version string to package
  403. dnl name, string and version fields.
  404. dnl -----------------------------------
  405. if test "x${EXTRAVERSION}" != "x" ; then
  406. VERSION="${VERSION}${EXTRAVERSION}"
  407. PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
  408. PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
  409. fi
  410. if test "x$with_pkg_git_version" = "xyes"; then
  411. if test -d "${srcdir}/.git"; then
  412. AC_DEFINE(GIT_VERSION, [1], [include git version info])
  413. else with_pkg_git_version="no"
  414. AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
  415. fi
  416. fi
  417. AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
  418. dnl ------------------------------------
  419. dnl Check C keywords and standard types
  420. dnl ------------------------------------
  421. AC_C_CONST
  422. AC_C_INLINE
  423. AC_C_RESTRICT
  424. AC_C_VOLATILE
  425. AC_HEADER_STDC
  426. AC_HEADER_TIME
  427. AC_HEADER_SYS_WAIT
  428. AC_HEADER_STDBOOL
  429. dnl AC_TYPE_PID_T
  430. AC_TYPE_UID_T
  431. AC_TYPE_MODE_T
  432. AC_TYPE_SIZE_T
  433. AC_STRUCT_TM
  434. dnl -------------------------
  435. dnl Check other header files.
  436. dnl -------------------------
  437. AC_CHECK_HEADERS([stropts.h sys/ksym.h sys/times.h sys/select.h \
  438. sys/types.h linux/version.h netdb.h asm/types.h \
  439. sys/cdefs.h sys/param.h limits.h signal.h \
  440. sys/socket.h netinet/in.h time.h sys/time.h features.h])
  441. dnl Utility macro to avoid retyping includes all the time
  442. m4_define([QUAGGA_INCLUDES],
  443. [#ifdef SUNOS_5
  444. #define _XPG4_2
  445. #define __EXTENSIONS__
  446. #endif
  447. #include <stdio.h>
  448. #if STDC_HEADERS
  449. # include <stdlib.h>
  450. # include <stddef.h>
  451. #else
  452. # if HAVE_STDLIB_H
  453. # include <stdlib.h>
  454. # endif
  455. #endif
  456. #if HAVE_SYS_TYPES_H
  457. # include <sys/types.h>
  458. #endif
  459. /* sys/conf.h depends on param.h on FBSD at least */
  460. #if HAVE_SYS_PARAM_H
  461. # include <sys/param.h>
  462. #endif
  463. /* Required for MAXSIG */
  464. #if HAVE_SIGNAL_H
  465. # include <signal.h>
  466. #endif
  467. #if HAVE_SYS_SOCKET_H
  468. # include <sys/socket.h>
  469. #endif
  470. #ifdef __APPLE__
  471. # define __APPLE_USE_RFC_3542
  472. #endif
  473. #if HAVE_NETINET_IN_H
  474. # include <netinet/in.h>
  475. #endif
  476. #ifdef TIME_WITH_SYS_TIME
  477. # include <sys/time.h>
  478. # include <time.h>
  479. #else
  480. # ifdef HAVE_SYS_TIME_H
  481. # include <sys/time.h>
  482. # else
  483. # include <time.h>
  484. # endif
  485. #endif /* TIME_WITH_SYS_TIME */
  486. ])dnl
  487. dnl HAVE_NET_IF_H must be discovered by the time the longer AC_CHECK_HEADERS
  488. dnl round below execution begins, otherwise it doesn't properly detect
  489. dnl HAVE_NETINET6_IN6_VAR_H, HAVE_NET_IF_VAR_H and HAVE_STRUCT_IN6_ALIASREQ
  490. dnl on FreeBSD (BZ#408).
  491. AC_CHECK_HEADERS([net/if.h], [], [], QUAGGA_INCLUDES)
  492. m4_define([QUAGGA_INCLUDES],
  493. QUAGGA_INCLUDES
  494. [#if HAVE_NET_IF_H
  495. # include <net/if.h>
  496. #endif
  497. ])dnl
  498. dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
  499. dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
  500. dnl an additional round for it.
  501. AC_CHECK_HEADERS([net/if_var.h], [], [], QUAGGA_INCLUDES)
  502. m4_define([QUAGGA_INCLUDES],
  503. QUAGGA_INCLUDES
  504. [#if HAVE_NET_IF_VAR_H
  505. # include <net/if_var.h>
  506. #endif
  507. ])dnl
  508. AC_CHECK_HEADERS([sys/un.h netinet/in_systm.h netinet/in_var.h \
  509. net/if_dl.h net/netopt.h net/route.h \
  510. inet/nd.h arpa/inet.h netinet/ip_icmp.h \
  511. fcntl.h stddef.h sys/ioctl.h syslog.h wchar.h wctype.h \
  512. sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
  513. [], [], QUAGGA_INCLUDES)
  514. AC_CHECK_HEADERS([ucontext.h], [], [],
  515. [#ifndef __USE_GNU
  516. #define __USE_GNU
  517. #endif /* __USE_GNU */
  518. QUAGGA_INCLUDES
  519. ])
  520. m4_define([UCONTEXT_INCLUDES],
  521. [#include <ucontext.h>])dnl
  522. AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
  523. [], [], [UCONTEXT_INCLUDES])
  524. AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
  525. [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
  526. [], [], [UCONTEXT_INCLUDES])],
  527. [], [UCONTEXT_INCLUDES])
  528. AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
  529. [], [], [UCONTEXT_INCLUDES])
  530. m4_define([QUAGGA_INCLUDES],
  531. QUAGGA_INCLUDES
  532. [#if HAVE_SYS_UN_H
  533. # include <sys/un.h>
  534. #endif
  535. #if HAVE_NETINET_IN_SYSTM_H
  536. # include <netinet/in_systm.h>
  537. #endif
  538. #if HAVE_NETINET_IN_VAR_H
  539. # include <netinet/in_var.h>
  540. #endif
  541. #if HAVE_NET_IF_DL_H
  542. # include <net/if_dl.h>
  543. #endif
  544. #if HAVE_NET_NETOPT_H
  545. # include <net/netopt.h>
  546. #endif
  547. #if HAVE_NET_ROUTE_H
  548. # include <net/route.h>
  549. #endif
  550. #if HAVE_INET_ND_H
  551. # include <inet/nd.h>
  552. #endif
  553. #if HAVE_ARPA_INET_H
  554. # include <arpa/inet.h>
  555. #endif
  556. /* Required for IDRP */
  557. #if HAVE_NETINET_IP_ICMP_H
  558. # include <netinet/ip_icmp.h>
  559. #endif
  560. ])dnl
  561. dnl V6 headers are checked below, after we check for v6
  562. dnl Some systems (Solaris 2.x) require libnsl (Network Services Library)
  563. case "$host" in
  564. [*-sunos5.[6-7]*] | [*-solaris2.[6-7]*])
  565. opsys=sol2-6
  566. AC_DEFINE(SUNOS_56, 1, SunOS 5.6 to 5.7)
  567. AC_DEFINE(SUNOS_5, 1, SunOS 5)
  568. AC_CHECK_LIB(xnet, main)
  569. CURSES=-lcurses
  570. SOLARIS="solaris"
  571. ;;
  572. [*-sunos5.[8-9]] \
  573. | [*-sunos5.1[0-9]] \
  574. | [*-sunos5.1[0-9].[0-9]] \
  575. | [*-solaris2.[8-9]] \
  576. | [*-solaris2.1[0-9]] \
  577. | [*-solaris2.1[0-9].[0-9]])
  578. opsys=sol8
  579. AC_DEFINE(SUNOS_59, 1, [SunOS 5.8 up])
  580. AC_DEFINE(SUNOS_5, 1, [SunOS 5])
  581. AC_CHECK_LIB(socket, main)
  582. AC_CHECK_LIB(nsl, main)
  583. AC_CHECK_LIB(umem, main)
  584. AC_CHECK_FUNCS([printstack],
  585. [AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
  586. AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
  587. ])
  588. CURSES=-lcurses
  589. SOLARIS="solaris"
  590. ;;
  591. *-sunos5* | *-solaris2*)
  592. AC_DEFINE(SUNOS_5,,SunOS 5, Unknown SunOS)
  593. AC_CHECK_LIB(socket, main)
  594. AC_CHECK_LIB(nsl, main)
  595. CURSES=-lcurses
  596. SOLARIS="solaris"
  597. ;;
  598. *-linux*)
  599. opsys=gnu-linux
  600. AC_DEFINE(GNU_LINUX,,GNU Linux)
  601. ;;
  602. *-openbsd*)
  603. opsys=openbsd
  604. AC_DEFINE(OPEN_BSD,,OpenBSD)
  605. ;;
  606. esac
  607. AC_SYS_LARGEFILE
  608. dnl ---------------------
  609. dnl Integrated VTY option
  610. dnl ---------------------
  611. case "${enable_vtysh}" in
  612. "no") VTYSH="";;
  613. *) VTYSH="vtysh";
  614. AC_DEFINE(VTYSH,,VTY shell)
  615. dnl Vtysh uses libreadline, which looks for termcap functions at
  616. dnl configure time. We follow readlines search order.
  617. dnl The required procedures are in libtermcap on NetBSD, in
  618. dnl [TODO] on Linux, and in [TODO] on Solaris.
  619. AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
  620. [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
  621. [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
  622. [AC_CHECK_LIB(ncurses, tputs,
  623. LIBREADLINE="$LIBREADLINE -lncurses")]
  624. )]
  625. )]
  626. )
  627. AC_CHECK_LIB(readline, main, LIBREADLINE="$LIBREADLINE -lreadline",,
  628. "$LIBREADLINE")
  629. if test $ac_cv_lib_readline_main = no; then
  630. AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
  631. fi
  632. AC_CHECK_HEADER(readline/history.h)
  633. if test $ac_cv_header_readline_history_h = no;then
  634. AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
  635. fi
  636. AC_CHECK_LIB(readline, rl_completion_matches,
  637. LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
  638. if test $ac_cv_lib_readline_rl_completion_matches = no; then
  639. AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
  640. fi
  641. ;;
  642. "no" ) VTYSH="";;
  643. esac
  644. AC_SUBST(LIBREADLINE)
  645. AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
  646. dnl ----------
  647. dnl PAM module
  648. dnl
  649. dnl Quagga detects the PAM library it is built against by checking for a
  650. dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
  651. dnl is known to #include pam_appl.h, the standard header of a PAM library, and
  652. dnl openpam.h doesn't do that, although depends on the header too. Hence a
  653. dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
  654. dnl of OpenPAM.
  655. dnl ----------
  656. if test "$with_libpam" = "yes"; then
  657. AC_CHECK_HEADER([security/pam_misc.h],
  658. [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
  659. AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
  660. pam_conv_func="misc_conv"
  661. ],
  662. [], QUAGGA_INCLUDES)
  663. AC_CHECK_HEADER([security/openpam.h],
  664. [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
  665. AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
  666. pam_conv_func="openpam_ttyconv"
  667. ],
  668. [], QUAGGA_INCLUDES[#include <security/pam_appl.h>])
  669. if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
  670. AC_MSG_WARN([*** pam support will not be built ***])
  671. with_libpam="no"
  672. fi
  673. fi
  674. if test "$with_libpam" = "yes"; then
  675. dnl took this test from proftpds configure.in and suited to our needs
  676. dnl -------------------------------------------------------------------------
  677. dnl
  678. dnl This next check looks funky due to a linker problem with some versions
  679. dnl of the PAM library. Prior to 0.72 release, the Linux PAM shared library
  680. dnl omitted requiring libdl linking information. PAM-0.72 or better ships
  681. dnl with RedHat 6.2 and Debian 2.2 or better.
  682. AC_CHECK_LIB(pam, pam_start,
  683. [AC_CHECK_LIB(pam, $pam_conv_func,
  684. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  685. LIBPAM="-lpam"],
  686. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  687. LIBPAM="-lpam -lpam_misc"]
  688. )
  689. ],
  690. [AC_CHECK_LIB(pam, pam_end,
  691. [AC_CHECK_LIB(pam, $pam_conv_func,
  692. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  693. LIBPAM="-lpam -ldl"],
  694. [AC_DEFINE(USE_PAM,,Use PAM for authentication)
  695. LIBPAM="-lpam -ldl -lpam_misc"]
  696. )
  697. ],AC_MSG_WARN([*** pam support will not be built ***]),
  698. [-ldl])
  699. ]
  700. )
  701. fi
  702. AC_SUBST(LIBPAM)
  703. dnl -------------------------------
  704. dnl Endian-ness check
  705. dnl -------------------------------
  706. AC_WORDS_BIGENDIAN
  707. dnl -------------------------------
  708. dnl check the size in byte of the C
  709. dnl -------------------------------
  710. dnl AC_CHECK_SIZEOF(char)
  711. dnl AC_CHECK_SIZEOF(int)
  712. dnl AC_CHECK_SIZEOF(short)
  713. dnl AC_CHECK_SIZEOF(long)
  714. dnl ----------------------------
  715. dnl check existance of functions
  716. dnl ----------------------------
  717. AC_FUNC_CHOWN
  718. AC_FUNC_FNMATCH
  719. AC_FUNC_FORK
  720. AC_FUNC_MEMCMP
  721. AC_FUNC_MKTIME
  722. AC_FUNC_STRFTIME
  723. AC_FUNC_STAT
  724. AC_FUNC_SELECT_ARGTYPES
  725. AC_FUNC_STRFTIME
  726. dnl Avoid AC_FUNC_STRNLEN because it pulls in AC_SYSTEM_EXTENSIONS which
  727. dnl can lead to strange side effects. So we just check for strnlen
  728. dnl directly, see below.
  729. dnl AC_FUNC_STRNLENdnl
  730. AC_FUNC_VPRINTF
  731. dnl -------------------------------
  732. dnl bgpd needs pow() and hence libm
  733. dnl -------------------------------
  734. TMPLIBS="$LIBS"
  735. AC_CHECK_HEADER([math.h],
  736. [AC_CHECK_LIB([m], [pow],
  737. [LIBM="-lm"
  738. LIBS="$LIBS $LIBM"
  739. AC_DEFINE(HAVE_LIBM,, Have libm)
  740. AC_CHECK_FUNCS(pow,[],[LIBM=""])
  741. ])
  742. ])
  743. if test x"$LIBM" = x ; then
  744. AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
  745. fi
  746. LIBS="$TMPLIBS"
  747. AC_SUBST(LIBM)
  748. dnl ---------------
  749. dnl other functions
  750. dnl ---------------
  751. AC_CHECK_FUNCS([dup2 ftruncate getcwd gethostbyname getpagesize gettimeofday \
  752. inet_ntoa inet_aton strnlen \
  753. memchr memmove memset select socket \
  754. strcasecmp strchr strcspn strdup strerror \
  755. strncasecmp strndup strrchr strspn strstr \
  756. strtol strtoul strlcat strlcpy \
  757. daemon snprintf vsnprintf \
  758. if_nametoindex if_indextoname getifaddrs \
  759. uname fcntl getgrouplist])
  760. AC_CHECK_HEADER([asm-generic/unistd.h],
  761. [AC_CHECK_DECL(__NR_setns,
  762. AC_DEFINE(HAVE_NETNS,, Have netns),,
  763. QUAGGA_INCLUDES [#include <asm-generic/unistd.h>
  764. ])
  765. AC_CHECK_FUNCS(setns, AC_DEFINE(HAVE_SETNS,, Have setns))]
  766. )
  767. dnl ------------------------------------
  768. dnl Determine routing get and set method
  769. dnl ------------------------------------
  770. AC_MSG_CHECKING(zebra between kernel interface method)
  771. if test x"$opsys" = x"gnu-linux"; then
  772. AC_MSG_RESULT(netlink)
  773. RT_METHOD=rt_netlink.o
  774. AC_DEFINE(HAVE_NETLINK,,netlink)
  775. netlink=yes
  776. else
  777. AC_MSG_RESULT(Route socket)
  778. KERNEL_METHOD="kernel_socket.o"
  779. RT_METHOD="rt_socket.o"
  780. fi
  781. AC_SUBST(RT_METHOD)
  782. AC_SUBST(KERNEL_METHOD)
  783. AM_CONDITIONAL([HAVE_NETLINK], [test "x$netlink" = "xyes"])
  784. dnl --------------------------
  785. dnl Determine IS-IS I/O method
  786. dnl --------------------------
  787. AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
  788. AC_DEFINE(ISIS_METHOD_DLPI, 2, [ constant value for isis method dlpi ])
  789. AC_DEFINE(ISIS_METHOD_BPF, 3, [ constant value for isis method bpf ])
  790. AC_CHECK_HEADER(net/bpf.h)
  791. AC_CHECK_HEADER(sys/dlpi.h)
  792. AC_MSG_CHECKING(zebra IS-IS I/O method)
  793. if test x"$opsys" = x"gnu-linux"; then
  794. AC_MSG_RESULT(pfpacket)
  795. ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
  796. elif test x"$opsys" = x"sol2-6" -o x"$opsys" = x"sol8"; then
  797. AC_MSG_RESULT(DLPI)
  798. ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
  799. else
  800. if test $ac_cv_header_net_bpf_h = no; then
  801. if test $ac_cv_header_sys_dlpi_h = no; then
  802. AC_MSG_RESULT(none)
  803. AC_MSG_WARN([*** IS-IS support will not be built ***])
  804. ISISD=""
  805. else
  806. AC_MSG_RESULT(DLPI)
  807. fi
  808. ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
  809. else
  810. AC_MSG_RESULT(BPF)
  811. ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
  812. fi
  813. fi
  814. AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
  815. dnl ------------------------------------
  816. dnl check for broken CMSG_FIRSTHDR macro
  817. dnl ------------------------------------
  818. AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
  819. AC_RUN_IFELSE([AC_LANG_SOURCE([[
  820. #ifdef SUNOS_5
  821. #define _XPG4_2
  822. #define __EXTENSIONS__
  823. #endif
  824. #ifdef HAVE_STDLIB_H
  825. # include <stdlib.h>
  826. #endif
  827. #ifdef HAVE_SYS_TYPES_H
  828. #include <sys/types.h>
  829. #endif
  830. #ifdef HAVE_SYS_SOCKET_H
  831. #include <sys/socket.h>
  832. #endif
  833. main()
  834. {
  835. struct msghdr msg;
  836. char buf[4];
  837. msg.msg_control = buf;
  838. msg.msg_controllen = 0;
  839. if (CMSG_FIRSTHDR(&msg) != NULL)
  840. exit(0);
  841. exit (1);
  842. }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
  843. [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
  844. dnl ------------------------------
  845. dnl check kernel route read method
  846. dnl ------------------------------
  847. AC_CACHE_CHECK([route read method], [quagga_cv_rtread_method],
  848. [if test "x$netlink" = xyes; then
  849. quagga_cv_rtread_method="netlink"
  850. else
  851. for quagga_cv_rtread_method in /dev/ip /dev/null;
  852. do
  853. test x`ls $quagga_cv_rtread_method 2>/dev/null` = x"$quagga_cv_rtread_method" && break
  854. done
  855. case $quagga_cv_rtread_method in
  856. "/dev/ip")
  857. case "$host" in
  858. *-freebsd*) quagga_cv_rtread_method="sysctl";;
  859. *) quagga_cv_rtread_method="getmsg";;
  860. esac;;
  861. *)
  862. quagga_cv_rtread_method="sysctl";;
  863. esac
  864. fi])
  865. RTREAD_METHOD=rtread_${quagga_cv_rtread_method}.o
  866. AC_SUBST(RTREAD_METHOD)
  867. dnl -----------------------------
  868. dnl check interface lookup method
  869. dnl -----------------------------
  870. IOCTL_METHOD=ioctl.o
  871. AC_MSG_CHECKING(interface looking up method)
  872. if test "$netlink" = yes; then
  873. AC_MSG_RESULT(netlink)
  874. IF_METHOD=if_netlink.o
  875. elif test "$opsys" = "sol2-6";then
  876. AC_MSG_RESULT(Solaris GIF)
  877. IF_METHOD=if_ioctl.o
  878. elif test "$opsys" = "sol8";then
  879. AC_MSG_RESULT(Solaris GLIF)
  880. IF_METHOD=if_ioctl_solaris.o
  881. IOCTL_METHOD=ioctl_solaris.o
  882. elif test "$opsys" = "openbsd";then
  883. AC_MSG_RESULT(openbsd)
  884. IF_METHOD=if_ioctl.o
  885. elif grep NET_RT_IFLIST /usr/include/sys/socket.h >/dev/null 2>&1; then
  886. AC_MSG_RESULT(sysctl)
  887. IF_METHOD=if_sysctl.o
  888. AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
  889. else
  890. AC_MSG_RESULT(ioctl)
  891. IF_METHOD=if_ioctl.o
  892. fi
  893. AC_SUBST(IF_METHOD)
  894. AC_SUBST(IOCTL_METHOD)
  895. dnl ---------------------------------------------------------------
  896. dnl figure out how to specify an interface in multicast sockets API
  897. dnl ---------------------------------------------------------------
  898. AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], QUAGGA_INCLUDES)
  899. AC_CHECK_HEADERS([linux/mroute.h], [], [],
  900. [
  901. #if HAVE_NETINET_IN_H
  902. #include<netinet/in.h>
  903. #endif])
  904. AC_MSG_CHECKING([for BSD struct ip_mreq hack])
  905. AC_TRY_COMPILE([#ifdef HAVE_SYS_PARAM_H
  906. #include <sys/param.h>
  907. #endif],[#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
  908. return (0);
  909. #else
  910. #error No support for BSD struct ip_mreq hack detected
  911. #endif],[AC_MSG_RESULT(yes)
  912. AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
  913. AC_MSG_RESULT(no))
  914. AC_MSG_CHECKING([for RFC3678 protocol-independed API])
  915. AC_TRY_COMPILE([
  916. #include <sys/types.h>
  917. #include <netinet/in.h>
  918. ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
  919. ], [AC_MSG_RESULT(yes)
  920. AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
  921. AC_MSG_RESULT(no))
  922. dnl ---------------------------------------------------------------
  923. dnl figure out how to check link-state
  924. dnl ---------------------------------------------------------------
  925. AC_CHECK_HEADER([net/if.h],
  926. [AC_CHECK_HEADER( [net/if_media.h],
  927. [m4_define([LINK_DETECT_INCLUDES],
  928. QUAGGA_INCLUDES
  929. [#include <net/if_media.h>
  930. ])
  931. AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
  932. AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
  933. [], LINK_DETECT_INCLUDES)],
  934. [],
  935. QUAGGA_INCLUDES)],
  936. [], QUAGGA_INCLUDES )
  937. dnl ---------------------------------------------------------------
  938. dnl Additional, newer way to check link-state using ifi_link_state.
  939. dnl Not available in all BSD's when ifmediareq available
  940. dnl ---------------------------------------------------------------
  941. AC_CHECK_HEADER([net/if.h],
  942. AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
  943. AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
  944. [], QUAGGA_INCLUDES),
  945. ,)
  946. dnl ------------------------
  947. dnl TCP_MD5SIG socket option
  948. dnl ------------------------
  949. AC_CHECK_HEADER([netinet/tcp.h],
  950. [m4_define([MD5_INCLUDES],
  951. QUAGGA_INCLUDES
  952. [#include <netinet/tcp.h>
  953. ])
  954. AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
  955. [],
  956. QUAGGA_INCLUDES)
  957. if test $ac_cv_have_decl_TCP_MD5SIG = no; then
  958. AC_CHECK_HEADER([linux/tcp.h],
  959. [m4_define([MD5_INCLUDES],
  960. QUAGGA_INCLUDES
  961. [#include <linux/tcp.h>
  962. ])
  963. AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
  964. fi
  965. dnl -----------------------------
  966. dnl check ipforward detect method
  967. dnl -----------------------------
  968. AC_CACHE_CHECK([ipforward method], [quagga_cv_ipforward_method],
  969. [if test x$cross_compiling = xyes; then
  970. if test x"$opsys" = x"gnu-linux"; then
  971. quagga_cv_ipforward_method=/proc/net/snmp
  972. else
  973. quagga_cv_ipforward_method=/dev/ip
  974. fi
  975. else
  976. for quagga_cv_ipforward_method in /proc/net/snmp /dev/ip /dev/null;
  977. do
  978. test x`ls $quagga_cv_ipforward_method 2>/dev/null` = x"$quagga_cv_ipforward_method" && break
  979. done
  980. fi
  981. case $quagga_cv_ipforward_method in
  982. "/proc/net/snmp") quagga_cv_ipforward_method="proc";;
  983. "/dev/ip")
  984. case "$host" in
  985. *-freebsd*) quagga_cv_ipforward_method="sysctl";;
  986. *) quagga_cv_ipforward_method="solaris";;
  987. esac;;
  988. *) quagga_cv_ipforward_method="sysctl";;
  989. esac])
  990. IPFORWARD=ipforward_${quagga_cv_ipforward_method}.o
  991. AC_SUBST(IPFORWARD)
  992. AC_CHECK_FUNCS(getaddrinfo, [have_getaddrinfo=yes], [have_getaddrinfo=no])
  993. dnl ----------
  994. dnl IPv6 check
  995. dnl ----------
  996. AC_MSG_CHECKING(whether does this OS have IPv6 stack)
  997. dnl ---------
  998. dnl KAME IPv6
  999. dnl ---------
  1000. if grep WIDE /usr/include/netinet6/in6.h >/dev/null 2>&1; then
  1001. AC_DEFINE(KAME,1,KAME IPv6)
  1002. AC_MSG_RESULT(KAME)
  1003. dnl ------------------------------------
  1004. dnl Solaris 9, 10 and potentially higher
  1005. dnl ------------------------------------
  1006. elif test x"$opsys" = x"sol8"; then
  1007. AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
  1008. AC_MSG_RESULT(Solaris IPv6)
  1009. dnl ----------
  1010. dnl Linux IPv6
  1011. dnl ----------
  1012. elif test x"$opsys" = x"gnu-linux"; then
  1013. AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
  1014. AC_MSG_RESULT(Linux IPv6)
  1015. else
  1016. AC_MSG_ERROR([Failed to detect IPv6 stack])
  1017. fi
  1018. dnl this is unconditial, for compatibility
  1019. AC_DEFINE(HAVE_IPV6,1,IPv6)
  1020. dnl ------------------
  1021. dnl IPv6 header checks
  1022. dnl ------------------
  1023. AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h netinet/icmp6.h \
  1024. netinet6/in6_var.h netinet6/nd6.h], [], [],
  1025. QUAGGA_INCLUDES)
  1026. m4_define([QUAGGA_INCLUDES],dnl
  1027. QUAGGA_INCLUDES
  1028. [#if HAVE_NETINET6_IN6_H
  1029. #include <netinet6/in6.h>
  1030. #endif
  1031. #if HAVE_NETINET_IN6_VAR_H
  1032. #include <netinet/in6_var.h>
  1033. #endif
  1034. #if HAVE_NETINET_ICMP6_H
  1035. # include <netinet/icmp6.h>
  1036. #endif
  1037. #if HAVE_NETINET6_IN6_VAR_H
  1038. # include <netinet6/in6_var.h>
  1039. #endif
  1040. #if HAVE_NETINET6_ND6_H
  1041. # include <netinet6/nd6.h>
  1042. #endif
  1043. ])dnl
  1044. dnl disable doc check
  1045. if test "${enable_doc}" = "no";then
  1046. DOC=""
  1047. else
  1048. DOC="doc"
  1049. fi
  1050. dnl --------------------
  1051. dnl Daemon disable check
  1052. dnl --------------------
  1053. if test "${enable_zebra}" = "no";then
  1054. ZEBRA=""
  1055. else
  1056. ZEBRA="zebra"
  1057. fi
  1058. AM_CONDITIONAL(ZEBRA, test "x$ZEBRA" = "xzebra")
  1059. if test "${enable_bgpd}" = "no";then
  1060. BGPD=""
  1061. else
  1062. BGPD="bgpd"
  1063. fi
  1064. AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
  1065. if test "${enable_ripd}" = "no";then
  1066. RIPD=""
  1067. else
  1068. RIPD="ripd"
  1069. fi
  1070. AM_CONDITIONAL(RIPD, test "x$RIPD" = "xripd")
  1071. if test "${enable_ospfd}" = "no";then
  1072. OSPFD=""
  1073. else
  1074. OSPFD="ospfd"
  1075. fi
  1076. AM_CONDITIONAL(OSPFD, test "x$OSPFD" = "xospfd")
  1077. if test "${enable_watchquagga}" = "no";then
  1078. WATCHQUAGGA=""
  1079. else
  1080. WATCHQUAGGA="watchquagga"
  1081. fi
  1082. AM_CONDITIONAL(WATCHQUAGGA, test "x$WATCHQUAGGA" = "xwatchquagga")
  1083. OSPFCLIENT=""
  1084. if test "${enable_ospfapi}" != "no";then
  1085. AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
  1086. if test "${enable_ospfclient}" != "no";then
  1087. OSPFCLIENT="ospfclient"
  1088. fi
  1089. fi
  1090. AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
  1091. case "${enable_ripngd}" in
  1092. "no" ) RIPNGD="";;
  1093. * ) RIPNGD="ripngd";;
  1094. esac
  1095. AM_CONDITIONAL(RIPNGD, test "x$RIPNGD" = "xripngd")
  1096. case "${enable_ospf6d}" in
  1097. "no" ) OSPF6D="";;
  1098. * ) OSPF6D="ospf6d";;
  1099. esac
  1100. AM_CONDITIONAL(OSPF6D, test "x$OSPF6D" = "xospf6d")
  1101. case "${enable_isisd}" in
  1102. "no" ) ISISD="";;
  1103. * ) ISISD="isisd";;
  1104. esac
  1105. AM_CONDITIONAL(ISISD, test "x$ISISD" = "xisisd")
  1106. case "${enable_pimd}" in
  1107. "no" ) PIMD="";;
  1108. * ) PIMD="pimd";;
  1109. esac
  1110. AM_CONDITIONAL(PIMD, test "x$PIMD" = "xpimd")
  1111. if test "${enable_bgp_announce}" = "no";then
  1112. AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
  1113. else
  1114. AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
  1115. fi
  1116. AC_SUBST(DOC)
  1117. AC_SUBST(ZEBRA)
  1118. AC_SUBST(BGPD)
  1119. AC_SUBST(RIPD)
  1120. AC_SUBST(RIPNGD)
  1121. AC_SUBST(OSPFD)
  1122. AC_SUBST(OSPF6D)
  1123. AC_SUBST(WATCHQUAGGA)
  1124. AC_SUBST(ISISD)
  1125. AC_SUBST(PIMD)
  1126. AC_SUBST(SOLARIS)
  1127. AC_SUBST(VTYSH)
  1128. AC_SUBST(CURSES)
  1129. AC_SUBST(OSPFCLIENT)
  1130. AC_SUBST(OSPFAPI)
  1131. AC_CHECK_LIB(c, inet_ntop, [AC_DEFINE(HAVE_INET_NTOP,,inet_ntop)])
  1132. AC_CHECK_LIB(c, inet_pton, [AC_DEFINE(HAVE_INET_PTON,,inet_pton)])
  1133. AC_CHECK_LIB(crypt, crypt)
  1134. AC_CHECK_LIB(resolv, res_init)
  1135. dnl ---------------------------
  1136. dnl check system has PCRE regexp
  1137. dnl ---------------------------
  1138. if test "x$enable_pcreposix" = "xyes"; then
  1139. AC_CHECK_LIB(pcreposix, pcreposix_regexec, ,[enable_pcreposix=no
  1140. AC_MSG_WARN([*** falling back to other regex library ***]) ])
  1141. fi
  1142. if test "x$enable_pcreposix" != "xyes"; then
  1143. dnl ---------------------------
  1144. dnl check system has GNU regexp
  1145. dnl ---------------------------
  1146. AC_MSG_CHECKING(whether system has GNU regex)
  1147. AC_CHECK_LIB(c, regexec,
  1148. [AC_DEFINE(HAVE_GNU_REGEX,,GNU regexp library)
  1149. LIB_REGEX=""],
  1150. [LIB_REGEX="regex.o"])
  1151. fi
  1152. AC_SUBST(HAVE_LIBPCREPOSIX)
  1153. AC_SUBST(LIB_REGEX)
  1154. dnl ------------------
  1155. dnl check Net-SNMP library
  1156. dnl ------------------
  1157. if test "${enable_snmp}" != ""; then
  1158. AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
  1159. if test x"$NETSNMP_CONFIG" = x"no"; then
  1160. AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
  1161. fi
  1162. LIBS="$LIBS `${NETSNMP_CONFIG} --agent-libs`"
  1163. CFLAGS="`${NETSNMP_CONFIG} --base-cflags` $CFLAGS"
  1164. AC_MSG_CHECKING([whether we can link to Net-SNMP])
  1165. AC_LINK_IFELSE([AC_LANG_PROGRAM([
  1166. int main(void);
  1167. ],
  1168. [
  1169. {
  1170. return 0;
  1171. }
  1172. ])],[AC_MSG_RESULT(yes)],[
  1173. AC_MSG_RESULT(no)
  1174. AC_MSG_ERROR([--enable-snmp given but not usable])])
  1175. AC_DEFINE(HAVE_SNMP,,SNMP)
  1176. case "${enable_snmp}" in
  1177. yes)
  1178. SNMP_METHOD=agentx
  1179. ;;
  1180. smux|agentx)
  1181. SNMP_METHOD="${enable_snmp}"
  1182. ;;
  1183. *)
  1184. AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
  1185. ;;
  1186. esac
  1187. AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
  1188. AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
  1189. AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
  1190. fi
  1191. dnl ---------------------------
  1192. dnl sockaddr and netinet checks
  1193. dnl ---------------------------
  1194. AC_CHECK_TYPES([struct sockaddr, struct sockaddr_in,
  1195. struct sockaddr_in6, struct sockaddr_un, struct sockaddr_dl,
  1196. socklen_t, struct vifctl, struct mfcctl, struct sioc_sg_req,
  1197. vifi_t, struct sioc_vif_req, struct igmpmsg,
  1198. struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
  1199. struct nd_opt_adv_interval, struct rt_addrinfo,
  1200. struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
  1201. [], [], QUAGGA_INCLUDES)
  1202. AC_CHECK_MEMBERS([struct sockaddr.sa_len,
  1203. struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
  1204. struct sockaddr_in6.sin6_scope_id,
  1205. struct sockaddr_dl.sdl_len,
  1206. struct if6_aliasreq.ifra_lifetime,
  1207. struct nd_opt_adv_interval.nd_opt_ai_type],
  1208. [], [], QUAGGA_INCLUDES)
  1209. dnl ---------------------------
  1210. dnl IRDP/pktinfo/icmphdr checks
  1211. dnl ---------------------------
  1212. AC_CHECK_TYPES([struct in_pktinfo],
  1213. [AC_CHECK_TYPES([struct icmphdr],
  1214. [if test "${enable_irdp}" != "no"; then
  1215. AC_DEFINE(HAVE_IRDP,, IRDP)
  1216. fi],
  1217. [if test "${enable_irdp}" = "yes"; then
  1218. AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
  1219. fi], [QUAGGA_INCLUDES])],
  1220. [if test "${enable_irdp}" = "yes"; then
  1221. AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
  1222. fi], [QUAGGA_INCLUDES])
  1223. dnl -----------------------
  1224. dnl checking for IP_PKTINFO
  1225. dnl -----------------------
  1226. AC_MSG_CHECKING(for IP_PKTINFO)
  1227. AC_TRY_COMPILE([#include <netdb.h>], [
  1228. int opt = IP_PKTINFO;
  1229. ], [
  1230. AC_MSG_RESULT(yes)
  1231. AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
  1232. ], [
  1233. AC_MSG_RESULT(no)
  1234. ])
  1235. dnl ---------------------------
  1236. dnl checking for IP_RECVDSTADDR
  1237. dnl ---------------------------
  1238. AC_MSG_CHECKING(for IP_RECVDSTADDR)
  1239. AC_TRY_COMPILE([#include <netinet/in.h>], [
  1240. int opt = IP_RECVDSTADDR;
  1241. ], [
  1242. AC_MSG_RESULT(yes)
  1243. AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
  1244. ], [
  1245. AC_MSG_RESULT(no)
  1246. ])
  1247. dnl ----------------------
  1248. dnl checking for IP_RECVIF
  1249. dnl ----------------------
  1250. AC_MSG_CHECKING(for IP_RECVIF)
  1251. AC_TRY_COMPILE([#include <netinet/in.h>], [
  1252. int opt = IP_RECVIF;
  1253. ], [
  1254. AC_MSG_RESULT(yes)
  1255. AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
  1256. ], [
  1257. AC_MSG_RESULT(no)
  1258. ])
  1259. dnl --------------------------------------
  1260. dnl checking for getrusage struct and call
  1261. dnl --------------------------------------
  1262. if test "${enable_rusage}" != "no"; then
  1263. AC_MSG_CHECKING(whether getrusage is available)
  1264. AC_TRY_COMPILE([#include <sys/resource.h>],[struct rusage ac_x; getrusage (RUSAGE_SELF, &ac_x);],
  1265. [AC_MSG_RESULT(yes)
  1266. AC_DEFINE(HAVE_RUSAGE,,rusage)],
  1267. AC_MSG_RESULT(no))
  1268. fi
  1269. dnl --------------------------------------
  1270. dnl checking for clock_time monotonic struct and call
  1271. dnl --------------------------------------
  1272. AC_CHECK_DECL(CLOCK_MONOTONIC,
  1273. [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
  1274. AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
  1275. ], [AC_MSG_RESULT(no)], [QUAGGA_INCLUDES])
  1276. dnl -------------------
  1277. dnl capabilities checks
  1278. dnl -------------------
  1279. if test "${enable_capabilities}" != "no"; then
  1280. AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
  1281. AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
  1282. [AC_MSG_RESULT(yes)
  1283. AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
  1284. quagga_ac_keepcaps="yes"],
  1285. AC_MSG_RESULT(no)
  1286. )
  1287. if test x"${quagga_ac_keepcaps}" = x"yes"; then
  1288. AC_CHECK_HEADERS(sys/capability.h)
  1289. fi
  1290. if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
  1291. AC_CHECK_LIB(cap, cap_init,
  1292. [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
  1293. LIBCAP="-lcap"
  1294. quagga_ac_lcaps="yes"]
  1295. )
  1296. else
  1297. AC_CHECK_HEADERS(priv.h,
  1298. [AC_MSG_CHECKING(Solaris style privileges are available)
  1299. AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
  1300. [AC_MSG_RESULT(yes)
  1301. AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
  1302. quagga_ac_scaps="yes"],
  1303. AC_MSG_RESULT(no)
  1304. )
  1305. ]
  1306. )
  1307. fi
  1308. if test x"${quagga_ac_scaps}" = x"yes" \
  1309. -o x"${quagga_ac_lcaps}" = x"yes"; then
  1310. AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
  1311. fi
  1312. fi
  1313. AC_SUBST(LIBCAP)
  1314. dnl ---------------------------------------------------------------------------
  1315. dnl http://www.gnu.org/software/autoconf-archive/ax_sys_weak_alias.html
  1316. dnl Check for and set one of the following = 1
  1317. dnl HAVE_SYS_WEAK_ALIAS_ATTRIBUTE
  1318. dnl HAVE_SYS_WEAK_ALIAS_PRAGMA
  1319. dnl HAVE_SYS_WEAK_ALIAS_HPSECONDARY
  1320. dnl HAVE_SYS_WEAK_ALIAS_CRIDUPLICATE
  1321. dnl If any scheme is found, set
  1322. dnl HAVE_SYS_WEAK_ALIAS=1
  1323. dnl The following variable is set to text value
  1324. dnl WEAK_ALIAS = "attribute" || "pragma" || "hpsecondary" || "criduplicate" || "no"
  1325. dnl If weak alias can cross object file boundaries
  1326. dnl WEAK_ALIAS_CROSSFILE = "yes" || "no"
  1327. dnl ---------------------------------------------------------------------------
  1328. AX_SYS_WEAK_ALIAS
  1329. dnl ---------------------------
  1330. dnl check for glibc 'backtrace'
  1331. dnl ---------------------------
  1332. if test x"${enable_backtrace}" != x"no" ; then
  1333. backtrace_ok=no
  1334. AC_CHECK_HEADER([execinfo.h], [
  1335. AC_SEARCH_LIBS([backtrace], [execinfo], [
  1336. AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
  1337. AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
  1338. backtrace_ok=yes
  1339. ],, [-lm])
  1340. ])
  1341. if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
  1342. dnl user explicitly requested backtrace but we failed to find support
  1343. AC_MSG_FAILURE([failed to find backtrace support])
  1344. fi
  1345. fi
  1346. dnl -----------------------------------------
  1347. dnl check for malloc mallinfo struct and call
  1348. dnl this must try and link using LIBS, in
  1349. dnl order to check no alternative allocator
  1350. dnl has been specified, which might not provide
  1351. dnl mallinfo, e.g. such as Umem on Solaris.
  1352. dnl -----------------------------------------
  1353. AC_CHECK_HEADER([malloc.h],
  1354. [AC_MSG_CHECKING(whether mallinfo is available)
  1355. AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
  1356. [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
  1357. [AC_MSG_RESULT(yes)
  1358. AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
  1359. AC_MSG_RESULT(no)
  1360. )
  1361. ], [], QUAGGA_INCLUDES)
  1362. dnl ----------
  1363. dnl configure date
  1364. dnl ----------
  1365. CONFDATE=`date '+%Y%m%d'`
  1366. AC_SUBST(CONFDATE)
  1367. dnl -------
  1368. dnl DejaGNU
  1369. dnl -------
  1370. if test x"$DEJAGNU" = x
  1371. then
  1372. DEJAGNU="\$(top_srcdir)/tests/global-conf.exp"
  1373. fi
  1374. RUNTESTDEFAULTFLAGS="-x --tool \$\$tool"
  1375. AC_SUBST(DEJAGNU)
  1376. AC_SUBST(RUNTESTDEFAULTFLAGS)
  1377. dnl ------------------------------
  1378. dnl set paths for state directory
  1379. dnl ------------------------------
  1380. AC_MSG_CHECKING(directory to use for state file)
  1381. if test "${prefix}" = "NONE"; then
  1382. quagga_statedir_prefix="";
  1383. else
  1384. quagga_statedir_prefix=${prefix}
  1385. fi
  1386. if test "${localstatedir}" = '${prefix}/var'; then
  1387. for QUAGGA_STATE_DIR in ${quagga_statedir_prefix}/var/run dnl
  1388. ${quagga_statedir_prefix}/var/adm dnl
  1389. ${quagga_statedir_prefix}/etc dnl
  1390. /var/run dnl
  1391. /var/adm dnl
  1392. /etc dnl
  1393. /dev/null;
  1394. do
  1395. test -d $QUAGGA_STATE_DIR && break
  1396. done
  1397. quagga_statedir=$QUAGGA_STATE_DIR
  1398. else
  1399. quagga_statedir=${localstatedir}
  1400. fi
  1401. if test $quagga_statedir = "/dev/null"; then
  1402. AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
  1403. fi
  1404. AC_MSG_RESULT(${quagga_statedir})
  1405. AC_SUBST(quagga_statedir)
  1406. AC_DEFINE_UNQUOTED(PATH_ZEBRA_PID, "$quagga_statedir/zebra.pid",zebra PID)
  1407. AC_DEFINE_UNQUOTED(PATH_RIPD_PID, "$quagga_statedir/ripd.pid",ripd PID)
  1408. AC_DEFINE_UNQUOTED(PATH_RIPNGD_PID, "$quagga_statedir/ripngd.pid",ripngd PID)
  1409. AC_DEFINE_UNQUOTED(PATH_BGPD_PID, "$quagga_statedir/bgpd.pid",bgpd PID)
  1410. AC_DEFINE_UNQUOTED(PATH_OSPFD_PID, "$quagga_statedir/ospfd.pid",ospfd PID)
  1411. AC_DEFINE_UNQUOTED(PATH_OSPF6D_PID, "$quagga_statedir/ospf6d.pid",ospf6d PID)
  1412. AC_DEFINE_UNQUOTED(PATH_ISISD_PID, "$quagga_statedir/isisd.pid",isisd PID)
  1413. AC_DEFINE_UNQUOTED(PATH_PIMD_PID, "$quagga_statedir/pimd.pid",pimd PID)
  1414. AC_DEFINE_UNQUOTED(PATH_WATCHQUAGGA_PID, "$quagga_statedir/watchquagga.pid",watchquagga PID)
  1415. AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$quagga_statedir/zserv.api",zebra api socket)
  1416. AC_DEFINE_UNQUOTED(ZEBRA_VTYSH_PATH, "$quagga_statedir/zebra.vty",zebra vty socket)
  1417. AC_DEFINE_UNQUOTED(RIP_VTYSH_PATH, "$quagga_statedir/ripd.vty",rip vty socket)
  1418. AC_DEFINE_UNQUOTED(RIPNG_VTYSH_PATH, "$quagga_statedir/ripngd.vty",ripng vty socket)
  1419. AC_DEFINE_UNQUOTED(BGP_VTYSH_PATH, "$quagga_statedir/bgpd.vty",bgpd vty socket)
  1420. AC_DEFINE_UNQUOTED(OSPF_VTYSH_PATH, "$quagga_statedir/ospfd.vty",ospfd vty socket)
  1421. AC_DEFINE_UNQUOTED(OSPF6_VTYSH_PATH, "$quagga_statedir/ospf6d.vty",ospf6d vty socket)
  1422. AC_DEFINE_UNQUOTED(ISIS_VTYSH_PATH, "$quagga_statedir/isisd.vty",isisd vty socket)
  1423. AC_DEFINE_UNQUOTED(PIM_VTYSH_PATH, "$quagga_statedir/pimd.vty",pimd vty socket)
  1424. AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$quagga_statedir",daemon vty directory)
  1425. dnl -------------------------------
  1426. dnl Quagga sources should always be
  1427. dnl current wrt interfaces. Dont
  1428. dnl allow deprecated interfaces to
  1429. dnl be exposed.
  1430. dnl -------------------------------
  1431. AC_DEFINE(QUAGGA_NO_DEPRECATED_INTERFACES, 1, Hide deprecated interfaces)
  1432. dnl ---------------------------
  1433. dnl Check htonl works correctly
  1434. dnl ---------------------------
  1435. AC_MSG_CHECKING(for working htonl)
  1436. AC_CACHE_VAL(ac_cv_htonl_works,
  1437. [AC_LINK_IFELSE([AC_LANG_PROGRAM([QUAGGA_INCLUDES],[htonl (0);])],
  1438. [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
  1439. ]
  1440. )
  1441. AC_MSG_RESULT($ac_cv_htonl_works)
  1442. AC_CONFIG_FILES([Makefile lib/Makefile qpb/Makefile zebra/Makefile ripd/Makefile
  1443. ripngd/Makefile bgpd/Makefile ospfd/Makefile watchquagga/Makefile
  1444. ospf6d/Makefile isisd/Makefile vtysh/Makefile
  1445. doc/Makefile ospfclient/Makefile tests/Makefile m4/Makefile
  1446. pimd/Makefile
  1447. tests/bgpd.tests/Makefile
  1448. tests/libzebra.tests/Makefile
  1449. redhat/Makefile
  1450. pkgsrc/Makefile
  1451. fpm/Makefile
  1452. redhat/quagga.spec
  1453. lib/version.h
  1454. doc/defines.texi
  1455. isisd/topology/Makefile
  1456. pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
  1457. pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh])
  1458. AC_CONFIG_FILES([solaris/Makefile])
  1459. AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
  1460. ## Hack, but working solution to avoid rebuilding of quagga.info.
  1461. ## It's already in CVS until texinfo 4.7 is more common.
  1462. AC_OUTPUT
  1463. echo "
  1464. Quagga configuration
  1465. --------------------
  1466. quagga version : ${PACKAGE_VERSION}
  1467. host operating system : ${host_os}
  1468. source code location : ${srcdir}
  1469. compiler : ${CC}
  1470. compiler flags : ${CFLAGS}
  1471. make : ${MAKE-make}
  1472. linker flags : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
  1473. state file directory : ${quagga_statedir}
  1474. config file directory : `eval echo \`echo ${sysconfdir}\``
  1475. example directory : `eval echo \`echo ${exampledir}\``
  1476. user to run as : ${enable_user}
  1477. group to run as : ${enable_group}
  1478. group for vty sockets : ${enable_vty_group}
  1479. config file mask : ${enable_configfile_mask}
  1480. log file mask : ${enable_logfile_mask}
  1481. zebra protobuf enabled : ${have_protobuf:-no}
  1482. The above user and group must have read/write access to the state file
  1483. directory and to the config files in the config file directory."
  1484. if test x"$quagga_cv_gnu_make" = x"no"; then echo "
  1485. Warning: The ${MAKE-make} programme detected, either in your path or
  1486. via the MAKE variable, is not GNU Make. GNU make may be installed as
  1487. gmake on some systems. and is required to complete a build of Quagga
  1488. " > /dev/stderr
  1489. fi